XSLT 2.0 - как объединить элементы одного уровня

Question

Как я могу объединить определенный элемент с соседними братьями и сестрами одного типа в один элемент? Я чувствую, что это должно быть просто, но не могу найти ответ.

Мой код:

...
<nodeX>
  <a>words</a>
  <b>things</b>
  <g>hi</g>
  <g>there</g>
  <g>friend</g>
  <c>stuff</c>
  <g>yep</g>
</nodeX>
...

Желаемый вывод:

...
<nodeX>
  <a>words</a>
  <b>things</b>
  <g>hi there friend</g>
  <c>stuff</c>
  <g>yep</g>
</nodeX>
...

Я работаю с чрезвычайно сложным и разнообразным документом с глубокой иерархией, поэтому я не могу работать со многими предположениями, за исключением того факта, что эти элементы будут отображаться в том или ином контексте, и когда они появляются со смежным брат, эти братья должны слиться. Любая помощь будет оценена.

Обновление:

Используя советы zx485 и Мартина Хоннена, кажется, что следующее хорошо работает для развертывания только определенного элемента:

<xsl:template match="nodeX">
    <xsl:copy>
        <xsl:copy-of select="@*" />
        <xsl:for-each-group select="*" group-adjacent="name()">
            <xsl:choose>
                <xsl:when test="name()='g'">
                    <xsl:copy>
                        <xsl:copy-of select="current-group()/@*" />
                        <xsl:value-of select="current-group()"/>
                    </xsl:copy>
                </xsl:when>
                <xsl:otherwise>
                    <xsl:apply-templates select="current-group()"/>
                </xsl:otherwise>
            </xsl:choose>
        </xsl:for-each-group>
    </xsl:copy>
</xsl:template>

Answer 1

С XSLT-2.0 это не сложно. Это вопрос XSLT-2.0 Grouping . В этом случае используйте xsl:for-each-group с атрибутом group-adjacent.

Следующий шаблон сопоставляет все элементы nodeX и копирует их, включая их атрибуты. Он перебирает все дочерние элементы и группирует смежные элементы по их name(). Затем он копирует первый элемент группы и добавляет атрибуты всех элементов с одинаковым именем. Теперь text() всех элементов в этой группе объединены с разделителем - здесь это пробел.

<xsl:template match="nodeX">
    <xsl:copy>
        <xsl:copy-of select="@*" />
        <xsl:for-each-group select="*" group-adjacent="name()">
            <xsl:copy>
                <xsl:copy-of select="current-group()/@*" />
                <xsl:value-of select="current-group()" separator=" " />
            </xsl:copy>
        </xsl:for-each-group>
    </xsl:copy>
</xsl:template> 

Вывод:

<nodeX>
   <a>words</a>
   <b>things</b>
   <g>hi there friend</g>
   <c>stuff</c>
   <g>yep</g>
</nodeX>