Диапазон копирования VBA от Excel до PowerPoint - PullRequest
Новая
       21

Диапазон копирования VBA от Excel до PowerPoint

0 голосов
/ 30 апреля 2018

Я пытаюсь скопировать определенный диапазон из Excel и вставить его в pp как рисунок. Я собрал следующий код из различных сетевых источников и продолжаю получать ошибку времени выполнения 91 (переменная объекта или переменная блока не задана) при запуске PowerPointApp.WindowState = 2.

Как я могу исправить эту ошибку и избежать ее в будущем?

сначала я успешно запустил 

    Private Sub OpenPowerpoint()

        Dim PPT As PowerPoint.Application
        Set PPT = New PowerPoint.Application

        PPT.Visible = True
        PPT.Presentations.Open Filename:="C:\Users\aofarrell\Desktop\CYB\Weekly Pack Update - Template.pptx"
        PPT.ActivePresentation.Slides(2).Select

    End Sub

Затем я пытаюсь запустить 

 Private Sub CopyToPowerPoint()

            Dim rng As Range
            Dim PowerPointApp As Object
            Dim mySlide As Object
            Dim myShape As Object


        'Copy Range from Excel

            Set rng = ThisWorkbook.Sheets("Triggers").Range("B6:Z33")

        'Copy Excel Range
            rng.Copy

        'Paste to PowerPoint and position
            PowerPointApp.WindowState = 2 'ERROR OCCURS HERE
            mySlide.Shapes.PasteSpecial DataType:=0
            Set myShape = mySlide.Shapes(mySlide.Shapes.Count)

        'Set position:
            myShape.Left = 20
            myShape.Top = 70
            myShape.Width = 675
            myShape.Height = 400

        'Clear The Clipboard
            Application.CutCopyMode = False
            Application.Wait (Now + TimeValue("00:00:01"))

        End Sub

1 Ответ

0 голосов
/ 30 апреля 2018

Хмм ... Ну, во-первых, вам нужно определить тип Object вашего PowerPointApp. А какой конкретный объект у тебя mySlide? Помните также, что локальные переменные уничтожаются в конце Sub / Function, поэтому вам могут потребоваться некоторые переменные / объекты уровня модуля: 

Option Explicit

Private PPT As PowerPoint.Application
Private PPT_pres As PowerPoint.Presentation

Private Sub OpenPowerpoint()
    Set PPT = New PowerPoint.Application

    PPT.Visible = True
    Set PPT_pres = PPT.Presentations.Open(FileName:="C:\Users\aofarrell\Desktop\CYB\Weekly Pack Update - Template.pptx")
    PPT_pres.Slides(2).Select
End Sub

Private Sub CopyToPowerPoint()
    If PPT Is Nothing Then Exit Sub
    If PPT_pres Is Nothing Then Exit Sub

    Dim rng As Range
    Dim mySlide As Object
    Dim myShape As Object

    Set mySlide = PPT_pres.Slides(2)

    'Copy Range from Excel

    Set rng = ThisWorkbook.Sheets("Triggers").Range("B6:Z33")

    'Copy Excel Range
    rng.Copy

    'Paste to PowerPoint and position
    PPT.WindowState = 2
    mySlide.Shapes.PasteSpecial DataType:=0
    Set myShape = mySlide.Shapes(mySlide.Shapes.Count)

    'Set position:
    myShape.Left = 20
    myShape.Top = 70
    myShape.Width = 675
    myShape.Height = 400

    'Clear The Clipboard
    Application.CutCopyMode = False
    Application.Wait (Now + TimeValue("00:00:01"))

End Sub

(Также: если бы я копировал как изображение из Excel в PowerPoint, я бы обычно использовал Range.CopyPicture xlPrinter вместо Shapes.PasteSpecial, который изменяет размер изображения в зависимости от разрешения экрана)

...