Как добавить номера кодов ошибок в выходной текстовый файл?

Question

У меня есть пакетный скрипт, который перебирает все ошибки Windows и помещает их в текстовый файл с именем helplog2.txt. Однако они не разделены пустыми строками, и в сообщениях об ошибках перед ними нет номеров ошибок.

Есть ли способ это исправить?

Вот мой пакетный скрипт:

@echo off
If Exist HelpLog2.txt Del HelpLog2.txt
(for /l %%i in (0,1,99999) do net helpmsg %%i 1>NUL 2>&1 && echo %%i & net helpmsg %%i | findstr /i "[a-z]" >> HelpLog2.txt)
Start "" HelpLog2.txt
pause

Answer 1

Используйте этот код партии:

@echo off
del HelpLog2.txt 2>nul
for /L %%I in (0,1,9) do for /F delims^=^ eol^= %%J in ('%SystemRoot%\System32\net.exe helpmsg %%I 2^>^&1') do >>HelpLog2.txt echo     %%I: %%J
for /L %%I in (10,1,99) do for /F delims^=^ eol^= %%J in ('%SystemRoot%\System32\net.exe helpmsg %%I 2^>^&1 ^| %SystemRoot%\System32\findstr.exe /V /C:"NET HELPMSG 3871"') do >>HelpLog2.txt echo    %%I: %%J
for /L %%I in (100,1,999) do for /F delims^=^ eol^= %%J in ('%SystemRoot%\System32\net.exe helpmsg %%I 2^>^&1 ^| %SystemRoot%\System32\findstr.exe /V /C:"NET HELPMSG 3871"') do >>HelpLog2.txt echo   %%I: %%J
for /L %%I in (1000,1,9999) do for /F delims^=^ eol^= %%J in ('%SystemRoot%\System32\net.exe helpmsg %%I 2^>^&1 ^| %SystemRoot%\System32\findstr.exe /V /C:"NET HELPMSG 3871"') do >>HelpLog2.txt echo  %%I: %%J
for /L %%I in (10000,1,99999) do for /F delims^=^ eol^= %%J in ('%SystemRoot%\System32\net.exe helpmsg %%I 2^>^&1 ^| %SystemRoot%\System32\findstr.exe /V /C:"NET HELPMSG 3871"') do >>HelpLog2.txt echo %%I: %%J
start "" HelpLog2.txt

Это займет несколько минут, но, наконец, вы должны получить нужную информацию в хорошо отформатированном файле HelpLog2.txt.

Чтобы понять используемые команды и то, как они работают, откройте окно командной строки, выполните там следующие команды и полностью прочитайте все страницы справки, отображаемые для каждой команды.

• del /?
• echo /?
• findstr /?
• for /?
• net /?
• net helpmsg /?