Изменить определенные поля BSEG из обычной структурированной таблицы - PullRequest
Новая
       9

Изменить определенные поля BSEG из обычной структурированной таблицы

0 голосов
/ 27 августа 2018

Я пытаюсь использовать следующее: 

update bseg from zbseg

, если таблицы не одинаковой длины (ZBSEG сокращенная версия BSEG).

Идея в том, что BSEG это просто пример, у меня есть цикл, в котором все таблицы кластеров будут повторяться, поэтому все должно быть динамически.

Данные таблицы из кластера сокращаются до нескольких полей и копируются в прозрачную таблицу (словарь данных в новой прозрачной таблице имеет первичные ключи + только несколько полей кластера), после чего данные в БД будут модифицироваться и копироваться обратно через UPDATE в кластер. 

update bseg from zbseg

этот оператор обновляет значения полей с ZBSEG, но для остальных не будет сохранять старые значения, а скорее помещает начальные значения.

Я пробовал даже это: 

SELECT *
FROM bseg
INTO TABLE gt_bseg.

SELECT mandt bukrs belnr gjahr buzei buzid augdt
FROM zbseg
INTO CORRESPONDING FIELDS OF TABLE gt_bseg.

но он все еще перекрывает те поля, которые не рассматриваются в zbseg.

Любой оператор, который обновит только определенный диапазон полей, извлеченных из ZBSEG, не затрагивая другие BSEG поля?

IMAGE: Looping over original full length and short table

Ответы [ 3 ]

0 голосов
/ 28 августа 2018

Вы можете попытаться использовать инструкцию MODIFY для обновления таблиц.

Другой способ сделать это - использовать cl_abap_typedescr , чтобы получить поля каждой таблицы и сравнить их для обновления.

Вот пример того, как получить поля. 

DATA : ref_table_des TYPE REF TO cl_abap_structdescr,
       columns TYPE abap_compdescr_tab.

ref_table_des ?= cl_abap_typedescr=>describe_by_data( struc ).
columns = ref_table_des->components[].
0 голосов
/ 09 июля 2019

Вот фрагмент кода, который вы можете использовать для своей задачи. Он основан на динамическом операторе UPDATE, который позволяет обновлять только определенные поля: 

DATA: handle      TYPE REF TO data,
      lref_struct TYPE REF TO cl_abap_structdescr,
      source      TYPE string,
      columns     TYPE string,
      keys        TYPE string,
      cond        TYPE string,
      sets        TYPE string.

SELECT tabname FROM dd02l INTO TABLE @DATA(clusters) WHERE tabclass = 'CLUSTER'.

LOOP AT clusters ASSIGNING FIELD-SYMBOL(<cluster>).
  lref_struct ?= cl_abap_structdescr=>describe_by_name( <cluster>-tabname ).
  source = 'Z' && <cluster>-tabname. " name of your ZBSEG-like table
* get key fields
  DATA(key_fields) = VALUE ddfields( FOR line IN lref_struct->get_ddic_field_list( ) 
                                     WHERE ( keyflag NE space ) ( line ) ).
  lref_struct ?= cl_abap_structdescr=>describe_by_name( source ).
* get all fields from source reduced table
  DATA(fields) = VALUE ddfields( FOR line IN lref_struct->get_ddic_field_list( ) ( line ) ).

* filling SELECT fields and SET clause
  LOOP AT fields ASSIGNING FIELD-SYMBOL(<field>).
    AT FIRST.
      columns = <field>-fieldname.
      CONTINUE.
    ENDAT.
    CONCATENATE columns <field>-fieldname INTO columns SEPARATED BY `, `.
    IF NOT line_exists( key_fields[ fieldname = <field>-fieldname ] ).
      IF sets IS INITIAL.
        sets = <field>-fieldname && ` = @<fsym_wa>-` && <field>-fieldname.
      ELSE.
        sets = sets && `, ` && <field>-fieldname && ` = @<fsym_wa>-` && <field>-fieldname.
      ENDIF.
    ENDIF.
  ENDLOOP.

* filling key fields and conditions
  LOOP AT key_fields ASSIGNING <field>.
    AT FIRST.
      keys = <field>-fieldname.
      CONTINUE.
    ENDAT.
    CONCATENATE keys <field>-fieldname INTO keys SEPARATED BY `, `.
    IF cond IS INITIAL.
      cond = <field>-fieldname && ` = @<fsym_wa>-` && <field>-fieldname.
    ELSE.
      cond = cond && ` AND ` && <field>-fieldname && ` = @<fsym_wa>-` && <field>-fieldname.
    ENDIF.
  ENDLOOP.

* constructing reduced table type
  lref_struct ?= cl_abap_typedescr=>describe_by_name( source ).
  CREATE DATA handle TYPE HANDLE lref_struct.
  ASSIGN handle->*  TO FIELD-SYMBOL(<fsym_wa>).

* updating result cluster table
  SELECT (columns)
    FROM (source)
    INTO @<fsym_wa>.
  UPDATE (<cluster>-tabname)
  SET (sets)
  WHERE (cond).
  ENDSELECT.

ENDLOOP.

Эта часть выбирает все таблицы кластеров из DD02L и предполагает, что вы уменьшили таблицу БД с префиксом Z для каждой целевой таблицы кластеров. Например. ZBSEG для BSEG , ZBSET для BSET , ZKONV для KONV и т. Д. .

Таблицы обновляются по первичному ключу, который должен быть включен в сокращенную таблицу. Поля, которые должны быть обновлены, взяты из уменьшенной таблицы как все поля, исключая ключевые поля, поскольку первичный ключ запрещен для обновления.

0 голосов
/ 27 августа 2018

Я думаю, вам нужно получить записи из zbseg с ограничением, потому что будет существовать миллион записей, затем получить их от bseg одну за другой и обновить их, а затем удалить или обновить флаги из zbseg для производительности. 

tables: BSEG, ZBSEG.

data: GT_ZBSEG like ZBSEG occurs 1 with header line,
      GS_BSEG type BSEG.

select *
into table GT_ZBSEG up to 1000 rows
from ZBSEG.

check SY-SUBRC is initial.
check SY-DBCNT is not initial.

loop at GT_ZBSEG.
  select single * from BSEG into GS_BSEG
  where BSEG~MANDT = GT_ZBSEG-MANDT
    and BSEG~BUKRS = GT_ZBSEG-BUKRS
    and BSEG~BELNR = GT_ZBSEG-BELNR
    and BSEG~GJAHR = GT_ZBSEG-GJAHR
    and BSEG~BUZEI = GT_ZBSEG-BUZEI.
  if SY-SUBRC ne 0.
    message E208(00) with 'Record not found!'.
  endif.
  if GS_BSEG-BUZID ne GT_ZBSEG-BUZID
  or GS_BSEG-AUGDT ne GT_ZBSEG-AUGDT.
    move-corresponding GT_ZBSEG to GS_BSEG.
    update BSEG from GS_BSEG.
  endif.
  " delete same records and transfered
  delete ZBSEG from GT_ZBSEG.
endloop.
...