Полукольцо матрично-векторного произведения у Юлии не работает - PullRequest
Новая
       3

Полукольцо матрично-векторного произведения у Юлии не работает

0 голосов
/ 30 апреля 2018

Я пытаюсь реализовать алгебру max-plus semiring в Julia (0.6.2), следуя этой статье:

http://www.mit.edu/~kepner/pubs/JuliaSemiring_HPEC2013_Paper.pdf

Определение типа для чисел max-plus и определения всех соответствующих операторов, взятые прямо из упомянутой выше статьи, следующие: 

# define max-plus number type

immutable MPNumber{T} <: Number 
  val::T
end

+(a::MPNumber, b::MPNumber) = MPNumber(max(a.val, b.val))

*(a::MPNumber, b::MPNumber) = MPNumber(a.val + b.val)

show(io::IO, k::MPNumber) = show(io, k.val)

zero{T}(::MPNumber{T}) = MPNumber(typemin(T))

one{T}(::MPNumber{T}) = MPNumber(zero(T))

promote_rule{T<:Number}(::Type{MPNumber}, ::Type{T}) = MPNumber

mparray(A::Array) = map(MPNumber, A)

array{T}(A::Array{MPNumber{T}}) = map(x->x.val, A)

Базовые тесты сложения и умножения max-plus работают просто отлично, например, 

MPNumber(1) + MPNumber(1)

дает MPNumber(1), как и ожидалось. Макс-плюс матрица возведения в степень, как показано в статье, также работает как шарм: 

A = mparray(Array([[1, 2] [3, 4]]))
A*A

дает 

2×2 Array{MPNumber{Int64},2}:
 MPNumber{Int64}(5)  MPNumber{Int64}(7)
 MPNumber{Int64}(6)  MPNumber{Int64}(8)

Однако, когда я пытаюсь умножить вектор с максимальным плюсом на матрицу с максимальным плюсом, 

A = mparray(Array([[1, 2] [3, 4]]))
x = mparray([1, 2])

A*x

Я получаю следующую ошибку: 

MethodError: Cannot `convert` an object of type Int64 to an object of type MPNumber{Int64}
This may have arisen from a call to the constructor MPNumber{Int64}(...) since type constructors fall back to convert methods.

Stacktrace:
 [1] generic_matvecmul!(::Array{MPNumber{Int64},1}, ::Char, ::Array{MPNumber{Int64},2}, ::Array{MPNumber{Int64},1}) at ./linalg/matmul.jl:434
 [2] Ac_mul_B(::Array{MPNumber{Int64},1}, ::Array{MPNumber{Int64},2}) at ./linalg/rowvector.jl:227

Я все еще довольно новичок в Джулии, поэтому мне трудно разобраться, что именно здесь идет не так и как это можно исправить. Любая помощь будет высоко ценится.

1 Ответ

0 голосов
/ 30 апреля 2018

Это проверено под Julia 0.6.2. Используйте следующий код: 

struct MPNumber{T} <: Number
  val::T
end
Base.:+(a::MPNumber, b::MPNumber) = MPNumber(max(a.val, b.val))
Base.:*(a::MPNumber, b::MPNumber) = MPNumber(a.val + b.val)
Base.show(io::IO, k::MPNumber) = show(io, k.val)
Base.zero(::MPNumber{T}) where T = MPNumber(typemin(T))
Base.one(::MPNumber{T}) where T = MPNumber(zero(T))
Base.zero(::Type{MPNumber{T}}) where T = MPNumber(typemin(T))
Base.one(::Type{MPNumber{T}}) where T = MPNumber(zero(T))
mparray(A::Array) = map(MPNumber, A)

(я рекомендую начинать с этой части только потому, что переходы и рекламные акции более сложны и не нужны для ваших целей).

Обратите внимание, что важная часть заключается в том, что я расширяю функции с Base, добавляя перед ними Base.. Для + и * вам необходимо дополнительно использовать : перед именами функций.

Теперь вы можете запускать все, что хотели: 

julia> MPNumber(1) + MPNumber(1)
1

julia> A = mparray(Array([[1, 2] [3, 4]]))
2×2 Array{MPNumber{Int64},2}:
 1  3
 2  4

julia> A*A
2×2 Array{MPNumber{Int64},2}:
 5  7
 6  8

julia> A = mparray(Array([[1, 2] [3, 4]]))
2×2 Array{MPNumber{Int64},2}:
 1  3
 2  4

julia> x = mparray([1, 2])
2-element Array{MPNumber{Int64},1}:
 1
 2

julia> A*x
2-element Array{MPNumber{Int64},1}:
 5
 6

как хотел.

РЕДАКТИРОВАТЬ: я сделал определения zero и one в вашем коде, чтобы они были более полными и соответствовали стандартным требованиям.

...