Как вы тестируете время выполнения кода VBA?

Question

Есть ли код в VBA, с которым я могу обернуть функцию, которая позволит мне узнать время, необходимое для запуска, чтобы я мог сравнить различные времена выполнения функций?

Answer 1

Если ваши функции не очень медленные, вам понадобится таймер с очень высоким разрешением. Самый точный из известных мне QueryPerformanceCounter. Google это для получения дополнительной информации. Попробуйте вставить следующее в класс, назовите его CTimer скажем, тогда вы можете сделать экземпляр где-нибудь глобальным и просто вызвать .StartCounter и .TimeElapsed

Option Explicit

Private Type LARGE_INTEGER
    lowpart As Long
    highpart As Long
End Type

Private Declare Function QueryPerformanceCounter Lib "kernel32" (lpPerformanceCount As LARGE_INTEGER) As Long
Private Declare Function QueryPerformanceFrequency Lib "kernel32" (lpFrequency As LARGE_INTEGER) As Long

Private m_CounterStart As LARGE_INTEGER
Private m_CounterEnd As LARGE_INTEGER
Private m_crFrequency As Double

Private Const TWO_32 = 4294967296# ' = 256# * 256# * 256# * 256#

Private Function LI2Double(LI As LARGE_INTEGER) As Double
Dim Low As Double
    Low = LI.lowpart
    If Low < 0 Then
        Low = Low + TWO_32
    End If
    LI2Double = LI.highpart * TWO_32 + Low
End Function

Private Sub Class_Initialize()
Dim PerfFrequency As LARGE_INTEGER
    QueryPerformanceFrequency PerfFrequency
    m_crFrequency = LI2Double(PerfFrequency)
End Sub

Public Sub StartCounter()
    QueryPerformanceCounter m_CounterStart
End Sub

Property Get TimeElapsed() As Double
Dim crStart As Double
Dim crStop As Double
    QueryPerformanceCounter m_CounterEnd
    crStart = LI2Double(m_CounterStart)
    crStop = LI2Double(m_CounterEnd)
    TimeElapsed = 1000# * (crStop - crStart) / m_crFrequency
End Property

Answer 2

Функция таймера в VBA показывает количество секунд, прошедших с полуночи, до 1/100 секунды.

Dim t as single
t = Timer
'code
MsgBox Timer - t

Answer 3

Если вы пытаетесь вернуть время как секундомер, вы можете использовать следующий API, который возвращает время в миллисекундах с момента запуска системы:

Public Declare Function GetTickCount Lib "kernel32.dll" () As Long
Sub testTimer()
Dim t As Long
t = GetTickCount

For i = 1 To 1000000
a = a + 1
Next

MsgBox GetTickCount - t, , "Milliseconds"
End Sub

после http://www.pcreview.co.uk/forums/grab-time-milliseconds-included-vba-t994765.html (так как timeGetTime в winmm.dll у меня не работал, а QueryPerformanceCounter был слишком сложен для необходимой задачи)

Answer 4

Для новичков эти ссылки объясняют, как выполнить автоматическое профилирование всех подводных лодок, которые вы хотите контролировать по времени:

http://www.nullskull.com/a/1602/profiling-and-optimizing-vba.aspx

http://sites.mcpher.com/share/Home/excelquirks/optimizationlink см. procProfiler.zip в http://sites.mcpher.com/share/Home/excelquirks/downlable-items

Answer 5

Мы использовали решение на основе timeGetTime в winmm.dll для миллисекундной точности в течение многих лет. Смотри http://www.aboutvb.de/kom/artikel/komstopwatch.htm

Статья написана на немецком языке, но код в загрузке (класс VBA, обертывающий вызов функции dll) достаточно прост для использования и понимания без возможности прочтения статьи.