Как вставить и сместить изображение на основе значения ячейки

Question

У меня возникла небольшая проблема.

Нам нужно было сделать небольшую отдельную ячейку, изменить примерно до 1000 выражений клиента (Excel).Я запустил изменение в python, используя openpyxl, и все логотипы компании исчезли.

Я скомпилировал VBA, чтобы вернуть изображения обратно, но мне трудно получить их в правильном положении на второй странице в верхней части окна.вторая страница не является заданным номером строки.

Тем не менее, имя клиента отмечает верхнюю часть второй страницы.

Есть ли способ найти в столбце B имя клиента и вставитьлоготип компании в той же строке, но 9 столбцов справа.

Это то, что я имею до сих пор:

Sub Example()
Dim MyPath As String, FilesInPath As String
Dim MyFiles() As String, Fnum As Long
Dim mybook As Workbook
Dim CalcMode As Long
Dim sh As Worksheet
Dim ErrorYes As Boolean

'Fill in the path\folder where the files are
MyPath = "Path\to\excels"

'Add a slash at the end if the user forget it
If Right(MyPath, 1) <> "\" Then
    MyPath = MyPath & "\"
End If

'If there are no Excel files in the folder exit the sub
FilesInPath = Dir(MyPath & "*.xl*")
If FilesInPath = "" Then
    MsgBox "No files found"
    Exit Sub
End If

'Fill the array(myFiles)with the list of Excel files in the folder
Fnum = 0
Do While FilesInPath <> ""
    Fnum = Fnum + 1
    ReDim Preserve MyFiles(1 To Fnum)
    MyFiles(Fnum) = FilesInPath
    FilesInPath = Dir()
Loop

'Change ScreenUpdating, Calculation and EnableEvents
With Application
    CalcMode = .Calculation
    .Calculation = xlCalculationManual
    .ScreenUpdating = False
    .EnableEvents = False
End With

'Loop through all files in the array(myFiles)
If Fnum > 0 Then
    For Fnum = LBound(MyFiles) To UBound(MyFiles)
        Set mybook = Nothing
        On Error Resume Next
        Set mybook = Workbooks.Open(MyPath & MyFiles(Fnum))
        On Error GoTo 0

        If Not mybook Is Nothing Then


            'Change cell value(s) in one worksheet in mybook
            On Error Resume Next
            With mybook.ActiveSheet.Pictures.Insert("C:Path\to\Pic.jpg")

                    With .ShapeRange
                        .LockAspectRatio = msoTrue
                        .Width = 40
                        .Height = 55
            End With
                        .Left = ActiveSheet.Range("K1").Left
                        .Top = ActiveSheet.Range("K1").Top
                        .Placement = 1
                        .PrintObject = True


            End With

            With ActiveSheet.Range("B12:L13").BorderAround(ColorIndex:=xlAutomatic, Weight:=xlMedium)

            End With

            If Err.Number > 0 Then
                ErrorYes = True
                Err.Clear
                'Close mybook without saving
                mybook.Close savechanges:=False
            Else
                'Save and close mybook
                mybook.Close savechanges:=True
            End If
            On Error GoTo 0
        Else
            'Not possible to open the workbook
            ErrorYes = True
        End If

    Next Fnum
End If

If ErrorYes = True Then
    MsgBox "There are problems in one or more files, possible problem:" _
         & vbNewLine & "protected workbook/sheet or a sheet/range that not exist"
End If

'Restore ScreenUpdating, Calculation and EnableEvents
With Application
    .ScreenUpdating = True
    .EnableEvents = True
    .Calculation = CalcMode
End With

End Sub

Answer 1

Вы можете использовать:

Option Explicit

Sub image()

    Dim i As Long, Lastrow As Long
    Dim pic As Picture
    Dim rng As Range

    With ThisWorkbook.Worksheets("Sheet1")

        Lastrow = .Cells(.Rows.Count, "O").End(xlUp).Row

        For i = 1 To Lastrow

            If .Range("O" & i).Value = "Import" Then

                Set rng = .Range("O" & i).Offset(0, -9)

                With .Pictures.Insert("C:\Users\XXXXX\Desktop\download.jpg")
                    .Top = rng.Top
                    .Left = rng.Left
                End With

            End If

        Next i

    End With

End Sub