Как мне выводить и отправлять вывод консоли на файл в скрипте bat?

Question

У меня есть пакетный скрипт, который выполняет задачу и отправляет вывод в текстовый файл. Можно ли отобразить вывод в окне консоли?

Например:

c:\Windows>dir > windows-dir.txt

Есть ли способ отобразить вывод dir в окне консоли и поместить его в текстовый файл?

Answer 1

Нет, вы не можете с чистым перенаправлением.
Но с некоторыми хитростями (например, tee.bat ) вы можете.

Я пытаюсь немного объяснить перенаправление.

Вы перенаправляете один из десяти потоков с помощью > file или
Это неважно, если перенаправление происходит до или после команды, поэтому эти две строки почти одинаковы.

dir > file.txt
> file.txt dir

Перенаправление в этом примере является только ярлыком для 1> , это означает, что поток 1 (STDOUT) будет перенаправлен.
Таким образом, вы можете перенаправить любой поток с добавлением числа, например 2> err.txt , и также разрешено перенаправлять несколько потоков в одну строку.

dir 1> files.txt 2> err.txt 3> nothing.txt

В этом примере «стандартный вывод» будет помещен в файл files.txt, все ошибки будут в файле err.txt, а stream3 - в none.txt (DIR не использует поток 3).
Stream0 - это STDIN
Stream1 является STDOUT
Stream2 is STDERR
Stream3-9 не используются

Но что произойдет, если вы попытаетесь перенаправить один и тот же поток несколько раз?

dir > files.txt > two.txt

«Может быть только один», и он всегда последний!
Таким образом, он равен dir> two.txt

Хорошо, есть еще одна возможность, перенаправить поток в другой поток.

dir 1>files.txt 2>&1 

2> & 1 перенаправляет stream2 в stream1, а 1> files.txt перенаправляет все в files.txt .
Здесь важен порядок!

dir ... 1>nul 2>&1
dir ... 2>&1 1>nul

разные. Первый перенаправляет все (STDOUT и STDERR) в NUL,
но вторая строка перенаправляет STDOUT в NUL, а STDERR в «пустой» STDOUT.

В качестве одного из выводов очевидно, что примеры Otávio Décio и andynormancx не могут работать.

command > file >&1
dir > file.txt >&2

Оба пытаются перенаправить stream1 два раза, но «может быть только один», и он всегда последний.
Итак, вы получите

command 1>&1
dir 1>&2

И в первом примере перенаправление stream1 на stream1 не разрешено (и не очень полезно).

Надеюсь, это поможет.

Answer 2

Просто используйте Windows-версию команды UNIX tee (можно найти в http://unxutils.sourceforge.net) следующим образом:

mycommand > tee outpu_file.txt

Если вам также нужен выход STDERR, используйте следующее.
2>&1 объединяет вывод STDERR в STDOUT (основной поток).

mycommand 2>&1 | tee output_file.txt

Answer 3

Если вам не нужен вывод в реальном времени (то есть, когда программа его пишет), вы можете добавить

type windows-dir.txt

после этой строки.

Answer 4

Решение, которое работало для меня, было: dir> a.txt | введите a.txt .

Answer 5

Да, есть способ показать вывод одной команды на консоли (экране) и в файле. Используя ваш пример, используйте ...

@ECHO OFF
FOR /F "tokens=*" %%I IN ('DIR') DO ECHO %%I & ECHO %%I>>windows-dir.txt

Подробное объяснение:

Команда FOR анализирует выходные данные команды или текста в переменную, на которую можно ссылаться несколько раз.

Для команды, такой как DIR /B, заключите в одинарные кавычки, как показано в примере ниже. Замените текст DIR /B на желаемую команду.

FOR /F "tokens=*" %%I IN ('DIR /B') DO ECHO %%I & ECHO %%I>>FILE.TXT

Для отображения текста заключите текст в двойные кавычки, как показано в примере ниже.

FOR /F "tokens=*" %%I IN ("Find this text on console (screen) and in file") DO ECHO %%I & ECHO %%I>>FILE.TXT

... и с переносом строк ...

FOR /F "tokens=*" %%I IN ("Find this text on console (screen) and in file") DO (
  ECHO %%I & ECHO %%I>>FILE.TXT
)

Если у вас есть моменты, когда вы хотите, чтобы вывод выводился только на консоли (на экране), и другие разы, отправленные только в файл, и другие разы, отправляемые в оба, укажите условие «DO» цикла FOR с использованием переменной, как показано ниже с %TOECHOWHERE%.

@ECHO OFF
FOR %%I IN (TRUE FALSE) DO (
  FOR %%J IN (TRUE FALSE) DO (
    SET TOSCREEN=%%I & SET TOFILE=%%J & CALL :Runit)
)
GOTO :Finish

:Runit
  REM Both TOSCREEN and TOFILE get assigned a trailing space in the FOR loops
  REM above when the FOR loops are evaluating the first item in the list,
  REM "TRUE".  So, the first value of TOSCREEN is "TRUE " (with a trailing
  REM space), the second value is "FALSE" (no trailing or leading space).
  REM Adding the ": =" text after "TOSCREEN" tells the command processor to
  REM remove all spaces from the value in the "TOSCREEN" variable.
  IF "%TOSCREEN: =%"=="TRUE" (
      IF "%TOFILE: =%"=="TRUE" (
          SET TEXT=On screen, and in "FILE.TXT"
          SET TOECHOWHERE="ECHO %%I & ECHO %%I>>FILE.TXT"
        ) ELSE (
          SET TEXT=On screen, not in "FILE.TXT"
          SET TOECHOWHERE="ECHO %%I"
      )
    ) ELSE (
      IF "%TOFILE: =%"=="TRUE" (
          SET TEXT=Not on screen, but in "FILE.TXT"
          SET TOECHOWHERE="ECHO %%I>>FILE.txt"
        ) ELSE (
          SET TEXT=Not on screen, nor in "FILE.TXT"
          SET TOECHOWHERE="ECHO %%I>NUL"
      )
  )
  FOR /F "tokens=*" %%I IN ("%TEXT%") DO %TOECHOWHERE:~1,-1%
GOTO :eof

:Finish
  ECHO Finished [this text to console (screen) only].
  PAUSE

Answer 6

command > file >&1

Answer 7

Если вы хотите добавить вместо замены выходной файл, вы можете использовать

dir 1>> files.txt 2>> err.txt

или

dir 1>> files.txt 2>>&1

Answer 8

Я сделал простую консоль C #, которая может обрабатывать вывод в реальном времени как на экран cmd, так и в журнал

class Tee
{
    static int Main(string[] args)
    {
        try
        {
            string logFilePath = Path.GetFullPath(args[0]);

            using (StreamWriter writer = new StreamWriter(logFilePath, true))
            {
                for (int value; (value = Console.In.Read()) != -1;)
                {
                    var word = Char.ConvertFromUtf32(value);
                    Console.Write(word);
                    writer.Write(word);
                }
            }
        }
        catch (Exception)
        {
            return 1;
        }
        return 0;
    }
}

Использование командного файла такое же, как и при использовании Unix tee

foo | tee xxx.log

А вот репозиторий, в который входит Tee.exe, если у вас нет инструмента для компиляции https://github.com/iamshiao/Tee

Answer 9

Мой вариант был такой:

Создайте подпрограмму, которая принимает сообщение и автоматизирует процесс отправки его как в консоль, так и в файл журнала.

setlocal
set logfile=logfile.log

call :screenandlog "%DATE% %TIME% This message goes to the screen and to the log"    

goto :eof

:screenandlog
set message=%~1
echo %message% & echo %message% >> %logfile%
exit /b

Если вы добавляете в сообщение переменную, обязательно удалите кавычки в нем перед отправкой в ​​подпрограмму, иначе она может испортить вашу партию. Конечно, это работает только для эха.

Answer 10

Мне нравится ответ atn, но скачать его было не так тривиально, как wintee , который также является открытым исходным кодом и дает только функциональность тройника (полезно, если вы просто хотите использовать тройник, а не весь набор утилит unix). Я узнал об этом из ответа Давора на Отображение вывода командной строки Windows и перенаправление его в файл , где вы также найдете ссылку на утилиты unix.