Почему количество страниц в документе Word различается в Perl и Word VBA? - PullRequest
Новая
       32

Почему количество страниц в документе Word различается в Perl и Word VBA?

2 голосов
/ 04 мая 2009

У меня есть (набор) документов Word, для которых я пытаюсь получить различные свойства (количество страниц, автора и т. Д.), Используя Win32 :: OLE в Perl: 

print $MSWord->Documents->Open($name)->
BuiltInDocumentProperties->{"Number of pages"}->value . " \n";

Это возвращает 4 страницы. Но фактическое количество страниц в документе - 9. Количество страниц в первом разделе - 4. Я хочу общее количество страниц в документе.

Если в Word VBA я делаю следующее: 

MsgBox ActiveDocument.BuiltInDocumentProperties("Number of pages")

Отображается 9. Количество страниц, отображаемых на странице свойств / статистики, равно 9.

Нужно ли принудительно пересчитывать? Есть ли способ попросить библиотеку OLE принудительно пересчитать или мне нужно обрабатывать каждый раздел отдельно?

Я нахожусь на XP, Word 2007, ActivePerl v5.10.0.

1 Ответ

4 голосов
/ 04 мая 2009 
#!/usr/bin/perl

use strict;
use warnings;

use File::Spec::Functions qw( catfile );

use Win32::OLE;
use Win32::OLE::Const 'Microsoft Word';
$Win32::OLE::Warn = 3;

my $word = get_word();
$word->{Visible} = 1;

my $doc = $word->{Documents}->Open(catfile $ENV{TEMP}, 'test.doc');
$doc->Repaginate;

my $props = $doc->BuiltInDocumentProperties;
my $x = $props->Item(wdPropertyPages)->valof;
print "$x\n";

$doc->Close(0);

sub get_word {
    my $word;
    eval {
        $word = Win32::OLE->GetActiveObject('Word.Application');
    };

    die "$@\n" if $@;

    unless(defined $word) {
        $word = Win32::OLE->new('Word.Application', sub { $_[0]->Quit })
            or die "Oops, cannot start Word: ", 
                   Win32::OLE->LastError, "\n";
    }
    return $word;
}
...