Как установить цвет по умолчанию (цвет черепахи, когда ее вводят в модель) черепахи после того, как она изменит свой цвет?

Question

Я пишу строку кода, которая это

ask turtles [if count other turtles in-radius 1 > 5 [set color white]]

теперь, когда черепаха изменила цвет на белый, но через определенное время это свойство не соответствует действительности для той же черепахи, ей следует изменить цвет на цвет по умолчанию? как я могу это исправить?

Answer 1

Я думаю, что вы после turtles-own счетчика, который уменьшается всякий раз, когда условие не выполняется. С этой настройкой:

turtles-own [ default-color countdown ]

to setup
  ca
  crt 150 [ 
    setxy random-xcor random-ycor 
    set default-color blue
    set color default-color
  ]
  reset-ticks
end

Теперь вы можете заставить своих черепах бродить и менять их countdown переменную всякий раз, когда они меняют цвет. Когда это условие не выполнено, они могут уменьшить счетчик, пока он не достигнет нуля, после чего они могут вернуться к своему цвету по умолчанию. Подробнее в комментариях:

to go
  ask turtles [
    rt random 60 - 30
    fd 0.25

    ; if there are more than 5 turtles in radius 3,
    ; turn white and set countdown to 5   
    ifelse count other turtles in-radius 3 > 5 [
      set color white 
      set countdown 5
    ] [
      ; If not, and counter is greater than 0,
      ; decrease the counter. 
      if countdown > 0 [
        set countdown countdown - 1

        ; If counter gets down to 0, 
        ; set color back to the default.
        if countdown = 0 [
          set color default-color
        ]
      ]
    ]

  ]
  tick
end