XSLT 2.0: Как определить, существует ли хотя бы одно значение в списке? - PullRequest
Новая
       6

XSLT 2.0: Как определить, существует ли хотя бы одно значение в списке?

0 голосов
/ 29 июня 2018

XSLT и XML, показанные ниже, генерируют следующий вывод: 

<CodeGroupA>Found</CodeGroupA>
<CodeGroupB>Not found</CodeGroupB>
<CodeGroupA>Found</CodeGroupA>
<CodeGroupB>Not found</CodeGroupB>
<CodeGroupA>Not found</CodeGroupA>
<CodeGroupB>Not found</CodeGroupB>

Мне нужно сгенерировать этот вывод: 

<CodeGroupA>Found</CodeGroupA>
<CodeGroupB>Not found</CodeGroupB>

Я попробовал несколько различных методов, используя рекурсию и для каждого, но я не могу понять это. Любое предложение будет оценено.

Заранее спасибо.

Вот мой XSLT: 

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xs="http://www.w3.org/2001/XMLSchema"
  xmlns:math="http://www.w3.org/2005/xpath-functions/math"
  xmlns:map="http://www.w3.org/2005/xpath-functions/map"
  xmlns:array="http://www.w3.org/2005/xpath-functions/array"
  exclude-result-prefixes="xs math map array"
  version="3.0">

  <!-- input/output configuration -->
  <xsl:output method="xml" indent="yes" />
  <xsl:strip-space elements="*"/>

  <xsl:variable name="CodeGroupA" select="'12', '13'" />
  <xsl:variable name="CodeGroupB" select="'17', '18'" />

  <xsl:template match="/Diagnoses/Diagnosis" >

    <xsl:if test=".[Code=($CodeGroupA)]">
        <CodeGroupA>Found</CodeGroupA>
    </xsl:if>

    <xsl:if test="not(.[Code=($CodeGroupA)])">
        <CodeGroupA>Not found</CodeGroupA>
    </xsl:if>

    <xsl:if test=".[Code=($CodeGroupB)]">
        <CodeGroupB>Found</CodeGroupB>
    </xsl:if>

    <xsl:if test="not(.[Code=($CodeGroupB)])">
        <CodeGroupB>Not found</CodeGroupB>
    </xsl:if>
  </xsl:template>

  <xsl:template match="text()|@*">
  </xsl:template>

</xsl:stylesheet>

Вот мой входной XML: 

<?xml version="1.0" encoding="UTF-8"?>
<Diagnoses>
  <Diagnosis>
    <Code>12</Code>
  </Diagnosis>
  <Diagnosis>
    <Code>13</Code>
  </Diagnosis>
  <Diagnosis>
    <Code>14</Code>
  </Diagnosis>
</Diagnoses>

Ответы [ 2 ]

0 голосов
/ 29 июня 2018

Вы должны действительно соответствовать элементу Diagnoses, в противном случае вы получите что-то для каждого Diagnosis, что не совсем то, что вы хотите.

Но если вы сделаете это, вы можете получить желаемый результат, сделав это ... 

<CodeGroupA>
    <xsl:value-of select="if (Diagnosis/Code=$CodeGroupA) then 'Found' else 'Not found'" />
</CodeGroupA>

и аналогично для CodeGroupB.

Конечно, вы можете избежать повторения логики, поместив логику в функцию. Попробуйте это XSLT 

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:my="my" version="3.0">

  <!-- input/output configuration -->
  <xsl:output method="xml" indent="yes" />
  <xsl:strip-space elements="*"/>

  <xsl:variable name="CodeGroupA" select="'12', '13'" />
  <xsl:variable name="CodeGroupB" select="'17', '18'" />

  <xsl:template match="/Diagnoses" >

    <CodeGroupA>
        <xsl:value-of select="my:check(Diagnosis/Code, $CodeGroupA)" />
    </CodeGroupA>

    <CodeGroupB>
        <xsl:value-of select="my:check(Diagnosis/Code, $CodeGroupB)" />
    </CodeGroupB>
  </xsl:template>

  <xsl:function name="my:check">
      <xsl:param name="nodes" />
      <xsl:param name="group" />
      <xsl:value-of select="if ($nodes = $group) then 'Found' else 'Not found'" />
  </xsl:function>
</xsl:stylesheet>
0 голосов
/ 29 июня 2018

Изменить узел контекста для тестов: 

  <xsl:template match="/Diagnoses" >

    <xsl:if test="Diagnosis/Code = $CodeGroupA">
        <CodeGroupA>Found</CodeGroupA>
    </xsl:if>

    <xsl:if test="not(Diagnosis/Code = $CodeGroupA)">
        <CodeGroupA>Not found</CodeGroupA>
    </xsl:if>

    <xsl:if test="Diagnosis/Code = $CodeGroupB">
        <CodeGroupB>Found</CodeGroupB>
    </xsl:if>

    <xsl:if test="not(Diagnosis/Code = $CodeGroupB)">
        <CodeGroupB>Not found</CodeGroupB>
    </xsl:if>
  </xsl:template>

https://xsltfiddle.liberty -development.net / bdxtq9

...