MQL4 Рисование динамической Rectangle_Label с текстом в нем - PullRequest
Новая
       46

MQL4 Рисование динамической Rectangle_Label с текстом в нем

0 голосов
/ 30 августа 2018

Я пытаюсь нарисовать Rectangle Label с текстом в нем каждый тик .. Я хочу, чтобы текст точно вписывался в Rectangle_Label .. В качестве текста я использую Label .. Но не могу заставить его работать точно. . Неправильно расположен ..

На самом деле я хотел бы создать класс, который бы делал все это в одном ... Так же, как прямоугольник с текстом в нем, который всегда имел бы одинаковую согласованность и размер и т. Д.

Любая помощь будет принята с благодарностью ... 

 bool createRectangleLabel(long chart_ID,string name,string labelName,int shift,double price,string text,double xSize,double ySize,double xOffSet,double yOffSet,double xDistance,double yDistance)
     {
      if(ObjectCreate(chart_ID,labelName,OBJ_RECTANGLE_LABEL,0,TimeCurrent()-shift,price))
    {
     Print(xDistance+"  "+yDistance);
     ObjectSetInteger(chart_ID,labelName,OBJPROP_BGCOLOR,clrBlack);
     ObjectSetInteger(chart_ID,labelName,OBJPROP_XDISTANCE,xDistance);
     ObjectSetInteger(chart_ID,labelName,OBJPROP_YDISTANCE,yDistance);
     ObjectSetInteger(chart_ID,labelName,OBJPROP_YSIZE,ySize);
     ObjectSetInteger(chart_ID,labelName,OBJPROP_XSIZE,xSize);
     ObjectSetString(chart_ID,labelName,OBJPROP_TEXT,text);
     ObjectSetInteger(chart_ID,name,OBJPROP_ANCHOR,ANCHOR_CENTER);

     return true;
    }
  else
    {
     Print("createRectangleLabel return error code: ",GetLastError());
     Print("+--------------------------------------------------------------+");
     return false;
    }
 }
   bool createLineText(long chart_ID,string name,string labelName,int shift,double price,string text)
 {
  int xDistance=0;
  int yDistance=0;
  int xSize,xOffSet;
  int ySize,yOffSet;
  bool i=ChartTimePriceToXY(chart_ID,0,TimeCurrent(),price,xDistance,yDistance);

  if(ObjectCreate(chart_ID,name,OBJ_LABEL,0,TimeCurrent()-shift,price))
    {
     ObjectSetInteger(chart_ID,name,OBJPROP_BGCOLOR,clrWhite);
     ObjectSetInteger(chart_ID,name,OBJPROP_XDISTANCE,xDistance);
     ObjectSetInteger(chart_ID,name,OBJPROP_YDISTANCE,yDistance);
     ObjectSetString(chart_ID,name,OBJPROP_TEXT,text);
     ObjectSetInteger(chart_ID,name,OBJPROP_ANCHOR,ANCHOR_CENTER);
     ObjectSetInteger(chart_ID,name,OBJPROP_COLOR,clrWhite);
     ObjectSetInteger(chart_ID,name,OBJPROP_FONTSIZE,10);
     xSize = ObjectGet(name,OBJPROP_XSIZE);
     ySize = ObjectGet(name,OBJPROP_YSIZE);
     xOffSet = ObjectGet(name,OBJPROP_XOFFSET);
     yOffSet = ObjectGet(name,OBJPROP_YOFFSET);
     TextGetSize(name,xSize,ySize);
     createRectangleLabel(chart_ID,name,labelName,shift,price,text,xSize,ySize,xOffSet,yOffSet,xDistance,yDistance);
     return true;
    }
  else
    {
     Print("createLineText return error code: ",GetLastError());
     Print("+--------------------------------------------------------------+");
     return false;
    }
 }

Ответы [ 2 ]

0 голосов
/ 31 августа 2018

Вы думаете по правильному пути, когда говорите, что хотите создать класс. К счастью для вас, standard library уже включает в себя все классы, необходимые для создания объектов диаграммы. Документация

Пример индикатора: 

#property strict
#property indicator_chart_window

#include <ChartObjects\ChartObjectsTxtControls.mqh>

class MyRectLabel : public CChartObjectRectLabel
{
   CChartObjectLabel m_label;
public:
   bool Create(long chart, const string name, const int window, 
               const int X, const int Y, const int sizeX, const int sizeY)
   {
      if(!CChartObjectRectLabel::Create(chart,name,window,X,Y,sizeX,sizeY))
         return false;
      return m_label.Create(chart, name + "_", window, X + 8, Y + 12);
   }
   bool Color(const color clr){
      return m_label.Color(clr);
   }
   bool Description(const string text){
      return m_label.Description(text);
   }
   bool FontSize(const int size){
      return m_label.FontSize(size);
   }
   bool ToolTip(const string text){
      return (this.ToolTip(text) && m_label.Tooltip(text));
   }
};
//+------------------------------------------------------------------+
MyRectLabel rect_label;
//+------------------------------------------------------------------+
int OnInit()
{
   if(!rect_label.Create(0, "rlabel", 0, 5, 25, 100, 50)
      || !rect_label.BackColor(clrWhiteSmoke)
      || !rect_label.Description("LABEL!")
      || !rect_label.Tooltip("I am a rectangle label")
      || !rect_label.Color(clrBlack)
      || !rect_label.FontSize(18)
   )
      return INIT_FAILED;
   return INIT_SUCCEEDED;
}
//+------------------------------------------------------------------+
int start()
{ 
   static double last_price = 0.;
   rect_label.Description(DoubleToString(Bid, _Digits));
   if(Bid > last_price)
      rect_label.Color(clrLimeGreen);
   else
      rect_label.Color(clrRed);
   last_price = Bid;
   return 0; 
}
0 голосов
/ 31 августа 2018

Вы не можете вызывать ObjectCreate() каждый тик - это вернет ошибку 4200. Если вы проверите объект существует до создания, это поможет. Альтернативный подход состоит в том, чтобы попытаться создать объект и присвоить ему некоторые необходимые свойства (например, цвет объекта, привязку и т. Д.) В одном блоке и переместить его в другой. 

if(ObjectFind(chart_id,labelName)<0){
   if(ObjectCreate(chart_ID,labelName,OBJ_RECTANGLE_LABEL,0,TimeCurrent()-shift,price)){
      ObjectSetInteger(chart_ID,labelName,OBJPROP_BGCOLOR,clrBlack);//etc.
   }
   ObjectSetInteger(chart_ID,labelName,OBJPROP_XDISTANCE,xDistance);
   ObjectSetInteger(chart_ID,labelName,OBJPROP_YDISTANCE,yDistance);//if you need to move the object or take other steps each tick, e.g. update text - do it here
}
...