Как я могу передать аргументы в командный файл?

Question

Мне нужно передать идентификатор и пароль в пакетный файл во время выполнения, а не жестко кодировать их в файл.

Вот как выглядит командная строка:

test.cmd admin P@55w0rd > test-log.txt

Answer 1

Еще один полезный совет - использовать %* для обозначения «все». Например:

echo off
set arg1=%1
set arg2=%2
shift
shift
fake-command /u %arg1% /p %arg2% %*

При запуске:

test-command admin password foo bar

будет запущен вышеуказанный пакетный файл:

fake-command /u admin /p password admin password foo bar

Возможно, у меня немного неправильный синтаксис, но это общая идея.

Answer 2

Вот как я это сделал:

@fake-command /u %1 /p %2

Вот как выглядит команда:

test.cmd admin P@55w0rd > test-log.txt

%1 применяется к первому параметру, %2 (и здесь сложная часть) применяется ко второму. Таким способом можно передать до 9 параметров.

Answer 3

Если вы хотите разумно обрабатывать пропущенные параметры, вы можете сделать что-то вроде:

IF %1.==. GOTO No1
IF %2.==. GOTO No2
... do stuff...
GOTO End1

:No1
  ECHO No param 1
GOTO End1
:No2
  ECHO No param 2
GOTO End1

:End1

Answer 4

Доступ к параметрам пакета может быть простым с% 1,% 2, ...% 9 или также% *,
но только если содержание простое.

Не существует простого способа для сложного содержимого, такого как "&"^&, так как невозможно получить доступ к% 1 без возникновения ошибки.

set  var=%1
set "var=%1"
set  var=%~1
set "var=%~1"

Строки расширяются до

set  var="&"&
set "var="&"&"
set  var="&"&
set "var="&"&"

И каждая строка терпит неудачу, так как один из & находится вне кавычек.

Это можно решить, прочитав из временного файла замеченную версию параметра.

@echo off
SETLOCAL DisableDelayedExpansion

SETLOCAL
for %%a in (1) do (
    set "prompt="
    echo on
    for %%b in (1) do rem * #%1#
    @echo off
) > param.txt
ENDLOCAL

for /F "delims=" %%L in (param.txt) do (
  set "param1=%%L"
)
SETLOCAL EnableDelayedExpansion
set "param1=!param1:*#=!"
set "param1=!param1:~0,-2!"
echo %%1 is '!param1!'

Хитрость заключается в том, чтобы включить echo on и расширить% 1 после оператора rem (работает также с %2 .. %*).
Таким образом, даже "&"& может отображаться без ошибок, как отмечается.

Но чтобы перенаправить вывод echo on, вам нужны два цикла for.

Дополнительные символы * # используются для защиты от содержимого, такого как /? (отображает справку для REM).
Или символ ^ в конце строки может работать как многострочный символ, даже после rem.

Затем читаем вывод rem параметра из файла, но внимательно.
FOR / F должен работать с отложенным расширением, иначе содержимое с "!" будет уничтожен.
После удаления лишних символов в param1 вы получили его.

И для безопасного использования param1 включите отложенное расширение.

Answer 5

Да, и просто не забудьте использовать переменные типа %%1 при использовании if и for и банды.

Если вы забудете двойное %, то вы будете подставлять (возможно, нулевые) аргументы командной строки и получите несколько довольно запутанных сообщений об ошибках.

Answer 6

Нет необходимости усложнять это. Это просто команда% 1% 2 параметров, например,

@echo off

xcopy %1 %2 /D /E /C /Q /H /R /K /Y /Z

echo copied %1 to %2

pause

«Пауза» показывает, что пакетный файл сделал, и ждет, когда вы нажмете ЛЮБУЮ клавишу. Сохраните его как xx.bat в папке Windows.

Чтобы использовать его, наберите, например:

xx c:\f\30\*.* f:\sites\30

Этот пакетный файл заботится обо всех необходимых параметрах, таких как копирование только тех файлов, которые новее и т. Д. Я использовал его еще до Windows. Если вам нравится видеть имена файлов во время их копирования, пропустите параметр Q.

Answer 7

@ECHO OFF
:Loop
IF "%1"=="" GOTO Continue
SHIFT
GOTO Loop
:Continue

Примечание: ЕСЛИ "%1"=="" вызовет проблемы, если %1 заключено в кавычки.

В этом случае используйте IF [%1]==[] или в NT 4 (SP6) и более поздних версиях IF "%~1"=="" вместо.

Answer 8

Мой друг недавно спрашивал меня об этой теме, поэтому я решил опубликовать, как мне обрабатывать аргументы командной строки в пакетных файлах.

Как вы увидите, эта техника имеет некоторые накладные расходы, но она делает мои командные файлы очень простыми для понимания и быстрыми в реализации. А также поддерживая следующие структуры:

>template.bat [-f] [--flag] [/f] [--namedvalue value] arg1 [arg2][arg3][...]

Jist имеет функции :init, :parse и :main.

Пример использования

>template.bat /?
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

USAGE:
test.bat [flags] "required argument" "optional argument"

/?, --help           shows this help
/v, --version        shows the version
/e, --verbose        shows detailed output
-f, --flag value     specifies a named parameter value

>template.bat          <- throws missing argument error
(same as /?, plus..)
****                                   ****
****    MISSING "REQUIRED ARGUMENT"    ****
****                                   ****

>template.bat -v
1.23

>template.bat --version
test v1.23
This is a sample batch file template,
providing command-line arguments and flags.

>template.bat -e arg1
**** DEBUG IS ON
UnNamedArgument:    "arg1"
UnNamedOptionalArg: not provided
NamedFlag:          not provided

>template.bat --flag "my flag" arg1 arg2
UnNamedArgument:    "arg1"
UnNamedOptionalArg: "arg2"
NamedFlag:          "my flag"

>template.bat --verbose "argument #1" --flag "my flag" second
**** DEBUG IS ON
UnNamedArgument:    "argument #1"
UnNamedOptionalArg: "second"
NamedFlag:          "my flag"

template.bat

@::!/dos/rocks
@echo off
goto :init

:header
    echo %__NAME% v%__VERSION%
    echo This is a sample batch file template,
    echo providing command-line arguments and flags.
    echo.
    goto :eof

:usage
    echo USAGE:
    echo   %__BAT_NAME% [flags] "required argument" "optional argument" 
    echo.
    echo.  /?, --help           shows this help
    echo.  /v, --version        shows the version
    echo.  /e, --verbose        shows detailed output
    echo.  -f, --flag value     specifies a named parameter value
    goto :eof

:version
    if "%~1"=="full" call :header & goto :eof
    echo %__VERSION%
    goto :eof

:missing_argument
    call :header
    call :usage
    echo.
    echo ****                                   ****
    echo ****    MISSING "REQUIRED ARGUMENT"    ****
    echo ****                                   ****
    echo.
    goto :eof

:init
    set "__NAME=%~n0"
    set "__VERSION=1.23"
    set "__YEAR=2017"

    set "__BAT_FILE=%~0"
    set "__BAT_PATH=%~dp0"
    set "__BAT_NAME=%~nx0"

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedOptionalArg="
    set "NamedFlag="

:parse
    if "%~1"=="" goto :validate

    if /i "%~1"=="/?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="-?"         call :header & call :usage "%~2" & goto :end
    if /i "%~1"=="--help"     call :header & call :usage "%~2" & goto :end

    if /i "%~1"=="/v"         call :version      & goto :end
    if /i "%~1"=="-v"         call :version      & goto :end
    if /i "%~1"=="--version"  call :version full & goto :end

    if /i "%~1"=="/e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="-e"         set "OptVerbose=yes"  & shift & goto :parse
    if /i "%~1"=="--verbose"  set "OptVerbose=yes"  & shift & goto :parse

    if /i "%~1"=="--flag"     set "NamedFlag=%~2"   & shift & shift & goto :parse

    if not defined UnNamedArgument     set "UnNamedArgument=%~1"     & shift & goto :parse
    if not defined UnNamedOptionalArg  set "UnNamedOptionalArg=%~1"  & shift & goto :parse

    shift
    goto :parse

:validate
    if not defined UnNamedArgument call :missing_argument & goto :end

:main
    if defined OptVerbose (
        echo **** DEBUG IS ON
    )

    echo UnNamedArgument:    "%UnNamedArgument%"

    if defined UnNamedOptionalArg      echo UnNamedOptionalArg: "%UnNamedOptionalArg%"
    if not defined UnNamedOptionalArg  echo UnNamedOptionalArg: not provided

    if defined NamedFlag               echo NamedFlag:          "%NamedFlag%"
    if not defined NamedFlag           echo NamedFlag:          not provided

:end
    call :cleanup
    exit /B

:cleanup
    REM The cleanup function is only really necessary if you
    REM are _not_ using SETLOCAL.
    set "__NAME="
    set "__VERSION="
    set "__YEAR="

    set "__BAT_FILE="
    set "__BAT_PATH="
    set "__BAT_NAME="

    set "OptHelp="
    set "OptVersion="
    set "OptVerbose="

    set "UnNamedArgument="
    set "UnNamedArgument2="
    set "NamedFlag="

    goto :eof

Answer 9

Давайте сделаем это просто.

Вот файл .cmd.

@echo off
rem this file is named echo_3params.cmd
echo %1
echo %2
echo %3
set v1=%1
set v2=%2
set v3=%3
echo v1 equals %v1%
echo v2 equals %v2%
echo v3 equals %v3%

Здесь 3 вызова из командной строки.

C:\Users\joeco>echo_3params 1abc 2 def  3 ghi
1abc
2
def
v1 equals 1abc
v2 equals 2
v3 equals def

C:\Users\joeco>echo_3params 1abc "2 def"  "3 ghi"
1abc
"2 def"
"3 ghi"
v1 equals 1abc
v2 equals "2 def"
v3 equals "3 ghi"

C:\Users\joeco>echo_3params 1abc '2 def'  "3 ghi"
1abc
'2
def'
v1 equals 1abc
v2 equals '2
v3 equals def'

C:\Users\joeco>

Answer 10

FOR %%A IN (%*) DO (
    REM Now your batch file handles %%A instead of %1
    REM No need to use SHIFT anymore.
    ECHO %%A
)

Это циклически повторяет пакетные параметры (% *), независимо от того, указаны они в кавычках или нет, а затем отображает каждый параметр.