Пакетный файл для удаления файлов старше N дней

Question

Я ищу способ удалить все файлы старше 7 дней в пакетном файле. Я искал в Интернете и нашел несколько примеров с сотнями строк кода, и другие, для выполнения которых требовалась установка дополнительных утилит командной строки.

Подобные вещи можно сделать в BASH всего за пару строк кода. Кажется, что-то хотя бы удаленно можно сделать для пакетных файлов в Windows. Я ищу решение, которое работает в стандартной командной строке Windows, без каких-либо дополнительных утилит. Пожалуйста, не PowerShell или Cygwin либо.

Answer 1

Очень часто есть относительные вопросы, связанные с датой и временем, которые нужно решить с помощью пакетного файла. Но интерпретатор командной строки cmd.exe не имеет функции для вычисления даты / времени. Множество хороших рабочих решений, использующих дополнительные консольные приложения или скрипты, уже размещены здесь, на других страницах Stack Overflow и на других веб-сайтах.

Общим для операций, основанных на дате / времени, является требование преобразования строки даты / времени в секунды с определенного дня. Очень распространено 1970-01-01 00:00:00 UTC. Но можно использовать любой более поздний день в зависимости от диапазона дат, необходимого для поддержки конкретной задачи.

Джей отправлено 7daysclean.cmd , содержащее быстрое решение «дата-секунды» для интерпретатора командной строки cmd.exe . Но это не учитывает правильных високосных лет. J.R. опубликовал дополнение для учета високосного дня в текущем году, но игнорируя другие високосные годы с базового года, т.е. с 1970 года.

Уже более 20 лет я использую статические таблицы (массивы), созданные один раз с небольшой функцией C, для быстрого получения количества дней, включая високосные дни с 1970-01-01 в функциях преобразования даты / времени в моих приложениях, написанных на C / C ++ .

Этот очень быстрый табличный метод можно использовать также в пакетном коде с помощью команды FOR . Поэтому я решил закодировать пакетную подпрограмму GetSeconds, которая вычисляет количество секунд с 1970-01-01 00:00:00 UTC для строки даты / времени, переданной этой подпрограмме.

Примечание: Дополнительные секунды не учитываются, поскольку файловые системы Windows также не поддерживают дополнительные секунды.

Во-первых, таблицы:

1. Дни с 1970-01-01 00:00:00 UTC за каждый год, включая високосные дни.

   1970 - 1979:     0   365   730  1096  1461  1826  2191  2557  2922  3287
   1980 - 1989:  3652  4018  4383  4748  5113  5479  5844  6209  6574  6940
   1990 - 1999:  7305  7670  8035  8401  8766  9131  9496  9862 10227 10592
   2000 - 2009: 10957 11323 11688 12053 12418 12784 13149 13514 13879 14245
   2010 - 2019: 14610 14975 15340 15706 16071 16436 16801 17167 17532 17897
   2020 - 2029: 18262 18628 18993 19358 19723 20089 20454 20819 21184 21550
   2030 - 2039: 21915 22280 22645 23011 23376 23741 24106 24472 24837 25202
   2040 - 2049: 25567 25933 26298 26663 27028 27394 27759 28124 28489 28855
   2050 - 2059: 29220 29585 29950 30316 30681 31046 31411 31777 32142 32507
   2060 - 2069: 32872 33238 33603 33968 34333 34699 35064 35429 35794 36160
   2070 - 2079: 36525 36890 37255 37621 37986 38351 38716 39082 39447 39812
   2080 - 2089: 40177 40543 40908 41273 41638 42004 42369 42734 43099 43465
   2090 - 2099: 43830 44195 44560 44926 45291 45656 46021 46387 46752 47117
   2100 - 2106: 47482 47847 48212 48577 48942 49308 49673
   

   Вычисление секунд для года с 2039 по 2106 с началом эпохи 1970-01-01 возможно только с использованием 32-битной переменной без знака, то есть без знака long (или без знака int) в C / C ++.

   Но cmd.exe использовать для математических выражений 32-битную переменную со знаком. Поэтому максимальное значение равно 2147483647 (0x7FFFFFFF), которое равно 2038-01-19 03: 14: 07.

2. Информация о високосном году (Нет / Да) за период с 1970 по 2106.

   1970 - 1989: N N Y N N N Y N N N Y N N N Y N N N Y N
   1990 - 2009: N N Y N N N Y N N N Y N N N Y N N N Y N
   2010 - 2029: N N Y N N N Y N N N Y N N N Y N N N Y N
   2030 - 2049: N N Y N N N Y N N N Y N N N Y N N N Y N
   2050 - 2069: N N Y N N N Y N N N Y N N N Y N N N Y N
   2070 - 2089: N N Y N N N Y N N N Y N N N Y N N N Y N
   2090 - 2106: N N Y N N N Y N N N N N N N Y N N
                                    ^ year 2100
   

3. Количество дней до первого дня каждого месяца в текущем году.

                      Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec
   Year with 365 days:  0  31  59  90 120 151 181 212 243 273 304 334
   Year with 366 days:  0  31  60  91 121 152 182 213 244 274 305 335
   

Преобразование даты в количество секунд с 1970-01-01 довольно просто с помощью этих таблиц.

Внимание, пожалуйста!

Формат строк даты и времени зависит от региона Windows и языковых настроек. Разделители и порядок токенов, назначенных переменным среды Day, Month и Year в первом FOR цикле GetSeconds, должны быть адаптированы к локальному формату даты / времени, если это необходимо.

Необходимо адаптировать строку даты переменной среды, если формат даты в переменной среды ДАТА отличается от формата даты, используемого командой FOR для %%~tF.

Например, когда %DATE% расширяется до Sun 02/08/2015, а %%~tF расширяется до 02/08/2015 07:38 PM, приведенный ниже код можно использовать с изменением строки 4 для:

call :GetSeconds "%DATE:~4% %TIME%"

Это приводит к передаче в подпрограмму только 02/08/2015 - строки даты без 3 букв сокращения дня недели и символа разделительного пробела.

В качестве альтернативы можно использовать следующую дату для передачи текущей даты в правильном формате:

call :GetSeconds "%DATE:~-10% %TIME%"

Теперь последние 10 символов из строки даты передаются в функцию GetSeconds, и поэтому не имеет значения, является ли строка даты переменной среды DATE днем ​​недели или месяцем, если день и месяц всегда с двумя цифрами в ожидаемом порядке, то есть в формате dd/mm/yyyy или dd.mm.yyyy.

Вот пакетный код с поясняющими комментариями, который выводит только какой файл для удаления и какой файл хранить в дереве папок C:\Temp, см. Код первого цикла FOR .

@echo off
setlocal EnableExtensions EnableDelayedExpansion
rem Get seconds since 1970-01-01 for current date and time.
call :GetSeconds "%DATE% %TIME%"
rem Subtract seconds for 7 days from seconds value.
set /A "LastWeek=Seconds-7*86400"

rem For each file in each subdirectory of C:\Temp get last modification date
rem (without seconds -> append second 0) and determine the number of seconds
rem since 1970-01-01 for this date/time. The file can be deleted if seconds
rem value is lower than the value calculated above.

for /F "delims=" %%F in ('dir /A-D-H-S /B /S "C:\Temp"') do (
    call :GetSeconds "%%~tF:0"
    rem if !Seconds! LSS %LastWeek% del /F "%%~fF"
    if !Seconds! LEQ %LastWeek% (
        echo Delete "%%~fF"
    ) else (
        echo Keep   "%%~fF"
    )
)
endlocal
goto :EOF


rem No validation is made for best performance. So make sure that date
rem and hour in string is in a format supported by the code below like
rem MM/DD/YYYY hh:mm:ss or M/D/YYYY h:m:s for English US date/time.

:GetSeconds

rem If there is " AM" or " PM" in time string because of using 12 hour
rem time format, remove those 2 strings and in case of " PM" remember
rem that 12 hours must be added to the hour depending on hour value.

set "DateTime=%~1"
set "Add12Hours=0"
if "%DateTime: AM=%" NEQ "%DateTime%" (
    set "DateTime=%DateTime: AM=%"
) else if "%DateTime: PM=%" NEQ "%DateTime%" (
    set "DateTime=%DateTime: PM=%"
    set "Add12Hours=1"
)

rem Get year, month, day, hour, minute and second from first parameter.

for /F "tokens=1-6 delims=,-./: " %%A in ("%DateTime%") do (
    rem For English US date MM/DD/YYYY or M/D/YYYY
    set "Day=%%B" & set "Month=%%A" & set "Year=%%C"
    rem For German date DD.MM.YYYY or English UK date DD/MM/YYYY
    rem set "Day=%%A" & set "Month=%%B" & set "Year=%%C"
    set "Hour=%%D" & set "Minute=%%E" & set "Second=%%F"
)
rem echo Date/time is: %Year%-%Month%-%Day% %Hour%:%Minute%:%Second%

rem Remove leading zeros from the date/time values or calculation could be wrong.
if "%Month:~0,1%"  EQU "0" ( if "%Month:~1%"  NEQ "" set "Month=%Month:~1%"   )
if "%Day:~0,1%"    EQU "0" ( if "%Day:~1%"    NEQ "" set "Day=%Day:~1%"       )
if "%Hour:~0,1%"   EQU "0" ( if "%Hour:~1%"   NEQ "" set "Hour=%Hour:~1%"     )
if "%Minute:~0,1%" EQU "0" ( if "%Minute:~1%" NEQ "" set "Minute=%Minute:~1%" )
if "%Second:~0,1%" EQU "0" ( if "%Second:~1%" NEQ "" set "Second=%Second:~1%" )

rem Add 12 hours for time range 01:00:00 PM to 11:59:59 PM,
rem but keep the hour as is for 12:00:00 PM to 12:59:59 PM.
if "%Add12Hours%" == "1" (
    if %Hour% LSS 12 set /A Hour+=12
)
set "DateTime="
set "Add12Hours="

rem Must use 2 arrays as more than 31 tokens are not supported
rem by command line interpreter cmd.exe respectively command FOR.
set /A "Index1=Year-1979"
set /A "Index2=Index1-30"

if %Index1% LEQ 30 (
    rem Get number of days to year for the years 1980 to 2009.
    for /F "tokens=%Index1% delims= " %%Y in ("3652 4018 4383 4748 5113 5479 5844 6209 6574 6940 7305 7670 8035 8401 8766 9131 9496 9862 10227 10592 10957 11323 11688 12053 12418 12784 13149 13514 13879 14245") do set "Days=%%Y"
    for /F "tokens=%Index1% delims= " %%L in ("Y N N N Y N N N Y N N N Y N N N Y N N N Y N N N Y N N N Y N") do set "LeapYear=%%L"
) else (
    rem Get number of days to year for the years 2010 to 2038.
    for /F "tokens=%Index2% delims= " %%Y in ("14610 14975 15340 15706 16071 16436 16801 17167 17532 17897 18262 18628 18993 19358 19723 20089 20454 20819 21184 21550 21915 22280 22645 23011 23376 23741 24106 24472 24837") do set "Days=%%Y"
    for /F "tokens=%Index2% delims= " %%L in ("N N Y N N N Y N N N Y N N N Y N N N Y N N N Y N N N Y N N") do set "LeapYear=%%L"
)

rem Add the days to month in year.
if "%LeapYear%" == "N" (
    for /F "tokens=%Month% delims= " %%M in ("0 31 59 90 120 151 181 212 243 273 304 334") do set /A "Days+=%%M"
) else (
    for /F "tokens=%Month% delims= " %%M in ("0 31 60 91 121 152 182 213 244 274 305 335") do set /A "Days+=%%M"
)

rem Add the complete days in month of year.
set /A "Days+=Day-1"

rem Calculate the seconds which is easy now.
set /A "Seconds=Days*86400+Hour*3600+Minute*60+Second"

rem Exit this subroutine
goto :EOF

Для оптимальной производительности было бы лучше удалить все комментарии, то есть все строки, начинающиеся с rem после 0-4 пробелов.

И массивы могут быть также уменьшены, т. Е. Уменьшен временной диапазон с 1980-01-01 00:00:00 до 2038-01-19 03:14:07, как в настоящее время поддерживается вышеуказанным кодом пакета, например, для 2015-01-01 - 2019-12-31, так как в приведенном ниже коде действительно удаляются файлы старше 7 дней в дереве папок C:\Temp.

Кроме того, приведенный ниже код партии оптимизирован для формата времени 24 часа.

@echo off
setlocal EnableDelayedExpansion
call :GetSeconds "%DATE:~-10% %TIME%"
set /A "LastWeek=Seconds-7*86400"

for /F "delims=" %%F in ('dir /A-D-H-S /B /S "C:\Temp"') do (
    call :GetSeconds "%%~tF:0"
    if !Seconds! LSS %LastWeek% del /F "%%~fF"
)
endlocal
goto :EOF

:GetSeconds
for /F "tokens=1-6 delims=,-./: " %%A in ("%~1") do (
    set "Day=%%B" & set "Month=%%A" & set "Year=%%C"
    set "Hour=%%D" & set "Minute=%%E" & set "Second=%%F"
)
if "%Month:~0,1%"  EQU "0" ( if "%Month:~1%"  NEQ "" set "Month=%Month:~1%"   )
if "%Day:~0,1%"    EQU "0" ( if "%Day:~1%"    NEQ "" set "Day=%Day:~1%"       )
if "%Hour:~0,1%"   EQU "0" ( if "%Hour:~1%"   NEQ "" set "Hour=%Hour:~1%"     )
if "%Minute:~0,1%" EQU "0" ( if "%Minute:~1%" NEQ "" set "Minute=%Minute:~1%" )
if "%Second:~0,1%" EQU "0" ( if "%Second:~1%" NEQ "" set "Second=%Second:~1%" )
set /A "Index=Year-2014"
for /F "tokens=%Index% delims= " %%Y in ("16436 16801 17167 17532 17897") do set "Days=%%Y"
for /F "tokens=%Index% delims= " %%L in ("N Y N N N") do set "LeapYear=%%L"
if "%LeapYear%" == "N" (
    for /F "tokens=%Month% delims= " %%M in ("0 31 59 90 120 151 181 212 243 273 304 334") do set /A "Days+=%%M"
) else (
    for /F "tokens=%Month% delims= " %%M in ("0 31 60 91 121 152 182 213 244 274 305 335") do set /A "Days+=%%M"
)
set /A "Days+=Day-1"
set /A "Seconds=Days*86400+Hour*3600+Minute*60+Second"
goto :EOF

Более подробную информацию о форматах даты и времени и сравнениях времени файлов в Windows смотрите в моем ответе на Узнайте, не старше ли файл в пакетном файле * 413 *, с большим количеством дополнительной информации о времени файлов. 1114 *

Answer 2

IMO, JavaScript постепенно становится универсальным стандартом сценариев: он, вероятно, доступен в большем количестве продуктов, чем любой другой язык сценариев (в Windows он доступен с помощью Windows Scripting Host). Я должен вычистить старые файлы во многих папках, поэтому для этого есть функция JavaScript:

// run from an administrator command prompt (or from task scheduler with full rights):  wscript jscript.js
// debug with:   wscript /d /x jscript.js

var fs = WScript.CreateObject("Scripting.FileSystemObject");

clearFolder('C:\\temp\\cleanup');

function clearFolder(folderPath)
{
    // calculate date 3 days ago
    var dateNow = new Date();
    var dateTest = new Date();
    dateTest.setDate(dateNow.getDate() - 3);

    var folder = fs.GetFolder(folderPath);
    var files = folder.Files;

    for( var it = new Enumerator(files); !it.atEnd(); it.moveNext() )
    {
        var file = it.item();

        if( file.DateLastModified < dateTest)
        {
            var filename = file.name;
            var ext = filename.split('.').pop().toLowerCase();

            if (ext != 'exe' && ext != 'dll')
            {
                file.Delete(true);
            }
        }
    }

    var subfolders = new Enumerator(folder.SubFolders);
    for (; !subfolders.atEnd(); subfolders.moveNext())
    {
        clearFolder(subfolders.item().Path);
    }
}

Чтобы очистить каждую папку, просто добавьте еще один вызов в функцию clearFolder (). Этот конкретный код также сохраняет файлы exe и dll, а также очищает подпапки.

Answer 3

Как насчет этой модификации на 7daysclean.cmd , чтобы учесть високосный год?

Это можно сделать менее чем за 10 строк!

set /a Leap=0
if (Month GEQ 2 and ((Years%4 EQL 0 and Years%100 NEQ 0) or Years%400 EQL 0)) set /a Leap=day
set /a Months=!_months!+Leap

---

Редактирование от Mofi:

Условие, указанное выше J.R. всегда оценивается как false из-за неверного синтаксиса.

И Month GEQ 2 также неверно, поскольку добавление 86400 секунд для еще одного дня должно выполняться в високосный год только для месяцев с марта по декабрь, но не для февраля.

Рабочий код для учета високосного дня - только в текущем году - в пакетном файле 7daysclean.cmd , отправленный Jay , будет:

set "LeapDaySecs=0"
if %Month% LEQ 2 goto CalcMonths
set /a "LeapRule=Years%%4"
if %LeapRule% NEQ 0 goto CalcMonths
rem The other 2 rules can be ignored up to year 2100.
set /A "LeapDaySecs=day"
:CalcMonths
set /a Months=!_months!+LeapDaySecs

Answer 4

Могу ли я добавить скромный вклад в эту и без того ценную ветку. Я обнаружил, что другие решения могут избавиться от фактического текста ошибки, но игнорируют% ERRORLEVEL%, который сигнализирует об ошибке в моем приложении. И я законно хочу% ERRORLEVEL%, только если это не ошибка «Файлы не найдены».

Некоторые примеры:

Отладка и устранение ошибки, а именно:

forfiles /p "[file path...]\IDOC_ARCHIVE" /s /m *.txt /d -1 /c "cmd /c del @path" 2>&1 |  findstr /V /O /C:"ERROR: No files found with the specified search criteria."2>&1 | findstr ERROR&&ECHO found error||echo found success

Использование oneliner для возврата ERRORLEVEL успеха или неудачи:

forfiles /p "[file path...]\IDOC_ARCHIVE" /s /m *.txt /d -1 /c "cmd /c del @path" 2>&1 |  findstr /V /O /C:"ERROR: No files found with the specified search criteria."2>&1 | findstr ERROR&&EXIT /B 1||EXIT /B 0

Использование oneliner для поддержания ERRORLEVEL на нуле для успеха в контексте пакетного файла в середине другого кода (ver> nul сбрасывает ERRORLEVEL):

forfiles /p "[file path...]\IDOC_ARCHIVE" /s /m *.txt /d -1 /c "cmd /c del @path" 2>&1 |  findstr /V /O /C:"ERROR: No files found with the specified search criteria."2>&1 | findstr ERROR&&ECHO found error||ver > nul

Для шага задания CmdExec агента SQL Server я обнаружил следующее. Я не знаю, является ли это ошибкой, но CmdExec на этом шаге распознает только первую строку кода:

cmd /e:on /c "forfiles /p "C:\SQLADMIN\MAINTREPORTS\SQL2" /s /m *.txt /d -1 /c "cmd /c del @path" 2>&1 |  findstr /V /O /C:"ERROR: No files found with the specified search criteria."2>&1 | findstr ERROR&&EXIT 1||EXIT 0"&exit %errorlevel%

Answer 5

Я думаю, e.James ответ хорош, поскольку он работает с неизмененными версиями Windows начиная с Windows 2000 SP4 (и, возможно, раньше), но требует записи во внешний файл. Вот модифицированная версия, которая не создает внешний текстовый файл при сохранении совместимости:

REM del_old.cmd
REM usage: del_old MM-DD-YYYY
setlocal enabledelayedexpansion
for /f "tokens=*" %%a IN ('xcopy *.* /d:%1 /L /I null') do @if exist "%%~nxa" set "excludefiles=!excludefiles!;;%%~nxa;;"
for /f "tokens=*" %%a IN ('dir /b') do @(@echo "%excludefiles%"|FINDSTR /C:";;%%a;;">nul || if exist "%%~nxa" DEL /F /Q "%%a">nul 2>&1)

Чтобы быть верным исходному вопросу, здесь в скрипте, который делает ВСЕ математические расчеты за вас, если вы вызываете его с числом дней в качестве параметра:

REM del_old_compute.cmd
REM usage: del_old_compute N
setlocal enabledelayedexpansion
set /a days=%1&set cur_y=%DATE:~10,4%&set cur_m=%DATE:~4,2%&set cur_d=%DATE:~7,2%
for /f "tokens=1 delims==" %%a in ('set cur_') do if "!%%a:~0,1!"=="0" set /a %%a=!%%a:~1,1!+0
set mo_2=28&set /a leapyear=cur_y*10/4
if %leapyear:~-1% equ 0 set mo_2=29
set mo_1=31&set mo_3=31&set mo_4=30&set mo_5=31
set mo_6=30&set mo_7=31&set mo_8=31&set mo_9=30
set mo_10=31&set mo_11=30&set mo_12=31
set /a past_y=(days/365)
set /a monthdays=days-((past_y*365)+((past_y/4)*1))&&set /a past_y=cur_y-past_y&set months=0
:setmonth
set /a minusmonth=(cur_m-1)-months
if %minusmonth% leq 0 set /a minusmonth+=12
set /a checkdays=(mo_%minusmonth%)
if %monthdays% geq %checkdays% set /a months+=1&set /a monthdays-=checkdays&goto :setmonth
set /a past_m=cur_m-months
set /a lastmonth=cur_m-1
if %lastmonth% leq 0 set /a lastmonth+=12
set /a lastmonth=mo_%lastmonth%
set /a past_d=cur_d-monthdays&set adddays=::
if %past_d% leq 0 (set /a past_m-=1&set adddays=)
if %past_m% leq 0 (set /a past_m+=12&set /a past_y-=1)
set mo_2=28&set /a leapyear=past_y*10/4
if %leapyear:~-1% equ 0 set mo_2=29
%adddays%set /a past_d+=mo_%past_m%
set d=%past_m%-%past_d%-%past_y%
for /f "tokens=*" %%a IN ('xcopy *.* /d:%d% /L /I null') do @if exist "%%~nxa" set "excludefiles=!excludefiles!;;%%~nxa;;"
for /f "tokens=*" %%a IN ('dir /b') do @(@echo "%excludefiles%"|FINDSTR /C:";;%%a;;">nul || if exist "%%~nxa" DEL /F /Q "%%a">nul 2>&1)

ПРИМЕЧАНИЕ. Приведенный выше код учитывает високосные годы, а также точное количество дней в каждом месяце. Единственный максимум - это общее количество дней, прошедших с 0/0/0 (после этого он возвращает отрицательные годы).

ПРИМЕЧАНИЕ: математика идет только в одну сторону; он не может правильно получить будущие даты из отрицательных входных данных (он попытается, но, скорее всего, пройдет после последнего дня месяца).

Answer 6

Если у вас есть набор ресурсов XP, вы можете использовать robocopy, чтобы переместить все старые каталоги в один каталог, а затем использовать rmdir, чтобы удалить только этот:

mkdir c:\temp\OldDirectoriesGoHere
robocopy c:\logs\SoManyDirectoriesToDelete\ c:\temp\OldDirectoriesGoHere\ /move /minage:7
rmdir /s /q c:\temp\OldDirectoriesGoHere

Answer 7

Черт возьми, ответов уже много. Простой и удобный маршрут, который я нашел, состоял в том, чтобы выполнить ROBOCOPY.EXE дважды в последовательном порядке из одной инструкции командной строки Windows, используя параметр & .

ROBOCOPY.EXE SOURCE-DIR TARGET-DIR *.* /MOV /MINAGE:30 & ROBOCOPY.EXE SOURCE-DIR TARGET-DIR *.* /MOV /MINAGE:30 /PURGE

В этом примере он работает, выбирая все файлы (. ) старше 30 дней и перемещая их в целевую папку. Вторая команда делает то же самое снова с добавлением команды PURGE , которая означает удаление файлов в целевой папке, которых нет в исходной папке. По сути, первая команда перемещает файлы, а вторая удаляет, потому что они больше не существуют в исходной папке при вызове второй команды.

Обратитесь к документации ROBOCOPY и используйте переключатель / L при тестировании.

Answer 8

Расширяя ответ аку, я вижу много людей, спрашивающих о путях UNC. Простое сопоставление пути unc с буквой диска порадует файлы. Сопоставление и отключение дисков можно выполнить программным способом, например, в командном файле.

net use Z: /delete
net use Z: \\unc\path\to\my\folder
forfiles /p Z: /s /m *.gz /D -7 /C "cmd /c del @path"

При этом будут удалены все файлы с расширением .gz старше 7 дней. Если вы хотите убедиться, что Z: не отображается ни перед чем другим, вы можете сделать что-то простое, как

net use Z: \\unc\path\to\my\folder
if %errorlevel% equ 0 (
    forfiles /p Z: /s /m *.gz /D -7 /C "cmd /c del @path"
) else (
    echo "Z: is already in use, please use another drive letter!"
)

Answer 9

в этом нет ничего удивительного, но мне нужно было сделать что-то подобное сегодня и запустить его как запланированное задание и т. Д.

командный файл, DelFilesOlderThanNDays.bat ниже с примером exec w / params:

DelFilesOlderThanNDays.bat 7 C: \ dir1 \ dir2 \ dir3 \ logs *. Log

echo off
cls
Echo(
SET keepDD=%1
SET logPath=%2 :: example C:\dir1\dir2\dir3\logs
SET logFileExt=%3
SET check=0
IF [%3] EQU [] SET logFileExt=*.log & echo: file extention not specified (default set to "*.log")
IF [%2] EQU [] echo: file directory no specified (a required parameter), exiting! & EXIT /B 
IF [%1] EQU [] echo: number of days not specified? :)
echo(
echo: in path [ %logPath% ]
echo: finding all files like [ %logFileExt% ]
echo: older than [ %keepDD% ] days
echo(
::
::
:: LOG
echo:  >> c:\trimLogFiles\logBat\log.txt
echo: executed on %DATE% %TIME% >> c:\trimLogFiles\logBat\log.txt
echo: ---------------------------------------------------------- >> c:\trimLogFiles\logBat\log.txt
echo: in path [ %logPath% ] >> c:\trimLogFiles\logBat\log.txt
echo: finding all files like [ %logFileExt% ] >> c:\trimLogFiles\logBat\log.txt
echo: older than [ %keepDD% ] days >> c:\trimLogFiles\logBat\log.txt
echo: ---------------------------------------------------------- >> c:\trimLogFiles\logBat\log.txt
::
FORFILES /p %logPath% /s /m %logFileExt% /d -%keepDD% /c "cmd /c echo @path" >> c:\trimLogFiles\logBat\log.txt 2<&1
IF %ERRORLEVEL% EQU 0 (
 FORFILES /p %logPath% /s /m %logFileExt% /d -%keepDD% /c "cmd /c echo @path"
)
::
::
:: LOG
IF %ERRORLEVEL% EQU 0 (
 echo:  >> c:\trimLogFiles\logBat\log.txt
 echo: deleting files ... >> c:\trimLogFiles\logBat\log.txt
 echo:  >> c:\trimLogFiles\logBat\log.txt
 SET check=1
)
::
::
IF %check% EQU 1 (
 FORFILES /p %logPath% /s /m %logFileExt% /d -%keepDD% /c "cmd /c del @path"
)
::
:: RETURN & LOG
::
IF %ERRORLEVEL% EQU 0 echo: deletion successfull! & echo: deletion successfull! >> c:\trimLogFiles\logBat\log.txt
echo: ---------------------------------------------------------- >> c:\trimLogFiles\logBat\log.txt

Answer 10

Возможно, вам удастся это осуществить. Вы можете взглянуть на этот вопрос , для более простого примера. Сложность наступает, когда вы начинаете сравнивать даты. Может быть легко определить, является ли дата большей или нет, но есть много ситуаций, которые нужно учитывать, если вам нужно получить разницу между двумя датами.

Другими словами - не пытайтесь изобретать это, если вы действительно не можете использовать сторонние инструменты.