Использование команды Slice поначалу может сбить с толку, поэтому здесь
подробное объяснение использования команды для вращения вокруг
X-ось.
В этом примере показано, как можно вращать 3D-данные по часовой стрелке вокруг своей оси X (при просмотре по X) с помощью команды Slice3.
Команда Slice3 указывает новое представление существующего массива данных.
Сначала указывается исходный пиксель, то есть координаты (в исходных данных), которые будут представлены (0,0,0) в новом виде.
Затем указывается направление выборки, длина и размер шага для каждой из трех новых осей.
Первый триплет указывает, как координаты (в исходных данных) изменяются вдоль направления x нового изображения, второй триплет для направления y новых изображений и последний триплет для направления z нового изображения.
Таким образом, вращение вокруг оси x можно представить как:
Для "пересчитанных" данных:
- Новые (повернутые) данные имеют происхождение в исходной точке данных (0,0, SZ-1).
- Его X-направление остается неизменным, то есть один шаг в X в новых данных будет увеличивать триплет координат в исходных данных также на (1,0,0).
И каждый идет SX-шаги с размер шага 1.
- Его Y-направление по существу является отрицательным Z-направлением, т. Е. Один шаг по Y в новых данных будет увеличивать триплет координат в исходных данных также на (0,0, -1).
Таким образом, каждый идет SZ шаги с размером шага -1.
- Его Z-направление по сути является Y-направлением, то есть один шаг по Z в новых данных увеличит триплет координат в исходных данных на (0,1,0).
SY шаги с размером шага 1.
Итак, для вращения по часовой стрелке вокруг оси X команда:
img.Slice3( 0,0,SZ-1, 0,SX,1, 2,SZ,-1, 1,SY,1 )
Эта команда просто создаст новое представление для тех же данных (т. Е. Дополнительная память не используется). Таким образом, чтобы получить повернутое изображение как новое изображение (со значениями данных, выровненными так, как они должны быть в памяти), можно было бы клонировать этот вид в новое изображение. usign ImageClone()
Всего следующий скрипт показывает это в качестве примера:
// Demo of rotating 3D data orthogonally around the X axis
// This is done by resampling the data using the Slice3 command
// Creation of test image with regcognizeable pattern
number SX = 100
number SY = 30
number SZ = 50
image img := RealImage("Test",4, SX,SY,SZ)
// trig. modulated linear increase in X
img = icol/iwidth* sin( icol/(iwidth-1) * 5 * Pi() ) **2
// Simple linear increase in Y
img += (irow/iheight) * 2
// Modulation of values in Z
// (doubling values for index 0,1, 3, 4, 9, 16, 25, 36, 49)
img *= (SQRT(iplane) == trunc(SQRT(iplane)) ? 2 : 1 )
img.ShowImage()
// Show captions. Image coordinate system is
// Origin (0,0,0) in top-left-front most pixel
// X axis goes left to right
// Y axis goes top to down
// Z axis goes front to back
img.ImageSetDimensionCalibration(0,0,1,"orig X",0)
img.ImageSetDimensionCalibration(1,0,1,"orig Y",0)
img.ImageSetDimensionCalibration(2,0,1,"orig Z",0)
img.ImageGetImageDisplay(0).ImageDisplaySetCaptionOn(1)
// Rotation around X axis, clockwise looking along X
// X --> X` (unchanged)
// Y --> Z'
// Z --> -Y'
// old origin moves to bottom-left-front most
// This means for "new" sampling:
// Specify sampling starting point:
// New origin (0,0,0)' will be value which was at (0,0,SZ-1)
// Going one step in X' in the new data, will be like going one step in X
// Going one step in Y' in the new data, will be like going one step backwards in Z
// Going one step in Z' in the new data, will be like going one step in Y
image rotXCW := img.Slice3( 0,0,SZ-1, 0,SX,1, 2,SZ,-1, 1,SY,1 ).ImageClone()
rotXCW.SetName("rotated X, CW")
rotXCW.ShowImage()
rotXCW.ImageGetImageDisplay(0).ImageDisplaySetCaptionOn(1)
Следующие методы выполняют вращение на 90 градусов:
// Functions for 90degree rotations of data
image RotateXCW( image input )
{
number SX,SY,SZ
input.Get3DSize(SX,SY,SZ)
return input.Slice3( 0,0,SZ-1, 0,SX,1, 2,SZ,-1, 1,SY,1 ).ImageClone()
}
image RotateXCCW( image input )
{
number SX,SY,SZ
input.Get3DSize(SX,SY,SZ)
return input.Slice3( 0,SY-1,0, 0,SX,1, 2,SZ,1, 1,SY,-1 ).ImageClone()
}
image RotateYCW( image input )
{
number SX,SY,SZ
input.Get3DSize(SX,SY,SZ)
return input.Slice3( SX-1,0,0, 2,SZ,1, 1,SY,1, 0,SX,-1 ).ImageClone()
}
image RotateYCCW( image input )
{
number SX,SY,SZ
input.Get3DSize(SX,SY,SZ)
return input.Slice3( 0,0,SZ-1, 2,SZ,-1, 1,SY,1, 0,SX,1 ).ImageClone()
}
image RotateZCW( image input )
{
number SX,SY,SZ
input.Get3DSize(SX,SY,SZ)
return input.Slice3( 0,SY-1,0, 1,SY,-1, 0,SX,1, 2,SZ,1 ).ImageClone()
}
image RotateZCCW( image input )
{
number SX,SY,SZ
input.Get3DSize(SX,SY,SZ)
return input.Slice3( SX-1,0,0, 1,SY,1, 0,SX,-1, 2,SZ,1 ).ImageClone()
}
Вращения вокруг оси z также можно выполнить с RotateRight() и RotateLeft(). Однако обратите внимание, что эти команды не будут адаптировать калибровку размеров изображений, в то время как команда Slice3 будет.