Расшифруйте JSON с mochijson2 в Erlang - PullRequest
Новая
       86

Расшифруйте JSON с mochijson2 в Erlang

5 голосов
/ 29 апреля 2010

У меня есть переменная, содержащая некоторые данные JSON: 

A = <<"{\"job\": {\"id\": \"1\"}}">>.

Используя mochijson2, я декодирую данные: 

 Struct = mochijson2:decode(A).

А теперь у меня есть это: 

{struct,[{<<"job">>,{struct,[{<<"id">>,<<"1">>}]}}]}

Я пытаюсь прочитать (например) "задание" или "идентификатор".

Я пытался использовать struct.get_value, но, похоже, он не работает.

Есть идеи?

Ответы [ 5 ]

13 голосов
/ 30 апреля 2010

Данные представлены в формате {struct, proplist ()}, поэтому вы можете сделать следующее: 

{struct, JsonData} = Struct,
{struct, Job} = proplists:get_value(<<"job">>, JsonData),
Id = proplists:get_value(<<"id">>, Job),

Подробнее о проплистах можно прочитать по адресу: http://www.erlang.org/doc/man/proplists.html

5 голосов
/ 30 ноября 2012

Еще одна вспомогательная функция для доступа к структуре json: 

jsonobj({struct,List}) ->
    fun({contains,Key}) ->
        lists:keymember(Key,1,List);
    ({raw,Key}) ->
        {_,Ret} = lists:keyfind(Key,1,List),Ret;
    (Key) ->
        {_,Ret} = lists:keyfind(Key,1,List),
        jsonobj(Ret)
    end;
jsonobj(List) when is_list(List) ->
    fun(len) ->
        length(List);
    (Index) ->
        jsonobj(lists:nth(Index,List))
    end;
jsonobj(Obj) -> Obj.

Использование: 

1> A=mochijson2:decode(<<"{\"job\": {\"id\": \"1\", \"ids\": [4,5,6], \"isok\": true}}">>).
2> B=jsonobj(A).
3> B(<<"job">>).
#Fun<jsonutils.1.33002110>
4> (B(<<"job">>))(<<"id">>).
1
5> (B(<<"job">>))(<<"ids">>).
#Fun<jsonutils.1.9495087>
6> (B(<<"job">>))({raw,<<"ids">>}).
[4,5,6]
7> ((B(<<"job">>))(<<"ids">>))(1).
4
8> B({raw,<<"job">>}).
{struct,[{<<"id">>,<<"1">>},
               {<<"ids">>,[1,2,3]},
               {<<"isok">>,true}]}
9> B({contains,<<"job">>}).
true
10> B({contains,<<"something">>}).
false
11> ((B(<<"job">>))(<<"ids">>))(len)
3

Не думаю, что извлечение значений из json может быть проще.

2 голосов
/ 18 августа 2012

Вот еще один способ доступа к данным. Для удобства использования синтаксис записей . 

-record(struct, {lst=[]}).

A = <<"{\"job\": {\"id\": \"1\"}}">>,
Struct = mochijson2:decode(A), 
Job = proplists:get_value(<<"job">>, Struct#struct.lst),
Id = proplists:get_value(<<"id">>, Job#struct.lst),

Делает то же самое, что и ответ, используя записи вместо этого. Просто еще один вариант при использовании mochijson2. Мне лично этот синтаксис нравится больше.

1 голос
/ 22 сентября 2016

Мой любимый способ обработки данных mochijson - заменить все структуры хеш-картами, после чего они могут быть точно сопоставлены с шаблоном. Для этого я написал эту простую для понимания функцию: 

structs_to_maps({struct, Props}) when is_list(Props) ->
    lists:foldl(
        fun({Key, Val}, Map) ->
            Map#{Key => structs_to_maps(Val)}
        end,
        #{},
        Props
    );
structs_to_maps(Vals) when is_list(Vals) ->
    lists:map(
        fun(Val) ->
            structs_to_maps(Val)
        end,
        Vals
    );
structs_to_maps(Val) ->
    Val.

Вот пример того, как его использовать: 

do() ->
    A = <<"{\"job\": {\"id\": \"1\"}}">>,
    Data = structs_to_maps(mochijson2:decode(A)),
    #{<<"job">> := #{<<"id">> := Id}} = Data,
    Id.

Это имеет много преимуществ, особенно при работе с входящими данными, которые могут иметь неожиданную форму.

1 голос
/ 30 апреля 2010

В дополнение к ответу, приведенному ранее, есть также хороший учебник по mochiweb, json (видео).

...