Нахождение xmlns с помощью xsl / xpath - PullRequest
Новая
       15

Нахождение xmlns с помощью xsl / xpath

4 голосов
/ 23 августа 2009

Я пытаюсь получить список информации для корневого элемента XML-документа, используя преобразование. Части, которые я не могу понять:

Как получить URL-адрес пространства имен по умолчанию?

Как получить список каждого префикса xmlns и соответствующего URL-адреса?

Вот мой xml-файл: 

<?xml version="1.0" encoding="UTF-8"?>
<?xml-stylesheet type="text/xsl" href="/example.xsl"?>
<foo:mytag xmlns="http://default.example.com/" 
           xmlns:foo="http://foo.example.com/" 
           xmlns:bar="http://bar.example.com">
</foo:mytag>

А вот мой xsl-файл: 

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output
     doctype-public="-//W3C//DTD XHTML 1.1//EN"
     doctype-system="http://www.w3.org/TR/xhtml11/DTD/xhtml11.dtd"
     encoding="UTF-8"
     indent="yes"
     method="xml"
     omit-xml-declaration="no"
     version="1.0" />

    <xsl:template match="/">
        <html xmlns="http://www.w3.org/1999/xhtml">
            <head>
                <title></title>
            </head>
            <body>
                default namespace - <b>???</b><br />
                full tag name - <b><xsl:value-of select="name(*)"/></b><br />
                xmlns for tag - <b><xsl:value-of select="namespace-uri(*)"/></b><br />
                tag prefix - <b>???</b><br />
                tag name - <b><xsl:value-of select="local-name(*)"/></b><br />
                List of xmlns - <br />
                ????
            </body>
        </html>
</xsl:template>

Это преобразование выполняется в браузере. В основном то, что я ожидаю в результате: 

default namespace - http://default.example.com/
full tag name - foo:mytag
xmlns for tag - http://foo.example.com/
tag prefix - foo
tag name - mytag
List of xmlns -
        - http://default.example.com/
    foo - http://foo.example.com/
    bar - http://bar.example.com/

Я что-то упускаю, чтобы заполнить недостающие данные?

1 Ответ

5 голосов
/ 24 августа 2009

Я думаю, это примерно то, что вы хотите. XSLT 1.0 - протестировано в XMLSpy 

<xsl:template match="/">
    <html xmlns="http://www.w3.org/1999/xhtml">
        <head>
            <title></title>
        </head>
        <body>
            default namespace - <b><xsl:value-of select="*/namespace::*[not (name())]"/></b><br />
            full tag name - <b><xsl:value-of select="name(*)"/></b><br />
            xmlns for tag - <b><xsl:value-of select="namespace-uri(*)"/></b><br />
            tag prefix - <b><xsl:value-of select="substring-before(name(*),':')" /></b><br />
            tag name - <b><xsl:value-of select="local-name(*)"/></b><br />
            List of xmlns - <br />
            <xsl:for-each select="*/namespace::*">
               <xsl:if test="not (name() = 'xml')"><xsl:text>
                   </xsl:text>
                   <xsl:value-of select="name()" /><xsl:text> - </xsl:text><xsl:value-of select="." /><br />
               </xsl:if>
            </xsl:for-each>
        </body>
    </html>
</xsl:template>
Добро пожаловать на сайт PullRequest, где вы можете задавать вопросы и получать ответы от других членов сообщества.

Нет похожих вопросов

...