Сортировка коллекции в классическом ASP

Question

Это довольно простой вопрос - как отсортировать коллекцию?

У меня есть CSV-файл со строками в случайном порядке. Я хотел бы отсортировать строки по дате в одном столбце. Добавлять ли строки в набор записей? Можно ли отсортировать с помощью Scripting.Dictionary?

Я явно был избалован .NET и Linq, и теперь я снова оказался в стране классического осина, осознав, что я должен был это знать 7 лет назад, и очень упустил дженерики. Я чувствую себя полным n00b.

Answer 1

В этом случае я бы получил помощь от старшего брата .net. Можно использовать System.Collections.Sortedlist в вашем приложении ASP и получать отсортированные пары ключей и значений.

set list = server.createObject("System.Collections.Sortedlist")
with list
  .add "something", "YY"
  .add "something else", "XX"
end with

for i = 0 to list.count - 1
    response.write(list.getKey(i) & " = " & list.getByIndex(i))
next

Кстати, если доступны также следующие классы .net:

• System.Collections.Queue
• System.Collections.Stack
• System.Collections.ArrayList
• System.Collections.SortedList
• System.Collections.Hashtable
• System.IO.StringWriter
• System.IO.MemoryStream;

Также см .: Чудеса взаимодействия COM .NET

Answer 2

Я бы пошел с подходом RecordSet. Используйте текстовый драйвер. Вам нужно будет изменить каталог в строке подключения и имя файла в операторе select. Расширенное свойство «HDR = Yes» указывает, что в CSV есть строка заголовка, которую я предлагаю, так как это облегчит написание psuedo SQL.

<%

Dim strConnection, conn, rs, strSQL

strConnection = "Provider=Microsoft.Jet.OLEDB.4.0;Data Source=c:\inetpub\wwwroot\;Extended Properties='text;HDR=Yes;FMT=Delimited';"

Set conn = Server.CreateObject("ADODB.Connection")
conn.Open strConnection

Set rs = Server.CreateObject("ADODB.recordset")
strSQL = "SELECT * FROM test.csv order by date desc"
rs.open strSQL, conn, 3,3

WHILE NOT rs.EOF
    Response.Write(rs("date") & "<br/>") 
    rs.MoveNext
WEND

rs.Close
Set rs = Nothing

conn.Close
Set conn = Nothing

%>

Answer 3

Поздно поздно ответ на этот вопрос, но все еще имеет значение.

Я работал с небольшими коллекциями, поэтому мог позволить себе подход, при котором каждый раз вставлял элемент в правильное место, эффективно восстанавливая коллекцию при каждом добавлении.

Класс VBScript выглядит следующим образом:

'Simple collection manager class.
'Performs the opration of adding/setting a collection item.
'Encapulated off here in order to delegate responsibility away from the collection class.
Class clsCollectionManager
    Public Sub PopulateCollectionItem(collection, strKey, Value)
        If collection.Exists(strKey) Then
            If (VarType(Value) = vbObject) Then
                Set collection.Item(strKey) = Value
            Else
                collection.Item(strKey) = Value
            End If
        Else
            Call collection.Add(strKey, Value)
        End If
    End Sub

    'take a collection and a new element as input parameters, an spit out a brand new collection 
    'with the new item iserted into the correct location by order
    'This works on the assumption that the collection it is receiving is already ordered 
    '(which it should be if we always use this method to populate the item)

    'This mutates the passed collection, so we highlight this by marking it as byref 
    '(this is not strictly necessary as objects are passed by reference anyway)
    Public Sub AddCollectionItemInOrder(byref existingCollection, strNewKey, Value)
        Dim orderedCollection: Set orderedCollection = Server.CreateObject("Scripting.Dictionary")
        Dim strExistingKey

        'If there is something already in our recordset then we need to add it in order.

        'There is no sorting available for a collection (or an array) in VBScript. Therefore we have to do it ourself.
        'First, iterate over eveything in our current collection. We have to assume that it is itself sorted.
        For Each strExistingKey In existingCollection

            'if the new item doesn't exist AND it occurs after the current item, then add the new item in now 
            '(before adding in the current item.)
            If (Not orderedCollection.Exists(strNewKey)) And (strExistingKey > strNewKey) Then
                Call PopulateCollectionItem(orderedCollection, strNewKey, Value)
            End If
            Call PopulateCollectionItem(orderedCollection, strExistingKey, existingCollection.item(strExistingKey))
        Next

        'Finally check to see if it still doesn't exist. 
        'It won't if the last place for it is at the very end, or the original collection was empty
        If (Not orderedCollection.Exists(strNewKey)) Then
            Call PopulateCollectionItem(orderedCollection, strNewKey, Value)
        End If

        Set existingCollection = orderedCollection
    End Sub
End Class

Answer 4

Также посмотрите на "Bubble Sort", отлично работает с этими классическими облаками тегов asp.

http://www.4guysfromrolla.com/webtech/011001-1.shtml

Answer 5

Это было слишком долго для меня тоже. IIRC у вас нет возможности из коробки.

На вашем месте я бы поместил все данные в массив, а затем отсортировал массив. Я нашел реализацию QuickSort здесь: http://www.4guysfromrolla.com/webtech/012799-3.shtml