Как функция с 'varargs' может извлечь содержимое стека? - PullRequest
Новая
       17

Как функция с 'varargs' может извлечь содержимое стека?

16 голосов
/ 18 ноября 2008

Обычно в Delphi можно было бы объявить функцию с переменным числом аргументов, используя метод 'array of const'. Тем не менее, для совместимости с кодом, написанным на C, существует очень неизвестная директива varargs, которую можно добавить к объявлению функции (я узнал об этом, читая превосходный ' Руди по конвертации ' документа).

В качестве примера можно было бы иметь функцию в C, объявленную так: 

void printf(const char *fmt, ...)

В Delphi это станет: 

procedure printf(const fmt: PChar); varargs;

У меня такой вопрос: как я могу получить содержимое стека при реализации метода, определенного с помощью директивы varargs?

Я бы ожидал, что для этого существуют некоторые инструменты, такие как переводы Dephi функций va_start (), va_arg () и va_end (), но я нигде не могу найти это.

Пожалуйста, помогите!

PS: Пожалуйста, не отвлекайтесь на дискуссии об альтернативе «почему» или «массив констант» - мне нужно это, чтобы написать C-подобные патчи для функций в играх Xbox (см. Проект эмулятора Delphi Xbox 'Dxbx 'на sourceforge для деталей).

Ответы [ 3 ]

18 голосов
/ 18 ноября 2008

ОК, я вижу разъяснение в вашем вопросе, которое означает, что вам нужно реализовать импорт C в Delphi. В этом случае вам нужно самостоятельно реализовать varargs.

Требуются базовые знания - соглашение о вызовах C для x86: стек растет вниз, а C выдвигает аргументы справа налево. Таким образом, указатель на последний объявленный аргумент после его увеличения на размер последнего объявленного аргумента будет указывать на список хвостовых аргументов. С этого момента это просто вопрос считывания аргумента и увеличения указателя на соответствующий размер для более глубокого перемещения в стек. Стек x86 в 32-битном режиме обычно выравнивается по 4 байта, а это также означает, что байты и слова передаются как 32-битные целые числа.

Во всяком случае, вот вспомогательная запись в демонстрационной программе, которая показывает, как считывать данные. Обратите внимание, что Delphi, кажется, передает расширенные типы очень странным образом; однако вам, вероятно, не придется беспокоиться об этом, поскольку 10-байтовые числа с плавающей запятой обычно не используются в C и даже не реализованы в последней версии MS C, IIRC. 

{$apptype console}

type  
  TArgPtr = record
  private
    FArgPtr: PByte;
    class function Align(Ptr: Pointer; Align: Integer): Pointer; static;
  public
    constructor Create(LastArg: Pointer; Size: Integer);
    // Read bytes, signed words etc. using Int32
    // Make an unsigned version if necessary.
    function ReadInt32: Integer;
    // Exact floating-point semantics depend on C compiler.
    // Delphi compiler passes Extended as 10-byte float; most C
    // compilers pass all floating-point values as 8-byte floats.
    function ReadDouble: Double;
    function ReadExtended: Extended;
    function ReadPChar: PChar;
    procedure ReadArg(var Arg; Size: Integer);
  end;

constructor TArgPtr.Create(LastArg: Pointer; Size: Integer);
begin
  FArgPtr := LastArg;
  // 32-bit x86 stack is generally 4-byte aligned
  FArgPtr := Align(FArgPtr + Size, 4);
end;

class function TArgPtr.Align(Ptr: Pointer; Align: Integer): Pointer;
begin
  Integer(Result) := (Integer(Ptr) + Align - 1) and not (Align - 1);
end;

function TArgPtr.ReadInt32: Integer;
begin
  ReadArg(Result, SizeOf(Integer));
end;

function TArgPtr.ReadDouble: Double;
begin
  ReadArg(Result, SizeOf(Double));
end;

function TArgPtr.ReadExtended: Extended;
begin
  ReadArg(Result, SizeOf(Extended));
end;

function TArgPtr.ReadPChar: PChar;
begin
  ReadArg(Result, SizeOf(PChar));
end;

procedure TArgPtr.ReadArg(var Arg; Size: Integer);
begin
  Move(FArgPtr^, Arg, Size);
  FArgPtr := Align(FArgPtr + Size, 4);
end;

procedure Dump(const types: string); cdecl;
var
  ap: TArgPtr;
  cp: PChar;
begin
  cp := PChar(types);
  ap := TArgPtr.Create(@types, SizeOf(string));
  while True do
  begin
    case cp^ of
      #0: 
      begin
        Writeln;
        Exit;
      end;

      'i': Write(ap.ReadInt32, ' ');
      'd': Write(ap.ReadDouble, ' ');
      'e': Write(ap.ReadExtended, ' ');
      's': Write(ap.ReadPChar, ' ');
    else
      Writeln('Unknown format');
      Exit;
    end;
    Inc(cp);
  end;
end;

type
  PDump = procedure(const types: string) cdecl varargs;
var
  MyDump: PDump;

function AsDouble(e: Extended): Double;
begin
  Result := e;
end;

function AsSingle(e: Extended): Single;
begin
  Result := e;
end;

procedure Go;
begin
  MyDump := @Dump;

  MyDump('iii', 10, 20, 30);
  MyDump('sss', 'foo', 'bar', 'baz');

  // Looks like Delphi passes Extended in byte-aligned
  // stack offset, very strange; thus this doesn't work.
  MyDump('e', 2.0);
  // These two are more reliable.
  MyDump('d', AsDouble(2));
  // Singles passed as 8-byte floats.
  MyDump('d', AsSingle(2));
end;

begin
  Go;
end.
2 голосов
/ 18 ноября 2008

Я нашел это (от парня мы знаем:))

Чтобы правильно написать этот материал, вам нужно использовать BASM, встроенный в Delphi. ассемблер, и закодируйте последовательность вызовов в asm. Надеюсь, у вас есть хороший Идея о том, что вам нужно сделать. Возможно, пост в группе .basm поможет, если Вы застряли.

0 голосов
/ 18 ноября 2008

Delphi не позволяет вам реализовать процедуру varargs. Это работает только для импорта внешних функций cdecl, которые используют это.

Поскольку varargs основан на соглашении о вызовах cdecl, вам, в основном, нужно переопределить его самостоятельно в Delphi, используя ассемблер и / или различные виды манипулирования указателями.

...