Получить текущего вошедшего в систему пользователя ОС в Adobe Air

Question

Мне нужно имя текущего вошедшего в систему пользователя в моем приложении Air / Flex. Приложение будет развернуто только на машинах Windows. Я думаю, что мог бы достичь этого путем регулярного выражения каталога User, но я открыт для других способов.

Answer 1

Есть пара небольших чисток, которые вы можете сделать ...

package
{
    import flash.filesystem.File;

    public class UserUtil
    {
        public static function get currentOSUser():String
        {
            var userDir:String = File.userDirectory.nativePath;
            var userName:String = userDir.substr(userDir.lastIndexOf(File.separator) + 1);
            return userName;
        }
    }
}

Как предложил Кевин, используйте File.separator, чтобы сделать кросс-платформенное разбиение каталога (только что протестировано в Windows и Mac OS X).

Вам не нужно использовать resolvePath(""), если вы не ищете ребенка.

Кроме того, создание правильного метода получения позволяет связывать без дальнейшей работы.

В приведенном выше примере я поместил его в класс UserUtil, теперь я могу связываться с UserUtil.currentOSUser, например:

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute">
    <mx:Label text="{UserUtil.currentOSUser}"/> 
</mx:WindowedApplication>

Answer 2

Также я бы попробовал:

File.userDirectory.name

Но у меня не установлен Air, поэтому я не могу это проверить ...

Answer 3

Это не самый красивый подход, но если вы знаете, что ваше приложение AIR будет работать только в среде Windows, оно работает достаточно хорошо:

public var username:String;

public function getCurrentOSUser():void
{       
   var nativeProcessStartupInfo:NativeProcessStartupInfo = new NativeProcessStartupInfo();  
   var file:File = new File("C:/WINDOWS/system32/whoami.exe");
   nativeProcessStartupInfo.executable = file;

   process = new NativeProcess();       
   process.addEventListener(ProgressEvent.STANDARD_OUTPUT_DATA, onOutputData);
   process.start(nativeProcessStartupInfo);
}

public function onOutputData(event:ProgressEvent):void
{           
   var output:String = process.standardOutput.readUTFBytes(process.standardOutput.bytesAvailable);
   this.username = output.split('\\')[1];
   trace("Got username: ", this.username);
}

Answer 4

Вот решение, которое работает в XP / Vista, но определенно расширяемо до OSX, Linux, я все еще был бы заинтересован в другом.

public static function GetCurrentOSUser():String{
    // XP & Vista only.
    var userDirectory:String = File.userDirectory.resolvePath("").nativePath;
    var startIndex:Number = userDirectory.lastIndexOf("\\") + 1
    var stopIndex:Number = userDirectory.length;
    var user = userDirectory.substring(startIndex, stopIndex);

    return user;
}

Answer 5

Обновите путь позже: на самом деле есть встроенная функция для получения текущего пользователя. Я думаю, что это в nativeApplication.