Бинарные операции на двоичных файлах Erlang? - PullRequest
Новая
       31

Бинарные операции на двоичных файлах Erlang?

5 голосов
/ 17 декабря 2009

Какой лучший способ сделать следующее? Двоичный файл -> список -> двоичный файл кажется ненужным. 

binary_and(A, B) ->
    A2 = binary_to_list(A),
    B2 = binary_to_list(B),
    list_to_binary([U band V || {U, V} <- lists:zip(A2, B2)]).

Ответы [ 2 ]

3 голосов
/ 18 декабря 2009

Если вы хотите увидеть силу темной стороны ... 

binary_and(A, B) ->
  Size = erlang:byte_size(A),
  Size = erlang:byte_size(B),
  Res = hipe_bifs:bytearray(Size, 0),
  binary_and(Res, A, B, 0, Size).

binary_and(Res, _A, _B, Size, Size) ->
  Res.

binary_and(Res, A, B, N, Size) ->
  Bin = hipe_bifs:bytearray_sub(A, N) band hipe_bifs:bytearray_sub(B,N),
  hipe_bifs:bytearray_update(Res, N, Bin),
  binary_and(Res, A, B, N+1, Size).
3 голосов
/ 17 декабря 2009

Если вас не волнует производительность, ваш код абсолютно в порядке. В противном случае вы можете сделать что-то другое.

Например, Erlang поддерживает целые числа произвольного размера: 

binary_and(A, B) ->
  Size = bit_size(A),
  <<X:Size>> = A,
  <<Y:Size>> = B,
  <<(X band Y):Size>>.

Или вы можете создать свою собственную программу для двоичного почтового индекса: 

binary_and(A,B) -> binary_and(A, B, <<>>).

binary_and(<<A:8, RestA/bytes>>, <<B:8, RestB/bytes>>, Acc) ->
  binary_add(RestA, RestB, <<Acc/bytes, (A band B):8>>);
binary_and(<<>>, <<>>, Result) -> Result.

Или оптимизированная версия: 

binary_and(A,B) -> binary_and(A, B, <<>>).

binary_and(<<A:64, RestA/bytes>>, <<B:64, RestB/bytes>>, Acc) ->
  binary_add(RestA, RestB, <<Acc/bytes, (A band B):64>>);
binary_and(<<A:8, RestA/bytes>>, <<B:8, RestB/bytes>>, Acc) ->
  binary_add(RestA, RestB, <<Acc/bytes, (A band B):8>>);
binary_and(<<>>, <<>>, Result) -> Result.

или более изощренный 

binary_and(A,B) -> binary_and({A, B}, 0, <<>>).

binary_and(Bins, Index, Acc) ->
  case Bins of
    {<<_:Index/bytes, A:64, _/bytes>>, <<_:Index/bytes, B:64, _/bytes>>} ->
      binary_add(Bins, Index+8, <<Acc/bytes, (A band B):64>>);
    {<<_:Index/bytes, A:8, _/bytes>>, <<_:Index/bytes, B:8, _/bytes>>} ->
      binary_add(Bins, Index+1, <<Acc/bytes, (A band B):8>>);
    {<<_:Index/bytes>>, <<_:Index/bytes>>} -> Acc
  end.

В любом случае, вы должны измерить, действительно ли вы заинтересованы в производительности. Может быть первый самый быстрый для ваших целей.

...