Как мне узнать, имеет ли переменная числовое значение в Perl?

Question

Есть ли в Perl простой способ, который позволит мне определить, является ли данная переменная числовой? Что-то вроде:

if (is_number($x))
{ ... }

было бы идеально. Техника, которая не выдаёт предупреждения при использовании переключателя -w, безусловно, предпочтительнее.

Answer 1

Используйте Scalar::Util::looks_like_number(), который использует внутреннюю функцию Perl C API look_like_number (), что, вероятно, является наиболее эффективным способом сделать это. Обратите внимание, что строки "inf" и "infinity" обрабатываются как числа.

Пример:

#!/usr/bin/perl

use warnings;
use strict;

use Scalar::Util qw(looks_like_number);

my @exprs = qw(1 5.25 0.001 1.3e8 foo bar 1dd inf infinity);

foreach my $expr (@exprs) {
    print "$expr is", looks_like_number($expr) ? '' : ' not', " a number\n";
}

Дает этот вывод:

1 is a number
5.25 is a number
0.001 is a number
1.3e8 is a number
foo is not a number
bar is not a number
1dd is not a number
inf is a number
infinity is a number

Смотри также:

• perldoc Scalar :: Util
• perldoc perlapi для looks_like_number

Answer 2

Проверьте модуль CPAN Regexp :: Common . Я думаю, что он делает именно то, что вам нужно, и обрабатывает все крайние случаи (например, реальные числа, научные записи и т. Д.). например,

use Regexp::Common;
if ($var =~ /$RE{num}{real}/) { print q{a number}; }

Answer 3

Первоначальный вопрос заключался в том, как определить, является ли переменная числовой, а не «имеет ли она числовое значение».

Есть несколько операторов, которые имеют отдельные режимы работы для числовых и строковых операндов, где «числовой» означает все, что изначально было числом или когда-либо использовалось в числовом контексте (например, в $x = "123"; 0+$x до добавления, $x - это строка, после чего она считается числовой).

Один из способов сказать это:

if ( length( do { no warnings "numeric"; $x & "" } ) ) {
    print "$x is numeric\n";
}

Answer 4

Простой (и, возможно, упрощенный) ответ на вопрос - это содержание $x числовое следующее:

if ($x  eq  $x+0) { .... }

Проводит текстовое сравнение оригинала $x с $x, преобразованным в числовое значение.

Answer 5

Обычно проверка номера выполняется с помощью регулярных выражений. Этот код будет определять, является ли что-то числовым, а также проверять неопределенные переменные, чтобы не выдавать предупреждения:

sub is_integer {
   defined $_[0] && $_[0] =~ /^[+-]?\d+$/;
}

sub is_float {
   defined $_[0] && $_[0] =~ /^[+-]?\d+(\.\d+)?$/;
}

Вот некоторые материалы для чтения , на которые вам следует взглянуть.

Answer 6

Я не верю, что для этого есть что-то встроенное. Больше, чем вы когда-либо хотели увидеть по этому вопросу, см. Perlmonks по обнаружению чисел

Answer 7

Не идеально, но вы можете использовать регулярное выражение:

sub isnumber 
{
    shift =~ /^-?\d+\.?\d*$/;
}

Answer 8

rexep не совершенен ... это:

use Try::Tiny;

sub is_numeric {
  my ($x) = @_;
  my $numeric = 1;
  try {
    use warnings FATAL => qw/numeric/;
    0 + $x;
  }
  catch {
    $numeric = 0;
  };
  return $numeric;
}

Answer 9

Несколько более надежное регулярное выражение можно найти в Regexp :: Common .

Звучит так, будто вы хотите знать, считает ли Perl переменную числовой. Вот функция, которая ловит это предупреждение:

sub is_number{
  my $n = shift;
  my $ret = 1;
  $SIG{"__WARN__"} = sub {$ret = 0};
  eval { my $x = $n + 1 };
  return $ret
}

Другой вариант - отключить предупреждение локально:

{
  no warnings "numeric"; # Ignore "isn't numeric" warning
  ...                    # Use a variable that might not be numeric
}

Обратите внимание, что нечисловые переменные будут автоматически преобразованы в 0, что, вероятно, в любом случае вам и нужно.

Answer 10

Я нашел это интересным, хотя

if ( $value + 0 eq $value) {
    # A number
    push @args, $value;
} else {
    # A string
    push @args, "'$value'";
}