Как получить список стеков вызовов в Perl?

Question

Есть ли способ, которым я могу получить доступ (для распечатки) к списку субмодулей с произвольной глубиной суб-вызовов, предшествующих текущей позиции в скрипте Perl?

Мне нужно внести изменения в некоторые модули Perl (.pm). Рабочий процесс инициируется с веб-страницы через cgi-скрипт, передавая ввод через несколько модулей / объектов, заканчивающихся в модуле, где мне нужно использовать данные. Где-то вдоль линии изменились данные, и мне нужно выяснить, где.

Answer 1

Вы можете использовать Devel :: StackTrace .

use Devel::StackTrace;
my $trace = Devel::StackTrace->new;
print $trace->as_string; # like carp

Он ведет себя как след Карпа, но вы можете получить больше контроля над кадрами.

Единственная проблема состоит в том, что ссылки являются строковыми, и если ссылочное значение изменяется, вы его не увидите. Тем не менее, вы можете скопировать некоторые вещи с помощью PadWalker , чтобы распечатать полные данные (хотя это было бы здорово).

Answer 2

Carp::longmess будет делать то, что вы хотите, и это стандартно.

use Carp qw<longmess>;
use Data::Dumper;
sub A { &B; }
sub B { &C; }
sub C { &D; }
sub D { &E; }

sub E { 
    # Uncomment below if you want to see the place in E
    # local $Carp::CarpLevel = -1; 
    my $mess = longmess();
    print Dumper( $mess );
}

A();
__END__
$VAR1 = ' at - line 14
    main::D called at - line 12
    main::C called at - line 10
    main::B called at - line 8
    main::A() called at - line 23
';

Я придумал этот саб (теперь с дополнительным действием благословения!)

my $stack_frame_re = qr{
    ^                # Beginning of line
    \s*              # Any number of spaces
    ( [\w:]+ )       # Package + sub
    (?: [(] ( .*? ) [)] )? # Anything between two parens
    \s+              # At least one space
    called [ ] at    # "called" followed by a single space
    \s+ ( \S+ ) \s+  # Spaces surrounding at least one non-space character
    line [ ] (\d+)   # line designation
}x;

sub get_stack {
    my @lines = split /\s*\n\s*/, longmess;
    shift @lines;
    my @frames
        = map { 
              my ( $sub_name, $arg_str, $file, $line ) = /$stack_frame_re/;
              my $ref =  { sub_name => $sub_name
                         , args     => [ map { s/^'//; s/'$//; $_ } 
                                         split /\s*,\s*/, $arg_str 
                                       ]
                         , file     => $file
                         , line     => $line 
                         };
              bless $ref, $_[0] if @_;
              $ref
          } 
          @lines
       ;
    return wantarray ? @frames : \@frames;
}

Answer 3

абонент может сделать это, хотя вам может потребоваться даже больше информации, чем это.

Answer 4

Этот код работает без каких-либо дополнительных модулей . Просто включите его, где это необходимо.

my $i = 1;
print STDERR "Stack Trace:\n";
while ( (my @call_details = (caller($i++))) ){
    print STDERR $call_details[1].":".$call_details[2]." in function ".$call_details[3]."\n";
}

Answer 5

Там также Carp::confess и Carp::cluck.

Answer 6

Тот, который более красив: Devel :: PrettyTrace

use Devel::PrettyTrace;
bt;