Условная формула DAX с датами в Power BI - PullRequest
Новая
       13

Условная формула DAX с датами в Power BI

0 голосов
/ 08 января 2019

У меня есть несколько столбцов с датами (отформатирован как даты в моделировании PBI). Каждый столбец представляет этап («Начало» - «Завершить»). Мне нужен новый столбец, который показывает, на каком этапе находится каждая строка.

Пока у меня есть это: 

Procurement Stage = IF(Milestones[Close Project]<>"1/01/1900","Close 
Project",IF(Milestones[Enable The Contract]<>"1/01/1900","Enable The 
Contract",IF(Milestones[Award Contract]<>"1/01/1900","Award 
Contract",IF(Milestones[Recommend Offer]<>"1/01/1900","Recommend 
Offer",IF(Milestones[Evaluate Offers]<>"1/01/1900","Evaluate 
Offers",IF(Milestones[Implement Strategy]<>"1/01/1900","Implement 
Strategy",If(Milestones[Strategy Approval]<>"1/01/1900","Strategy 
Approval",IF(Milestones[Conduct Analysis]<>"1/01/1900","Conduct 
Analysis",IF(Milestones[Initiate Project]<>"1/01/1900","Initiate Project","Not 
Yet Started")))))))))

Приходит следующая ошибка:

Операции сравнения DAX не поддерживают сравнение значений типа Date со значениями типа Text. Попробуйте использовать функцию VALUE или FORMAT для преобразования одного из значений.

Я дважды проверил и убедился, что все столбцы имеют одинаковый формат - дата.

Может кто-нибудь помочь с этим?

Мне нужно это сделать в моделировании, поэтому мне нужно это в DAX.

Спасибо.

Евгений

1 Ответ

0 голосов
/ 08 января 2019

Попробуйте: 

Procurement Stage =
VAR My_Date = DATE ( 1900, 1, 1 )
RETURN
    SWITCH (
        TRUE(),
        Milestones[Close Project] <> My_Date, "Close Project",
        Milestones[Enable The Contract] <> My_Date, "Enable The Contract",
        Milestones[Award Contract] <> My_Date, "Award Contract",
        Milestones[Recommend Offer] <> My_Date, "Recommend Offer",
        Milestones[Evaluate Offers] <> My_Date, "Evaluate Offer",
        Milestones[Implement Strategy] <> My_Date, "Implement Strategy",
        Milestones[Strategy Approval] <> My_Date, "Strategy Approval",
        Milestones[Conduct Analysis] <> My_Date, "Conduct Analysis",
        Milestones[Initiate Project] <> My_Date, "Initiate Project",
        "Not Yet Started"
    )
...