Вложение файла Excel в электронную почту с использованием VBA

Question

Я пытаюсь исправить проблему с VBA для вложения файла из Excel непосредственно в электронное письмо с .Display перед отправкой пользователем.Файл должен сохранять, создавать новый временный файл, копировать и вставлять этот временный файл непосредственно в тело письма, при этом прикрепляя фактический исходный документ к письму для справки.Как только это будет сделано, он должен уничтожить временный файл, не сохраняя его.

Проблема, с которой я столкнулся, заключается в том, что он создаст новую временную книгу, но не будет копировать и вставлять информацию в электронное письмо или прикреплять документ вэлектронная почта.Мой код ниже с адресом электронной почты.Любая помощь приветствуется.Кажется, что сообщение об ошибке всегда падает на .Attachments.Add (ActiveDocument.FullName)

Sub SendEmailOutlook()
    ActiveWorkbook.Save

    'Send an email. basically just to standardize and error-proof the process
    'RangetoHTML function (below this macro) allows a range of cells to be pasted into the email body    
    Dim strbody As String    
    Dim rng As Range    
    Dim OutApp As Object    
    Dim OutMail As Object    
    Dim Message As String    
    Dim subject As String    
    Dim UpdateTime As String        

    'this line is extra for HTML formatting but it makes the text easier to read    
    strbody = "<P STYLE='font-family:Calibri;font-size:12pt'>"

    subject = "2018 Safety Walk Form for " & Sheets("2018 Safety Walk").Range("H5") & " " & Sheets("2018 Safety Walk").Range("K5")

    Message = "Team <br><br>Please see the attached form for, " & Sheets("2018 Safety Walk").Range("K5")

    'Set last row based on input data
    '    Dim lastRow As String    
    '    lastRow = Sheets("Email").UsedRange.Rows.Count
    'Set range for email body    
    'The column is on the right, the row on the left. Change to .Range("A1:H30") if you want it to be static

    Set rng = Sheets("2018 Safety Walk").Range("B5:K43")

    'Create email
    With Application    
        .EnableEvents = False    
        .ScreenUpdating = False    
    End With

    Set OutApp = CreateObject("Outlook.Application")    
    Set OutMail = OutApp.CreateItem(0)

    With OutMail    
        .To = "123@123.com"    
        .BCC = ""    
        .subject = subject    
        .HTMLBody = strbody & Message & RangetoHTML(rng) & "<br>"    
        .Attachments.Add (ActiveDocument.FullName)        
        .Display    'you can use .Send to have the macro send the email without needing to confirm it    
    End With

    On Error GoTo 0

    With Application    
        .EnableEvents = True    
        .ScreenUpdating = True    
    End With

    Set OutMail = Nothing    
    Set OutApp = Nothing    
End Sub




Function RangetoHTML(rng As Range)    
    Dim fso As Object    
    Dim ts As Object    
    Dim TempFile As String    
    Dim TempWB As Workbook

    TempFile = Environ$("temp") & "/" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

    'Copy the range and create a new workbook to past the data in    
    rng.Copy    
    Set TempWB = Workbooks.Add(1)

    With TempWB.Sheets(1)    
        .Cells(1).PasteSpecial Paste:=8    
        .Cells(1).PasteSpecial xlPasteValues, , False, False    
        .Cells(1).PasteSpecial xlPasteFormats, , False, False    
        .Cells(1).Select    
        Application.CutCopyMode = False

        On Error Resume Next    
        .DrawingObjects.Visible = True    
        .DrawingObjects.Delete   
        On Error GoTo 0
    End With         

    'Copy the range and create a new workbook to past the data in
    rng.Copy
    Set TempWB = Workbooks.Add(1)
    With TempWB.Sheets(1)
        .Cells(1).PasteSpecial Paste:=8
        .Cells(1).PasteSpecial xlPasteValues, , False, False
        .Cells(1).PasteSpecial xlPasteFormats, , False, False
        .Cells(1).Select
        Application.CutCopyMode = False
        On Error Resume Next
        .DrawingObjects.Visible = True
        .DrawingObjects.Delete
        On Error GoTo 0
    End With

    'Publish the sheet to a htm file
    With TempWB.PublishObjects.Add( _
         SourceType:=xlSourceRange, _
         Filename:=TempFile, _
         Sheet:=TempWB.Sheets(1).Name, _
         Source:=TempWB.Sheets(1).UsedRange.Address, _
         HtmlType:=xlHtmlStatic)
        .Publish (True)
    End With

    'Read all data from the htm file into RangetoHTML
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
    RangetoHTML = ts.readall
    ts.Close
    RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                          "align=left x:publishsource=")

    'Close TempWB
    TempWB.Close SaveChanges:=False

    'Delete the htm file we used in this function
    Kill TempFile
    Set ts = Nothing
    Set fso = Nothing
    Set TempWB = Nothing
End Function

Answer 1

Из комментария ОП:

При запуске макроса получено сообщение об ошибке «Ошибка во время выполнения» -2147024894 (80070002) ': не удается найти этот файл. Проверьте путь и файлимя правильное. "

Это потому, что в вашей функции RangeToHTML вы создаете две временные книги, но закрываете только одну.Поэтому, как только RangeToHTML вернется, ваш ActiveWorkbook будет ссылаться на оставшуюся временную рабочую книгу, а не на оригинал.Поскольку он не был сохранен, его свойство .FullName еще не имеет значения, поэтому, таким образом, возникает ошибка «Не удается найти этот файл».

В RangeToHTML, избавьтесь от одного из этих разделов, где выскопируйте / вставьте, и ваша проблема будет решена:

'Copy the range and create a new workbook to past the data in    
rng.Copy    
Set TempWB = Workbooks.Add(1)

With TempWB.Sheets(1)    
    .Cells(1).PasteSpecial Paste:=8    
    .Cells(1).PasteSpecial xlPasteValues, , False, False    
    .Cells(1).PasteSpecial xlPasteFormats, , False, False    
    .Cells(1).Select    
    Application.CutCopyMode = False

    On Error Resume Next    
    .DrawingObjects.Visible = True    
    .DrawingObjects.Delete   
    On Error GoTo 0
End With         

'Copy the range and create a new workbook to past the data in
rng.Copy
Set TempWB = Workbooks.Add(1)
With TempWB.Sheets(1)
    .Cells(1).PasteSpecial Paste:=8
    .Cells(1).PasteSpecial xlPasteValues, , False, False
    .Cells(1).PasteSpecial xlPasteFormats, , False, False
    .Cells(1).Select
    Application.CutCopyMode = False
    On Error Resume Next
    .DrawingObjects.Visible = True
    .DrawingObjects.Delete
    On Error GoTo 0
End With

Вы также должны в своей процедуре SendEmailOutlook вообще не использовать ActiveWorkbook, так как, как вы можете видеть, это может сбить вас с толку, если выне осторожныВсегда лучше установить и работать со ссылкой непосредственно на рабочую книгу.

Итак, что-то вроде:

Dim wb as Workbook
Set wb = Workbooks("Your Workbook Name")

или:

Dim wb as Workbook
Set wb = ActiveWorkbook

в началеSendEmailOutlook, а затем используйте wb везде, где вы в данный момент используете ActiveWorkbook в другом месте процедуры.