Фильтрация текста через команду оболочки в Emacs

Question

В vi [m] есть команда !, которая позволяет мне передать текст через команду оболочки - например, sort или indent - и получить отфильтрованный текст обратно в буфер. Есть ли эквивалент в emacs?

Answer 1

Вы можете выбрать регион и набрать `C-u M- | команда RET ', и она заменяет регион выводом команды в том же буфере из-за аргумента интерактивного префикса shell-command-on-region.

Answer 2

Я написал это несколько лет назад, это может помочь вам:

(defun generalized-shell-command (command arg)
  "Unifies `shell-command' and `shell-command-on-region'. If no region is
selected, run a shell command just like M-x shell-command (M-!).  If
no region is selected and an argument is a passed, run a shell command
and place its output after the mark as in C-u M-x `shell-command' (C-u
M-!).  If a region is selected pass the text of that region to the
shell and replace the text in that region with the output of the shell
command as in C-u M-x `shell-command-on-region' (C-u M-|). If a region
is selected AND an argument is passed (via C-u) send output to another
buffer instead of replacing the text in region."
  (interactive (list (read-from-minibuffer "Shell command: " nil nil nil 'shell-command-history)
                     current-prefix-arg))
  (let ((p (if mark-active (region-beginning) 0))
        (m (if mark-active (region-end) 0)))
    (if (= p m)
        ;; No active region
        (if (eq arg nil)
            (shell-command command)
          (shell-command command t))
      ;; Active region
      (if (eq arg nil)
          (shell-command-on-region p m command t t)
        (shell-command-on-region p m command)))))

Я нашел эту функцию очень полезной. Если вы найдете это полезным, я предлагаю для удобства привязать его к некоторой функциональной клавише, лично я использую F3:

(global-set-key [f3] 'generalized-shell-command)

Answer 3

Позднее редактирование : Насколько я ценю положительные отзывы, ответ Юрты - это путь. И взлом Грега аккуратнее моего.

Я оставлю здесь все остальное, потому что это может чего-то стоить, но ...

---

M-x shell-command-on-region, что по умолчанию связано с M-|.

---

Я вижу, что это не совсем то, о чем просил Рохит. Использование C-h f shell-command-on-region показывает, что желаемое поведение доступно в неинтерактивной версии команды (путем установки аргумента replace не равным nil). Мы должны быть в состоянии написать оболочку для этого.

Попробуйте это (загрузите его в *scratch* и запустите M-x eval-buffer, если он работает, скопируйте его в файл .emacs):

(defun shell-command-on-region-replace (start end command)
  "Run shell-command-on-region interactivly replacing the region in place"
  (interactive (let (string) 
         (unless (mark)
           (error "The mark is not set now, so there is no region"))
         ;; Do this before calling region-beginning
         ;; and region-end, in case subprocess output
         ;; relocates them while we are in the minibuffer.
         ;; call-interactively recognizes region-beginning and
         ;; region-end specially, leaving them in the history.
         (setq string (read-from-minibuffer "Shell command on region: "
                            nil nil nil
                            'shell-command-history))
         (list (region-beginning) (region-end)
               string)))
  (shell-command-on-region start end command t t)
  )

И заметьте, как я сказал в комментариях, что это не очень истощающая вещь. Но я думаю, что это работает.

---

Для любых читателей, которые не знают, как выбрать регион:

1. Переместите «точку» (текущую позицию курсора) в один конец области и используйте C-space для активации «отметки»
2. Переместить точку на другой конец области
3. Готово, вызовите команду