Используя VBA в Excel, как вставить таблицу в Outlook, а затем преобразовать таблицу в текст? - PullRequest
Новая
       13

Используя VBA в Excel, как вставить таблицу в Outlook, а затем преобразовать таблицу в текст?

0 голосов
/ 02 ноября 2018

В настоящее время я пытаюсь написать функцию VBA, которая будет копировать диапазон в Excel и вставлять его в электронную почту Outlook. У меня есть что-то, что может успешно скопировать таблицу и отформатировать в Outlook, но проблема в том, что таблицы очень трудно читать на телефоне. Я хотел бы просто использовать внешний вид "ConvertToText", чтобы преобразовать таблицу в форматирование текста, чтобы ее было легче читать. Я не могу придумать, как это сделать. Мой код выглядит следующим образом, используя функцию и подпрограмму: 

Sub Mail_Selection_Range_Outlook_Body()

Dim rng As Range
Dim OutApp As Object
Dim OutMail As Object
Dim SDest As String
Dim i As Integer

Set rng = Nothing
On Error Resume Next
'You can also use a fixed range if you want
Set rng = Sheets("Email").Range("A2:Q400").SpecialCells(xlCellTypeVisible)
On Error GoTo 0

If rng Is Nothing Then
    MsgBox "The selection is not a range or the sheet is protected" & _
           vbNewLine & "please correct and try again.", vbOKOnly
    Exit Sub
End If

With Application
    .EnableEvents = False
    .ScreenUpdating = False
End With

Set OutApp = CreateObject("Outlook.Application")
Set OutMail = OutApp.createitem(0)

On Error Resume Next
With OutMail
    SDest = ""
    For i = 1 To WorksheetFunction.CountA(Sheets("Email List").Columns(1))
        If SDest = "" Then
            SDest = Sheets("Email List").Cells(i, 1).Value
        Else
            SDest = SDest & ";" & Sheets("Email List").Cells(i, 1).Value
        End If
    Next i
    .To = SDest
    .CC = ""
    .BCC = ""
    .Subject = "Frontside Update"
    .HTMLBody = RangetoHTML(rng)
    .Display   'or use .Send
End With
On Error GoTo 0



With Application
    .EnableEvents = True
    .ScreenUpdating = True
End With

Set OutMail = Nothing
Set OutApp = Nothing

End Sub

a 

Function RangetoHTML(rng As Range)

Dim fso As Object
Dim ts As Object
Dim TempFile As String
Dim TempWB As Workbook

TempFile = Environ$("temp") & "\" & Format(Now, "dd-mm-yy h-mm-ss") & ".htm"

'Copy the range and create a new workbook to past the data in
rng.Copy
Set TempWB = Workbooks.Add(1)
With TempWB.Sheets(1)
    .Cells(1).PasteSpecial Paste:=8
    .Cells(1).PasteSpecial xlPasteValues, , False, False
    .Cells(1).PasteSpecial xlPasteFormats, , False, False
    .Cells(1).Select
    Application.CutCopyMode = False
    On Error Resume Next
    .DrawingObjects.Visible = True
    .DrawingObjects.Delete
    On Error GoTo 0
End With

'Publish the sheet to a htm file
With TempWB.PublishObjects.Add( _
     SourceType:=xlSourceRange, _
     Filename:=TempFile, _
     Sheet:=TempWB.Sheets(1).Name, _
     source:=TempWB.Sheets(1).UsedRange.Address, _
     HtmlType:=xlHtmlStatic)
    .Publish (True)
End With

'Read all data from the htm file into RangetoHTML
Set fso = CreateObject("Scripting.FileSystemObject")
Set ts = fso.GetFile(TempFile).OpenAsTextStream(1, -2)
RangetoHTML = ts.readall
ts.Close
RangetoHTML = Replace(RangetoHTML, "align=center x:publishsource=", _
                      "align=left x:publishsource=")

'Close TempWB
TempWB.Close savechanges:=False

'Delete the htm file we used in this function
Kill TempFile

Set ts = Nothing
Set fso = Nothing
Set TempWB = Nothing
End Function

Любая помощь будет принята с благодарностью. Я не уверен, что я ошибся и нужно начать все сначала? Первоначально я надеялся, что таблица HTML будет работать хорошо, но позже понял, что она выглядит ужасно на телефонах (которыми пользуются многие получатели) и не знает лучшего решения.

1 Ответ

0 голосов
/ 02 ноября 2018

Если вы хотите простой текст, то, возможно, попробуйте это: Скопируйте диапазон в массив. Переберите массив и соберите строку, добавляя вкладки между значениями ячеек и возвраты между строками. (Вы также можете циклически проходить по ячейкам на листе, но макросы быстро работают с массивами.) 

Dim arrCells(), r, c, strBody
arrCells = Selection
For r = LBound(arrCells, 1) To UBound(arrCells, 1)
    For c = LBound(arrCells, 2) To UBound(arrCells, 2)
        strBody = strBody & vbTab & arrCells(r, c).Value
    Next c
        strBody = strBody & vbCrLf
Next r
...