Загрузить изображение из файла в Ocaml Graphics - PullRequest
Новая
       7

Загрузить изображение из файла в Ocaml Graphics

0 голосов
/ 01 мая 2018

Я читаю документацию для Графического модуля , и нет никакой информации о загрузке изображений из файла, только из цветового массива. Как бы я поступил так? Например, предположим, что у меня есть file.png, и я хочу нарисовать его с координатами (x, y) с z градусами поворота.

1 Ответ

0 голосов
/ 01 мая 2018

Библиотека camlimages может загружать файлы png (если они не представлены в формате RGBA или CMYK). Простой пример: 

open Images

let () = Graphics.open_graph "";;

let img = Png.load "png.png" [];;
let g = Graphic_image.of_image img;;

Graphics.draw_image g 0 0;;

Unix.sleep 10;;

Для запуска: 

opam install graphics camlimages
ocamlfind ocamlc -o test -package graphics -package unix \
    -package camlimages.png -package camlimages.graphics \
    -linkpkg test.ml
wget https://bytebucket.org/camlspotter/camlimages/raw/1611545463f493462aeafab65839c1112162559a/test/images/png.png
./test

(На основе примера в исходном коде библиотеки .)

Но я не думаю, что камлимы могут вращать PNG. Вы можете свернуть свою собственную функцию поворота (адаптировано из кода Мортимера на доктора Добба): 

let rotate src dst angle =
  let sh, sw = Array.(float (length src), float (length src.(0))) in
  let dh, dw = Array.(length dst, length dst.(0)) in
  let dx, dy = float dw /. 2., float dh /. 2. in
  let scale = min (float dh /. sh) (float dw /. sw) in
  let duCol = sin(-.angle) *. (1. /. scale) in
  let dvCol = cos(-.angle) *. (1. /. scale) in
  let rec col dst x u v =
    if x < dw then (
      dst.(x) <- if (0. <= u && u < sw) && (0. <= v && v < sh)
                 then src.(truncate v).(truncate u)
                 else Graphics.white;
      col dst (x + 1) (u +. dvCol) (v -. duCol))
  in
  let rec row y rowu rowv =
    if y < dh then (col dst.(y) 0 rowu rowv;
                    row (y + 1) (rowu +. duCol) (rowv +. dvCol))
  in
  row 0 ((sw /. 2.) -. (dx *. dvCol +. dy *. duCol))
        ((sh /. 2.) -. (dx *. (-.duCol) +. dy *. dvCol))

И назовите его из приведенного выше примера с 

let dg = Graphics.dump_image g
let dgr =Array.(make_matrix (length dg) (length dg.(0)) Graphics.white);;
rotate dg dgr (4. *. atan 1. /. 2);;
let g = Graphics.make_image dgr;;

Или вы можете использовать что-то вроде Sdlgfx.rotozoomSurface функции OCamlSDL .

Простой пример: 

let png = Sdlloader.load_image "png.png"

let png_rot = Sdlgfx.rotozoomSurface png 45.0 1.0 true;;

Sdl.init [`VIDEO];;
let screen = Sdlvideo.set_video_mode ~w:250 ~h:166 [];;

Sdlvideo.(blit_surface ~dst_rect:{ r_x = 0; r_y = 0; r_w = 250; r_h = 166}
                       ~src:png_rot ~dst:screen ());;

Sdlvideo.flip screen;
Sdltimer.delay 10000;
Sdl.quit ();;

После установки соответствующих пакетов SDL в вашей системе (не всегда просто ...), для запуска: 

opam install ocamlsdl
ocamlfind ocamlc -o test -package sdl -package sdl.sdlimage \
    -package sdl.sdlgfx -linkpkg test.ml
./test
...