Сбор выводов ввода-вывода в список

Question

Как я могу сделать несколько вызовов на SDL.pollEvent :: IO Event, пока на выходе не будет SDL.NoEvent и собрать все результаты в список?

В императивном выражении что-то вроде этого:

events = []
event = SDL.pollEvent
while ( event != SDL.NoEvent ) {
        events.add( event )
        event = SDL.pollEvent
}

Answer 1

Джеймс Кук любезно расширил монад-петлю с этой функцией:

unfoldWhileM  :: Monad  m => (a -> Bool) -> m a -> m [a]

используется с SDL:

events <- unfoldWhileM (/= SDL.NoEvent) SDL.pollEvent

Answer 2

Вы можете использовать что-то вроде:

takeWhileM :: (a -> Bool) -> IO a -> IO [a]
takeWhileM p act = do
  x <- act
  if p x
    then do
      xs <- takeWhileM p act
      return (x : xs)
    else
      return []

Вместо:

do
  xs <- takeWhileM p act
  return (x : xs)

Вы также можете использовать:

liftM (x:) (takeWhileM p act) выход:

takeWhileM :: (a -> Bool) -> IO a -> IO [a]
takeWhileM p act = do
  x <- act
  if p x
    then liftM (x:) (takeWhileM p act)
    else return []

Тогда вы можете использовать: takeWhileM (/=SDL.NoEvent) SDL.pollEvent

Answer 3

Вы можете использовать монадические списки:

import Control.Monad.ListT (ListT)
import Control.Monad.Trans.Class (lift) -- transformers, not mtl
import Data.List.Class (takeWhile, repeat, toList)
import Prelude hiding (takeWhile, repeat)

getEvents :: IO [Event]
getEvents = 
    toList . takeWhile (/= NoEvent) $ do
        repeat ()
        lift pollEvent :: ListT IO Event

ListT из пакета "Список" на взлом.

Answer 4

Использование этих заглушек для Event и pollEvent

data Event = NoEvent | SomeEvent
  deriving (Show,Eq)

instance Random Event where
  randomIO = randomRIO (0,1) >>= return . ([NoEvent,SomeEvent] !!)

pollEvent :: IO Event
pollEvent = randomIO

и комбинатор, заимствованный и адаптированный из более раннего ответа , который прекращает оценку при первом сбое предиката

spanM :: (Monad m) => (a -> Bool) -> m a -> m [a]
spanM p a = do
  x <- a
  if p x then do xs <- spanM p a
                 return (x:xs)
         else return [x]

разрешает этот сеанс ghci, например:

*Main> spanM (/= NoEvent) pollEvent 
[SomeEvent,SomeEvent,NoEvent]

Answer 5

В конце концов я наткнулся на этот фрагмент кода в реальной игре SDL от hackage

getEvents :: IO Event -> [Event] -> IO [Event]
getEvents pEvent es = do
  e <- pEvent
  let hasEvent = e /= NoEvent
  if hasEvent
   then getEvents pEvent (e:es)
   else return (reverse es)

спасибо за ваши ответы, кстати!