В Perl, как я могу узнать, используется ли мой файл как модуль или запускается как скрипт? - PullRequest
Новая
       217

В Perl, как я могу узнать, используется ли мой файл как модуль или запускается как скрипт?

10 голосов
/ 15 июля 2009

Допустим, у меня есть файл Perl, в котором есть части, которые мне нужно запускать, только когда меня вызывают как скрипт. Я помню, как читал некоторое время назад о включении этих частей в метод main () и выполнении 

main() unless(<some condition which tests if I'm being used as a module>);

Но я забыл, каково было состояние. Поиск в Google ничего полезного не дал. Может кто-нибудь указать правильное место, чтобы искать это?

Ответы [ 3 ]

15 голосов
/ 15 июля 2009

Если файл вызывается как сценарий, вызывающий абонент не будет, поэтому вы можете использовать: 

main() unless caller;

См. Брайан Д Фой объяснение . 

#!/usr/bin/perl

use strict;
use warnings;

main() unless caller;

sub main {
    my $obj = MyClass->new;
    $obj->hello;
}

package MyClass;

use strict;
use warnings;

sub new { bless {} => shift };

sub hello { print "Hello World\n" }

no warnings 'void';
"MyClass"

Выход: 

C:\Temp> perl MyClass.pm
Hello World

Использование из другого скрипта: 

C:\Temp\> cat mytest.pl
#!/usr/bin/perl

use strict;
use warnings;

use MyClass;

my $obj = MyClass->new;
$obj->hello;

Выход: 

C:\Temp> mytest.pl
Hello World
7 голосов
/ 16 июля 2009

Я называю эти вещи "модульными" первоначально в моих Сценариях как Модули Статья для The Perl Journal (теперь Доктор Доббс ). Google этот термин, и вы получите нужные ресурсы. Синан уже связался с моими источниками разработки для одной из моих книг, где я об этом говорю. Вам также может понравиться Как скрипт становится модулем .

2 голосов
/ 16 июля 2009

Лучше не делать этого, а вместо этого использовать структурированный подход, такой как MooseX :: Runnable .

Ваш класс будет выглядеть так: 

class Get::Me::Data with (MooseX::Runnable, MooseX::Getopt) {

    has 'dsn' => (
        is            => 'ro',
        isa           => 'Str',
        documentation => 'Database to connect to',
    );

    has 'database' => (
        is         => 'ro',
        traits     => ['NoGetopt'],
        lazy_build => 1,
    );

    method _build_database {
        Database->connect($self->dsn);
    }

    method get_data(Str $for_person){
        return $database->search({ person => $for_person });
    }

    method run(Str $for_person?) {
        if(!$defined $for_person){
            print "Type the person you are looking for: ";
            $for_person = <>;
            chomp $for_person;
        }

        my @data = $self->get_data($for_person);

        if(!@data){
            say "No data found for $for_person";
            return 1;
        }

        for my $data (@data){
            say $data->format;
        }

        return 0;
    }
}

Теперь у вас есть класс, который можно легко использовать внутри вашей программы: 

my $finder = Get::Me::Data->new( database => $dbh );
$finder->get_data('jrockway');

Внутри интерактивного скрипта, который больше, чем просто метод "run", описанный выше: 

...
my $finder = Get::Me::Data->new( dsn => 'person_database' );
$finder->run('jrockway') and die 'Failure'; # and because "0" is success
say "All done with Get::Me::Data.";
...

Если вы просто хотите сделать это автономно, вы можете сказать: 

$ mx-run Get::Me::Data --help
Usage: mx-run ... [arguments]
    --dsn     Database to connect to

$ mx-run Get::Me::Data --dsn person_database
Type the person you are looking for: jrockway
<data>

$ mx-run Get::Me::Data --dsn person_database jrockway
<data>

Обратите внимание, как мало кода вы написали, и насколько гибок получаемый класс. "main if! caller" это хорошо, но зачем беспокоиться, когда вы можете сделать лучше?

(Кстати, MX :: Runnable имеет плагины; так что вы можете легко увеличить объем выводимой отладочной информации, перезапустить приложение при изменении кода, сделать приложение постоянным, запустить его в профилировщике и т. Д.)

...