Дерево навигации с XML и XSLT - PullRequest
Новая
       24

Дерево навигации с XML и XSLT

2 голосов
/ 02 августа 2010

У меня есть этот древовидный XML (toc.xml): 

<?xml version="1.0" encoding="utf-8"?>
<toc>
  <item name="top" key="4294967296" subkey="1">
    <item name="child1" key="4294967611" subkey="">
      <item name="child2-1" key="4294961611" subkey="">
        <item name="child3-1" key="4294967613" subkey=""/>
        <item name="child3-2" key="4294967612" subkey=""/>
      </item>
      <item name="child2-2" key="4294962611" subkey="">
        <item name="d" key="4294974806" subkey=""/>
      </item>
      <item name="child2-3" key="4294963611" subkey="">
        <item name="d" key="4294967661" subkey=""/>
        <item name="PI" key="4294967659" subkey=""/>
        <item name="q" key="4294967660" subkey=""/>
      </item>
      <item name="child2-4" key="4294964611" subkey=""/>
      <item name="child2-5" key="4294965611" subkey="">
        <item name="bb" key="4294967616" subkey=""/>
        <item name="bb" key="4294967620" subkey=""/>
        <item name="f" key="4294967615" subkey=""/>
      </item>
    </item>
  </item>
</toc>

Каждый ключ в документе будет уникальным.

У меня есть XSLT, который импортирует toc XML и пытается вывести навигацию: 

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="html" indent="no" />
  <xsl:variable name="id" select="/member/@id" />

  <xsl:template match="/member">
    <html>
      <head>
        <title><xsl:value-of select="/member/name"/></title>
      </head>
      <body>
        <div class="navigation">
          <xsl:apply-templates select="document('toc.xml')" />
        </div>
        <div class="content">
          <xsl:apply-templates />
        </div>
      </body>
    </html>
  </xsl:template>
</xsl>

И хотел бы найти узел и вывести следующий HTML-код внутри HTML-файла: 

...html...
<div class="navigation">
  <ul>
    <li><a href="#">top</a><ul>
      <li><a href="#">child1</li><ul>
        <li><a href="#">child2</li><ul>
            <li><a href="#">child3-1</a></li>
            <li><a href="#">child3-2</a></li>
          </ul></li>
        </ul></li>
      </ul></li>
  </ul>
</div>
...more html...

В основном я хочу найти узел: item [@ key = '4294967611'] и вывести все родительские узлы и прямые дочерние элементы.

Я чувствую, что это должно быть действительно легко, но я изо всех сил пытаюсь найти информацию о том, как это сделать. Мои знания XSLT не велики.

Ответы [ 4 ]

3 голосов
/ 02 августа 2010

С предоставленным вводом (без уникального @key) эта таблица стилей: 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:param name="key" select="4294967611"/>
    <xsl:template match="item">
        <xsl:choose>
            <xsl:when test="generate-id() =
                            generate-id(../item[@key=$key][1])
                            and
                            not(item[@key=$key])">
                <xsl:call-template name="chain">
                    <xsl:with-param name="parents" select="ancestor-or-self::item"/>
                    <xsl:with-param name="childs" select="item"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:apply-templates/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
    <xsl:template name="chain">
        <xsl:param name="parents"/>
        <xsl:param name="childs"/>
        <xsl:if test="$parents">
            <ul>
                <li>
                    <a href="#">
                        <xsl:value-of select="$parents[1]/@name"/>
                    </a>
                    <xsl:call-template name="chain">
                        <xsl:with-param name="parents" select="$parents[position()!=1]"/>
                        <xsl:with-param name="childs" select="$childs"/>
                    </xsl:call-template>
                    <xsl:if test="count($parents)=1">
                        <ul>
                            <xsl:for-each select="$childs">
                                <li>
                                    <a href="#">
                                        <xsl:value-of select="@name"/>
                                    </a>
                                </li>
                            </xsl:for-each>
                        </ul>
                    </xsl:if>
                </li>
            </ul>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

Выход: 

<ul>
    <li>
        <a href="#">top</a>
        <ul>
            <li>
                <a href="#">child1</a>
                <ul>
                    <li>
                        <a href="#">child2-1</a>
                        <ul>
                            <li>
                                <a href="#">child3-1</a>
                            </li>
                            <li>
                                <a href="#">child3-2</a>
                            </li>
                        </ul>
                    </li>
                </ul>
            </li>
        </ul>
    </li>
</ul>

Если @key уникален, эта таблица стилей должна работать: 

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:key name="itemBykey" match="item" use="@key"/>
    <xsl:param name="key" select="4294967611"/>
    <xsl:template match="/">
        <xsl:for-each select="key('itemBykey',$key)">
            <xsl:call-template name="chain">
                <xsl:with-param name="parents" select="ancestor-or-self::item"/>
                <xsl:with-param name="childs" select="item"/>
            </xsl:call-template>
        </xsl:for-each>
    </xsl:template>
    <xsl:template name="chain">
        <xsl:param name="parents"/>
        <xsl:param name="childs"/>
        <xsl:if test="$parents">
            <ul>
                <li>
                    <a href="#">
                        <xsl:value-of select="$parents[1]/@name"/>
                    </a>
                    <xsl:call-template name="chain">
                        <xsl:with-param name="parents" select="$parents[position()!=1]"/>
                        <xsl:with-param name="childs" select="$childs"/>
                    </xsl:call-template>
                    <xsl:if test="count($parents)=1">
                        <ul>
                            <xsl:for-each select="$childs">
                                <li>
                                    <a href="#">
                                        <xsl:value-of select="@name"/>
                                    </a>
                                </li>
                            </xsl:for-each>
                        </ul>
                    </xsl:if>
                </li>
            </ul>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>
0 голосов
/ 02 августа 2010

Это правильная реализация с правильной иерархией родитель-потомок для элементов ul и li . Он выведет только те узлы, которые являются родителями или прямыми потомками значения для ключа, указанного в xsl: variable keyVar. 

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"    >
  <xsl:output method="xml" indent="yes"/>
  <xsl:variable name ="keyVar" select="'4294967666'" />

  <xsl:template match="toc">
    <ul>
      <xsl:apply-templates select="item" />
    </ul>
  </xsl:template>

  <xsl:template match="item">
    <li>
      <a href="#" />
      <xsl:value-of select="@name"/>
      <xsl:if test ="count(descendant::item) > 0">
        <ul>
          <xsl:apply-templates select="item[.//@key=$keyVar or ../@key = $keyVar]" />
        </ul>
      </xsl:if>
    </li>

  </xsl:template>
</xsl:stylesheet>

Выходная иерархия: 

<?xml version="1.0" encoding="utf-8"?>
<ul>
  <li>top<ul>
    <li>child1<ul>
      <li>child2-1<ul>
        <li>child3-1</li>
        <li>child3-2</li>
      </ul></li>
      <li>child2-2<ul>
        <li>d</li>
      </ul></li>
      <li>child2-3<ul>
        <li>d</li>
        <li>PI</li>
        <li>q</li>
      </ul></li>
      <li>child2-4</li>
      <li>child2-5<ul>
        <li>bb</li>
        <li>bb</li>
        <li>f</li>
      </ul></li>
    </ul></li>
  </ul></li>
</ul>
0 голосов
/ 02 августа 2010

Для начала предоставленный требуемый вывод не является правильно сформированным XML-документом или фрагментом.

Кроме того, в предоставленном исходном XML-документе нет элемента <item name="child2" ...>.

ТакжеЕсть шесть item элементов с key='4294967611', так что это также не годный критерий для идентификации элемента.

Я думаю, вы хотите это : 

<ul>
  <li><a href="#">top</a>
      <ul>
        <li><a href="#">child1</a>
        <ul>
          <li><a href="#">child2-1</a>
              <ul>
                  <li><a href="#">child3-1</a></li>
                  <li><a href="#">child3-2</a></li>
              </ul>
          </li>
        </ul>
       </li>
      </ul>
  </li>
</ul>

Если моя догадка верна, вот одно из возможных решений: 

<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:param name="pEl" select="//item[@name='child2-1']"/>

 <xsl:template match="toc">
   <xsl:variable name="pChain" select="$pEl/ancestor-or-self::item"/>
   <xsl:apply-templates select="$pChain[1]">
    <xsl:with-param name="pChain" select="$pChain"/>
    <xsl:with-param name="pEndElementId" select="generate-id($pEl)"/>
   </xsl:apply-templates>
 </xsl:template>

 <xsl:template match="item">
    <xsl:param name="pChain" select="/.."/>
    <xsl:param name="pcurPosition" select="1"/>
    <xsl:param name="pEndElementId"/>
    <ul>
      <li><a href="#"><xsl:value-of select="@name"/></a>
        <xsl:choose>
         <xsl:when test="generate-id() = $pEndElementId">
          <ul>
           <xsl:apply-templates select="item" mode="leafChildren"/>
          </ul>
         </xsl:when>
         <xsl:otherwise>
           <xsl:apply-templates select="$pChain[position()=$pcurPosition+1]">
            <xsl:with-param name="pChain" select="$pChain"/>
            <xsl:with-param name="pcurPosition" select="$pcurPosition +1"/>
            <xsl:with-param name="pEndElementId" select="$pEndElementId"/>
           </xsl:apply-templates>
         </xsl:otherwise>
        </xsl:choose>
      </li>
    </ul>
 </xsl:template>

 <xsl:template match="item" mode="leafChildren">
  <li><a href="#"><xsl:value-of select="@name"/></a></li>
 </xsl:template>
</xsl:stylesheet>

, когда это преобразование применяется к предоставленному XMLdocument : 

<toc>
<item name="top" key="4294967296" subkey="1">
    <item name="child1" key="4294967611" subkey="">
        <item name="child2-1" key="4294967611" subkey="">
            <item name="child3-1" key="4294967613" subkey=""/>
            <item name="child3-2" key="4294967612" subkey=""/>
        </item>
        <item name="child2-2" key="4294967611" subkey="">
            <item name="d" key="4294974806" subkey=""/>
        </item>
        <item name="child2-3" key="4294967611" subkey="">
            <item name="d" key="4294967661" subkey=""/>
            <item name="PI" key="4294967659" subkey=""/>
            <item name="q" key="4294967660" subkey=""/>
        </item>
        <item name="child2-4" key="4294967611" subkey=""/>
        <item name="child2-5" key="4294967611" subkey="">
            <item name="bb" key="4294967616" subkey=""/>
            <item name="bb" key="4294967620" subkey=""/>
            <item name="f" key="4294967615" subkey=""/>
        </item>
    </item>
</item>
</toc>

желаемый результат получен : 

<ul>
   <li>
      <a href="#">top</a>
      <ul>
         <li>
            <a href="#">child1</a>
            <ul>
               <li>
                  <a href="#">child2-1</a>
                  <ul>
                     <li>
                        <a href="#">child3-1</a>
                     </li>
                     <li>
                        <a href="#">child3-2</a>
                     </li>
                  </ul>
               </li>
            </ul>
         </li>
      </ul>
   </li>
</ul>

Если мое предположение о желаемом результате не было хитом, пожалуйста,исправьте свой вопрос и предоставьте правильно сформированный вывод.

0 голосов
/ 02 августа 2010

Это создает желаемый результат: 

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:template match="item">
    <ul>
      <li>
        <a href="'#'">
          <xsl:value-of select="@name"/>
        </a>
      <xsl:apply-templates select="*"/>
    </li>
  </ul>
</xsl:template>
</xsl:stylesheet>

Вместо '#' как href, вы должны сохранить URL в вашем XML-файле, как атрибут name. Чтобы найти узел, вам нужно передать поиск в качестве параметра. Как это сделать, зависит от того, как вы выполняете трансформацию.

Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.

Похожие темы

...