Простой способ распечатать массив Perl?(с небольшим форматированием)

Question

Есть ли простой способ распечатать массив Perl с запятыми между каждым элементом?

Написать цикл for довольно просто, но не совсем элегантно .... если это имеет смысл.

Answer 1

Просто используйте join():

# assuming @array is your array:
print join(", ", @array);

Answer 2

Вы можете использовать Data::Dump:

use Data::Dump qw(dump);
my @a = (1, [2, 3], {4 => 5});
dump(@a);

Производит:

"(1, [2, 3], { 4 => 5 })"

Answer 3

Если вы кодируете вид ясности, который будет понят тем, кто только начинает работать с Perl, традиционная конструкция this с высокой степенью ясности и разборчивости говорит, что это означает:

$string = join ', ', @array;
print "$string\n";

Эта конструкция задокументирована в perldoc -fjoin.

Однако мне всегда нравилось, как просто $, делает это.Специальная переменная $" предназначена для интерполяции, а специальная переменная $, - для списков.Объедините любой из них с динамическим ограничением области действия 'local', чтобы избежать появления волновых эффектов в сценарии:

use 5.012_002;
use strict;
use warnings;

my @array = qw/ 1 2 3 4 5 /;

{
    local $" = ', ';
    print "@array\n"; # Interpolation.
}

ИЛИ с $,:

use feature q(say);
use strict;
use warnings;

my @array = qw/ 1 2 3 4 5 /;
{
    local $, = ', ';
    say @array; # List
}

Специальные переменные $, и $" задокументированы в perlvar .Ключевое слово local и способы его использования для ограничения последствий изменения значения глобальной переменной пунктуации, вероятно, лучше всего описано в perlsub .

Наслаждайтесь!

Answer 4

Также вы можете попробовать Data :: Dumper . Пример:

use Data::Dumper;

# simple procedural interface
print Dumper($foo, $bar);

Answer 5

Для проверки / отладки проверьте модуль Data::Printer. Он предназначен для выполнения одной и только одной вещи:

отображение переменных и объектов Perl на экране, правильно отформатированных (для быть проверенным человеком)

Пример использования:

use Data::Printer;  
p @array;  # no need to pass references

Приведенный выше код может выводить что-то вроде этого (с цветами!):

   [
       [0] "a",
       [1] "b",
       [2] undef,
       [3] "c",
   ]

Answer 6

Вы можете просто print это.

@a = qw(abc def hij);

print "@a";

Вы получите:

abc def hij

Answer 7

# better than Dumper --you're ready for the WWW....

use JSON::XS;
print encode_json \@some_array

Answer 8

Я не пытался бежать ниже, хотя.Я думаю, что это хитрый способ.

map{print $_;} @array;

Answer 9

Карта также может быть использована, но иногда трудно читать, когда у вас много чего происходит.

map{ print "element $_\n" }   @array; 

Answer 10

Возможно, это не то, что вы ищете, но вот что я сделал для задания:

$" = ", ";
print "@ArrayName\n";