Вставка нескольких строк в временную таблицу с помощью одной команды в SQL2005

Question

У меня есть данные в следующем формате:

-1,-1,-1,-1,701,-1,-1,-1,-1,-1,304,390,403,435,438,439,442,455

Мне нужно вставить его во временную таблицу следующим образом:

CREATE TABLE #TEMP
(
Node int
)

Так что я могу использовать его в сравнении с данными в другой таблице.

Данные выше представляют отдельные строки столбца «Узел».

Есть ли простой способ вставить эти данные, все в одну команду?

Кроме того, данные будут поступать в виде строки ... так что мне нужно иметь возможность просто объединить их в строку запроса SQL. Я, очевидно, могу сначала изменить его, если это необходимо.

Answer 1

Попробуйте что-то вроде

CREATE TABLE #TEMP 
( 
    Node int 
) 


DECLARE @textXML XML
DECLARE @data NVARCHAR(MAX), 
        @delimiter NVARCHAR(5)
SELECT  @data = '-1,-1,-1,-1,701,-1,-1,-1,-1,-1,304,390,403,435,438,439,442,455 ',
        @delimiter = ','
SELECT    @textXML = CAST('<d>' + REPLACE(@data, @delimiter, '</d><d>') + '</d>' AS XML)

INSERT INTO #TEMP
SELECT  T.split.value('.', 'nvarchar(max)') AS data
FROM    @textXML.nodes('/d') T(split)

SELECT * FROM #TEMP

DROP TABLE #TEMP

Answer 2

Вы можете создать запрос динамически, как это:

declare @sql varchar(1000)
set @sql = 'insert into #TEMP select ' + replace(@values, ',', ' union all select ')
exec @sql

Как всегда при динамическом создании запросов, вы должны быть осторожны, чтобы использовать только надежные данные.

Answer 3

Я бы создал функцию, которая возвращала бы табличную переменную, а затем соединил бы эту функцию в select

Использование:

select * from myTable a 
inner join dbo.buildTableFromCSV('1,2,3') on a.id = b.theData

Вот моя функция для этого

CREATE  FUNCTION [dbo].[buildTableFromCSV] ( @csvString  varchar(8000) )  RETURNS @myTable TABLE (ID int identity (1,1), theData varchar(100))
AS    BEGIN 
    DECLARE @startPos       Int         -- position to chop next block of chars from
    DECLARE @currentPos     Int         -- position to current character we're examining
    DECLARE @strLen     Int

    DECLARE @c          char(1)         -- current subString

    -- variable initalization
    -- -------------------------------------------------------------------------------------------------------------------------------------------------
        SELECT @csvString   = @csvString + ','
        SELECT @startPos        = 1
        SELECT @currentPos  = 1



        SELECT @strLen      = Len(@csvString)




    -- loop over string and build temp table
    -- -------------------------------------------------------------------------------------------------------------------------------------------------

        WHILE @currentPos <= @strLen BEGIN
            SET @c = SUBSTRING(@csvString, @currentPos,  1 )        




            IF ( @c = ','  ) BEGIN


                IF ( @currentPos - @startPos > 0 ) BEGIN

                    INSERT 
                    INTO        @myTable ( theData )
                    VALUES          (  CAST( SUBSTRING ( @csvString, @startPos, @currentPos - @startPos) AS varchar ) )

                END
                ELSE
                begin
                    INSERT 
                    INTO        @myTable ( theData )
                    VALUES          (  null )

                end
                SELECT @startPos = @currentPos + 1

            END

            SET @currentPos = @currentPos + 1
        END

        delete from @myTable where theData  is null

    return  
END