Как получить более раннее значение на основе имени значения в столбце

Question

Я хотел бы получить значение предыдущего дня в зависимости от имени атрибута, следовательно, применяя двухуровневый фильтр к моему вычисляемому столбцу. В настоящее время я застрял в следующей формуле, оставив пустой столбец.

Column = CALCULATE(
                    MAX(useractivity[Value]),
                    FILTER(
                            useractivity,
                            useractivity[Dates]=EARLIER(useractivity[Dates])-1
                        ),
                    FILTER(
                        an IFS function maybe?
                    ))

Я хотел бы получить следующий вывод:

+------------------+-----------+---------+----------------+
|      Dates       | Attribute |  Value  | Previous_Value |
+------------------+-----------+---------+----------------+
| 31 december 2018 | active    | 100,000 |         80,000 |
| 31 december 2018 | inactive  |  50,000 |         40,000 |
| 29 december 2018 | active    |  80,000 |            ... |
| 29 december 2018 | inactive  |  40,000 |            ... |
+------------------+-----------+---------+----------------+

Answer 1

Это похоже на мой ответ здесь . Рассчитайте предыдущую дату, а затем выполните поиск.

Previous_Value =
VAR PrevDay =
    CALCULATE (
        LASTDATE ( useractivity[Dates] ),
        ALLEXCEPT ( useractivity, useractivity[Attribute] ),
        useractivity[Dates] < EARLIER ( useractivity[Dates] )
    )
RETURN
    LOOKUPVALUE (
        useractivity[Value],
        useractivity[Dates], PrevDay,
        useractivity[Attribute], useractivity[Attribute]
    )

---

Редактировать

В качестве меры вам понадобятся незначительные изменения,

Previous_Value = 
VAR PrevDay =
    CALCULATE (
        LASTDATE ( useractivity[Dates] ),
        FILTER(
            ALLEXCEPT ( useractivity, useractivity[Attribute] ),
            useractivity[Dates] < MAX( useractivity[Dates] )
        )
    )
RETURN
    LOOKUPVALUE (
        useractivity[Value],
        useractivity[Dates], PrevDay,
        useractivity[Attribute], MAX(useractivity[Attribute])
    )