Дублирование компонентов во время выполнения

Question

Есть ли простой способ дублировать все дочерние компоненты родительского компонента, включая их опубликованные свойства?

Например:

• TPanel
  • TLabel
  • TEdit
  • TListView
  • TSpecialClassX

Конечно, самый важный фактор, он должен дублировать любой новый компонент, который я добавляю на TPanel, без изменения кода в нормальных условиях.

Я слышал о RTTI, но никогда не использовал его на самом деле. Есть идеи?

Answer 1

Возможно, вы можете использовать подпрограмму CLoneProperties из ответа на " Заменить визуальный компонент во время выполнения " после того, как вы создадите дублирующие компоненты в цикле через родительские элементы управления.

Обновление : некоторый рабочий код ....

. Из вашего вопроса я предполагаю, что вы хотите продублировать элементы управления, содержащиеся в WinControl (поскольку родитель - это TWinControl).
, Поскольку я не знал, хотите ли вы также подключить дублированные элементы управления к тем же обработчикам событий, что и для оригиналов, я сделал для этого вариант.
, И вы можете захотеть дать правильное значимое имя для дублированных элементов управления.

uses
  TypInfo;

procedure CloneProperties(const Source: TControl; const Dest: TControl);
var
  ms: TMemoryStream;
  OldName: string;
begin
  OldName := Source.Name;
  Source.Name := ''; // needed to avoid Name collision
  try
    ms := TMemoryStream.Create;
    try
      ms.WriteComponent(Source);
      ms.Position := 0;
      ms.ReadComponent(Dest);
    finally
      ms.Free;
    end;
  finally
    Source.Name := OldName;
  end;
end;

procedure CloneEvents(Source, Dest: TControl);
var
  I: Integer;
  PropList: TPropList;
begin
  for I := 0 to GetPropList(Source.ClassInfo, [tkMethod], @PropList) - 1 do
    SetMethodProp(Dest, PropList[I], GetMethodProp(Source, PropList[I]));
end;

procedure DuplicateChildren(const ParentSource: TWinControl;
  const WithEvents: Boolean = True);
var
  I: Integer;
  CurrentControl, ClonedControl: TControl;
begin
  for I := ParentSource.ControlCount - 1 downto 0 do
  begin
    CurrentControl := ParentSource.Controls[I];
    ClonedControl := TControlClass(CurrentControl.ClassType).Create(CurrentControl.Owner);
    ClonedControl.Parent := ParentSource;
    CloneProperties(CurrentControl, ClonedControl);
    ClonedControl.Name := CurrentControl.Name + '_';
    if WithEvents then
      CloneEvents(CurrentControl, ClonedControl);
  end;
end;

procedure TForm1.Button1Click(Sender: TObject);
begin
  DuplicateChildren(Panel1);
end;

Answer 2

прочитайте эту страницу

Информация о типе среды выполнения в Delphi - может ли она что-нибудь сделать для вас?

Примечание к разделу Копирование свойств из компонента в другой

, который имеет модуль RTTIUnit с процедурой, который, кажется, выполняет часть того, что вы хотите, но я не думаю, что он скопирует любые дочерние компоненты без дополнительного кода. (я думаю, что это нормально, вставить это здесь ...)

procedure CopyObject(ObjFrom, ObjTo: TObject);    
  var
PropInfos: PPropList;
PropInfo: PPropInfo;
Count, Loop: Integer;
OrdVal: Longint;
StrVal: String;
FloatVal: Extended;  
MethodVal: TMethod;
begin
//{ Iterate thru all published fields and properties of source }
//{ copying them to target }

//{ Find out how many properties we'll be considering }
Count := GetPropList(ObjFrom.ClassInfo, tkAny, nil);
//{ Allocate memory to hold their RTTI data }
GetMem(PropInfos, Count * SizeOf(PPropInfo));
try
//{ Get hold of the property list in our new buffer }
GetPropList(ObjFrom.ClassInfo, tkAny, PropInfos);
//{ Loop through all the selected properties }
for Loop := 0 to Count - 1 do
begin
  PropInfo := GetPropInfo(ObjTo.ClassInfo, PropInfos^[Loop]^.Name);
 // { Check the general type of the property }
  //{ and read/write it in an appropriate way }
  case PropInfos^[Loop]^.PropType^.Kind of
    tkInteger, tkChar, tkEnumeration,
    tkSet, tkClass{$ifdef Win32}, tkWChar{$endif}:
    begin
      OrdVal := GetOrdProp(ObjFrom, PropInfos^[Loop]);
      if Assigned(PropInfo) then
        SetOrdProp(ObjTo, PropInfo, OrdVal);
    end;
    tkFloat:
    begin
      FloatVal := GetFloatProp(ObjFrom, PropInfos^[Loop]);
      if Assigned(PropInfo) then
        SetFloatProp(ObjTo, PropInfo, FloatVal);
    end;
    {$ifndef DelphiLessThan3}
    tkWString,
    {$endif}
    {$ifdef Win32}
    tkLString,
    {$endif}
    tkString:
    begin
      { Avoid copying 'Name' - components must have unique names }
      if UpperCase(PropInfos^[Loop]^.Name) = 'NAME' then
        Continue;
      StrVal := GetStrProp(ObjFrom, PropInfos^[Loop]);
      if Assigned(PropInfo) then
        SetStrProp(ObjTo, PropInfo, StrVal);
    end;
    tkMethod:
    begin
      MethodVal := GetMethodProp(ObjFrom, PropInfos^[Loop]);
      if Assigned(PropInfo) then
        SetMethodProp(ObjTo, PropInfo, MethodVal);
    end
  end
end
finally
  FreeMem(PropInfos, Count * SizeOf(PPropInfo));
end;
end;

Answer 3

Вы можете записать исходный компонент в поток и прочитать его обратно в целевой компонент.

MemStream := TMemoryStream.Create;
try
  MemStream.WriteComponent(Source);
  MemStream.Position := 0;
  MemStream.ReadComponent(Target);
finally
  MemStream.Free;
end;

Однако могут возникнуть проблемы с дублирующимися именами компонентов.

Answer 4

На самом деле довольно легко дублировать существующие компоненты во время выполнения. Сложная часть состоит в том, чтобы скопировать все их опубликованные свойства в новые (дублированные) объекты.

Извините, но мой пример кода написан на C ++ Builder. VCL - это то же самое, просто другой язык. Не должно быть слишком много проблем, чтобы перевести его Delphi:

for (i = 0; i < ComponentCount; ++i) {
    TControl *Comp = dynamic_cast<TControl *>(Components[i]);
    if (Comp) {
        if (Comp->ClassNameIs("TLabel")) {
            TLabel *OldLabel = dynamic_cast<TDBEdit *>(Components[i]);
            TLabel *NewLabel = new TLabel(this);  // new label
            // copy properties from old to new
            NewLabel->Top = OldLabel->Top;
            NewLabel->Left = OldLabel->Left;
            NewLabel->Caption = Oldlabel->Caption
            // and so on...
        } else if (Comp->ClassNameIs("TPanel")) {
            // copy a TPanel object
        }

Может быть, у кого-то есть лучший способ скопировать все опубликованные свойства старого элемента управления в новый.