Установка Docker на Windows 10 Home, это можно сделать?

Question

Docker требует win 10 pro, потому что ему нужны некоторые расширения виртуализации (HyperV и контейнеры).Можно ли выполнить эти требования на win 10 Home?

Answer 1

Да, это можно сделать в Windows 10 Home (пробовал на win10Home v1809 27.01.2019)

Запустить в командной строке как Администратор :

1. Установить Hyper-V:

   pushd "%~dp0"
   dir /b %SystemRoot%\servicing\Packages\*Hyper-V*.mum >hyper-v.txt
   for /f %%i in ('findstr /i . hyper-v.txt 2^>nul') do dism /online /norestart /add-package:"%SystemRoot%\servicing\Packages\%%i"
   del hyper-v.txt
   Dism /online /enable-feature /featurename:Microsoft-Hyper-V -All /LimitAccess /ALL
   pause
   

2. Установить контейнеры:

   pushd "%~dp0"
   dir /b %SystemRoot%\servicing\Packages\*containers*.mum >containers.txt
   for /f %%i in ('findstr /i . containers.txt 2^>nul') do dism /online /norestart /add-package:"%SystemRoot%\servicing\Packages\%%i"
   del containers.txt
   Dism /online /enable-feature /featurename:Containers -All /LimitAccess /ALL
   pause
   

3. Редактировать реестрключи:

   REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /f /v EditionID /t REG_SZ /d "Professional"
   REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /f /v ProductName /t REG_SZ /d "Windows 10 Pro"
   

4. Скачать и запустить официальный установщик Docker для Windows.

5. В моем случае ключи реестрабыли восстановлены после перезагрузки, но вы можете восстановить их вручную:

   REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v EditionID /t REG_SZ /d "Core"
   REG ADD "HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows NT\CurrentVersion" /v ProductName /t REG_SZ /d "Windows 10 Home"