Могу ли я повысить :: bind () для функции Objective C? - PullRequest
Новая
       12

Могу ли я повысить :: bind () для функции Objective C?

10 голосов
/ 20 июня 2009

Я понятия не имею, возможно ли это, но если это так, как будет выглядеть синтаксис?

Если не возможно, то почему бы и нет?

1 Ответ

16 голосов
/ 20 июня 2009

Вы должны иметь возможность связываться с реализацией сообщений (IMP), которые являются просто обычными функциями C с двумя скрытыми параметрами, self и _cmd типов id и SEL соответственно.

РЕДАКТИРОВАТЬ : только что протестировал следующий полный пример, и он, кажется, работает. 

#include <stdio.h>
#include <boost/bind.hpp>
#include <Foundation/NSObject.h>

@interface MyClass : NSObject
{
}
-(int) doSomething:(int)arg;
@end

@implementation MyClass
-(int) doSomething:(int)arg
{
  printf("doSomething: self=0x%08x _cmd=0x%08x\n", self, _cmd);
  return arg + 1;
}
@end

int main(void)
{
  MyClass *myObj = [[MyClass alloc] init], *otherObj = [[MyClass alloc] init];
  typedef int (*MyFunc)(id, SEL, int);
  SEL doSomething_sel = @selector(doSomething:);
  MyFunc doSomething_impl = (MyFunc)[myObj methodForSelector:doSomething_sel];

  // bind self & _cmd arguments:
  // calls [myObj doSomething:x]
  int result = boost::bind(doSomething_impl, myObj, doSomething_sel, _1)(14);
  printf("result1: %d\n", result);

  // bind _cmd & arg:
  // calls [otherObj doSomething:3]
  result = boost::bind(doSomething_impl, _1, doSomething_sel, 42)(otherObj);
  printf("result2: %d\n", result);

  return 0;
}

С помощью GNUstep скомпилируйте как: 

gcc objcbind.mm -o objcbind -I/usr/include/GNUstep -lobjc -lstdc++ -lgnustep-base

В Mac OS X скомпилируйте как: 

gcc objcbind.mm -o objcbind -framework Foundation -lstdc++

Выход: 

doSomething: self=0x01a85f70 _cmd=0x00602220
result1: 15
doSomething: self=0x01a83d70 _cmd=0x00602220
result2: 43
...