Как разбить строку в T-SQL?

Question

У меня есть varchar @ a = 'a | b | c | d | e | f | g | h | i | j | k | l | m | n | o | p', который имеет | значения с разделителями. Я хочу разделить эту переменную в массиве или таблице. У кого-нибудь есть идеи по этому поводу.

Answer 1

Используйте табличную функцию, например,

CREATE FUNCTION Splitfn(@String varchar(8000), @Delimiter char(1))       
returns @temptable TABLE (items varchar(8000))       
as       
begin       
    declare @idx int       
    declare @slice varchar(8000)       

    select @idx = 1       
        if len(@String)<1 or @String is null  return       

    while @idx!= 0       
    begin       
        set @idx = charindex(@Delimiter,@String)       
        if @idx!=0       
            set @slice = left(@String,@idx - 1)       
        else       
            set @slice = @String       

        if(len(@slice)>0)  
            insert into @temptable(Items) values(@slice)       

        set @String = right(@String,len(@String) - @idx)       
        if len(@String) = 0 break       
    end   
return      

end

и получите вашу переменную и используйте эту функцию следующим образом,

SELECT i.items FROM dbo.Splitfn(@a,'|') AS i

Answer 2

Попробуйте это:

declare @a varchar(10) 
set @a = 'a|b|c|'
while len(@a) > 1
begin
insert into #temp
select substring(@a,1,patindex('%|%',@a)-1);
set @a = substring(@a,patindex('%|%',@a)+1,len(@a))
end;

Answer 3

В общем, это такой распространенный вопрос:

Я дам общий ответ: Массивы и списки в SQL Server 2005 и более поздних версиях Эрланда Соммарского

Я бы порекомендовал таблицу чисел , а не цикл, для общего пользования.

Answer 4

Вот альтернативное решение на основе XML. Похоже, что производительность аналогична решению Splitfn ().

Преобразует varchar a|b|c|d|e|f|g|h|i|j|k|l|m|n|o|p в XML <a>a</a><a>b</a><a>c</a><a>d</a><a>e</a><a>f</a><a>g</a><a>h</a><a>i</a><a>j</a><a>k</a><a>l</a><a>m</a><a>n</a><a>o</a><a>p</a> и извлекает значение из каждого узла XML <a>.

declare @a      varchar(max);
set @a  =   'a|b|c|d|e|f|g|h|i|j|k|l|m|n|o|p';

declare @xml    xml;
set @xml    
    =   '<a>'+replace(replace(replace(@a,'&','&amp;'),'<','&lt;'),'|','</a><a>')+'</a>';

SELECT  x.n.value('.','VARCHAR(1)') AS  singleValue
FROM    @xml.nodes('/a') AS  x(n)
;