Delphi: как установить длину динамического массива с RTTI-доступом, используя DynArraySetLength? - PullRequest
Новая
       46

Delphi: как установить длину динамического массива с RTTI-доступом, используя DynArraySetLength?

3 голосов
/ 27 марта 2010

Я бы хотел установить длину динамического массива, как предложено в этом посте . У меня есть два класса TMyClass и связанный TChildClass, определенный как 

TChildClass = class
private
  FField1:  string;
  FField2:  string;
end;

TMyClass = class
private
  FField1:  TChildClass;
  FField2:  Array of TChildClass;
end;

Расширение массива реализовано как 

var
  RContext:     TRttiContext;
  RType:        TRttiType;
  Val:          TValue;      // Contains the TMyClass instance
  RField:       TRttiField;  // A field in the TMyClass instance
  RElementType: TRttiType;   // The kind of elements in the dyn array
  DynArr:       TRttiDynamicArrayType;
  Value:        TValue;  // Holding an instance as referenced by an array element
  ArrPointer:   Pointer;
  ArrValue:     TValue;
  ArrLength:    LongInt;
  i:            integer;
begin
  RContext := TRTTIContext.Create;
  try
    RType := RContext.GetType(TMyClass.ClassInfo);
    Val := RType.GetMethod('Create').Invoke(RType.AsInstance.MetaclassType, []);
    RField := RType.GetField('FField2');
    if (RField.FieldType is TRttiDynamicArrayType) then begin 
      DynArr := (RField.FieldType as TRttiDynamicArrayType);
      RElementType := DynArr.ElementType;
      // Set the new length of the array
      ArrValue := RField.GetValue(Val.AsObject);
      ArrLength := 3;   // Three seems like a nice number
      ArrPointer := ArrValue.GetReferenceToRawData;
      DynArraySetLength(ArrPointer, ArrValue.TypeInfo, 1, @ArrLength);
      { TODO : Fix 'Index out of bounds' }
      WriteLn(ArrValue.IsArray, ' ', ArrValue.GetArrayLength);
      if RElementType.IsInstance then begin
        for i := 0 to ArrLength - 1 do begin
          Value := RElementType.GetMethod('Create').Invoke(RElementType.AsInstance.MetaclassType, []);
          ArrValue.SetArrayElement(i, Value);
          // This is just a test, so let's clean up immediatly
          Value.Free;
        end;
      end;
    end;
    ReadLn;
    Val.AsObject.Free;
  finally
    RContext.Free;
  end;
end.

Будучи новичком в D2010 RTTI, я подозревал, что ошибка может зависеть от получения ArrValue из экземпляра класса, но последующий WriteLn выводит «TRUE», поэтому я исключил это. Однако, к сожалению, тот же WriteLn сообщает, что размер ArrValue равен 0, что подтверждается исключением «Индекс выходит за границы», которое я получаю при попытке установить любой из элементов в массиве (через ArrValue.SetArrayElement(i, Value);) , Кто-нибудь знает, что я здесь делаю не так? (Или, может быть, есть лучший способ сделать это?) TIA!

Ответы [ 2 ]

8 голосов
/ 27 марта 2010

Динамические массивы довольно сложны для работы. Они подсчитывают ссылки, и следующий комментарий внутри DynArraySetLength должен пролить свет на проблему:

// Если объект кучи не является общим (ref count = 1), просто измените его размер. В противном случае мы делаем копию

Ваш объект содержит одну ссылку на него, как и TValue. Кроме того, GetReferenceToRawData дает вам указатель на массив. Вам нужно сказать PPointer(GetReferenceToRawData)^, чтобы получить фактический массив для передачи в DynArraySetLength.

Как только вы получите это, вы можете изменить его размер, но у вас останется копия. Затем вы должны установить его обратно в исходный массив. 

TValue.Make(@ArrPointer, dynArr.Handle, ArrValue);
RField.SetValue(val.AsObject, arrValue);

В целом, возможно, намного проще использовать список вместо массива. С D2010 у вас есть Generics.Collections, что означает, что вы можете создать TList<TChildClass> или TObjectList<TChildClass> и пользоваться всеми преимуществами класса списка без потери безопасности типов.

0 голосов
/ 27 марта 2010

Я думаю, вы должны определить массив как отдельный тип: 

TMyArray = array of TMyClass;

и используйте это.

Из старого XML-сериализатора на основе RTTI я знаю, что общий метод, который вы используете, должен работать (проверено D7..2009): 

procedure TXMLImpl.ReadArray(const Name: string; TypeInfo: TArrayInformation; Data: Pointer; IO: TParameterInputOutput);
var
  P: PChar;
  L, D: Integer;
  BT: TTypeInformation;
begin
  FArrayType := '';
  FArraySize := -1;
  ComplexTypePrefix(Name, '');
  try
    // Get the element type info.
    BT := TypeInfo.BaseType;
    if not Assigned(BT) then RaiseSerializationReadError; // Not a supported datatype!
    // Typecheck the array specifier.
    if (FArrayType <> '') and (FArrayType <> GetTypeName(BT)) then RaiseSerializationReadError;
    // Do we have a fixed size array or a dynamically sized array?
    L := FArraySize;
    if L >= 0 then begin
      // Set the array
      DynArraySetLength(PPointer(Data)^,TypeInfo.TypeInformation,1,@L);
      // And restore he elements
      D := TypeInfo.ElementSize;
      P := PPointer(Data)^;
      while L > 0 do begin
        ReadElement(''{ArrayItemName},BT,P,IO); // we allow any array item name.
        Inc(P,D);
        Dec(L);
      end;
    end else begin
      RaiseNotSupported;
    end;
  finally
    ComplexTypePostfix;
  end;
end;

Надеюсь, это поможет ..

...