Возьмите части темы из электронной почты и введите их в таблицу Excel

Question

Здравствуйте, ниже. Я включил текущий скрипт vba для запуска файла, содержащего несколько электронных писем с конкретными именами файлов, которые соответствуют изменениям адресов, обсуждаемым в электронных письмах. Я хочу взять текст, относящийся к изменению адреса, из каждого из этих имен файлов и ввести новый и старый адрес в таблицу Excel. Все электронные письма в этой папке делятся на 4 категории того, как отформатирован их заголовок. Ниже приведены примеры всех четырех:

• «Циркуляция смены адреса - 14 до 12 Queen Street»
• «Циркуляция смены адреса - от 4 до 2 King Street»
• "Циркуляция смены адреса - 40 южных улиц до 1 главного проспекта"
• «Циркуляция смены адреса - от улицы 4 до 2 десятой».

Как вы видите, все они начинаются с одной и той же строки "Циркуляция изменения адреса", однако у меня возникли проблемы с получением сценария, который можно адаптировать ко всем этим различным сценариям. Ниже я включил текущую итерацию скрипта. Если у кого-то есть какие-либо предложения или улучшения, это было бы очень полезно, спасибо.

Dim StrFile As String
'Change this to the directory containing all Address Change Circulation emails
'This will Pull in a list and, to the best of its ability make two columns that hold the data for
'the old and the new address
StrFile = Dir(Range("AddressChangeFolderPath").Value)
Dim Names() As String
Dim StrName
Do While Len(StrFile) > 0
    CheckVal = InStr(1, StrFile, "Address Change Circulation -", vbTextCompare) + _
        InStr(1, StrFile, "Address Change Circulation from ", vbTextCompare)
    If CheckVal <> 1 Then   'if the email does not fit the standard, just place it in the cell and
                            'move on to the next entry
        Selection.Value = StrFile
        Selection.Interior.Color = RGB(255, 255, 0) 'highlight the cell
        Selection.Offset(1, 0).Select
    Else
        StrName = Right(StrFile, Len(StrFile) - 29) 'trim to the correct size - probably not the
                                                    'best way to do this but it works
        If Left(StrName, 4) = "from" Then
            StrName = Right(StrName, Len(StrName) - 5)
        ElseIf Left(StrName, 2) = "om" Then
 StrName = Right(StrName, Len(StrName) - 3)
        End If
        StrName = Left(StrName, Len(StrName) - 4)
        Changes = Split(StrName, " and ")
        For Each Change In Changes
            Names = Split(Change, " to ")

            If Len(Names(0)) < 5 Then
                Selection.Value = Names(0) & Right(Names(1), Len(Names(1)) - Len(Names(0)))
            Else
                Selection.Value = Names(0)
            End If
            If UBound(Names) >= 1 Then 'this is a zero indexed array, checking greater than or
                                       'equal to 1 will check if there are two or more entries
                Selection.Offset(0, 1).Value = Names(1) ' in the event that there is no " to " in
                                                'the file name and it hasn't been handeled already
            End If
            Selection.Offset(1, 0).Select 'select the next cell to accept the next entry
        Next
    End If

loop

Answer 1

Исходя из ваших примеров, это, вероятно, разумный подход. Управлять проще, если разбить анализ на отдельный метод.

Просто разбор текстов из диапазона на листе:

Sub Process()
    Dim c As Range, op As String, np As String

    For Each c In Range("A1:A6").Cells
        ParseAddresses c.Value, op, np '<< passing np/op by reference...
        c.Offset(0, 1).Value = op
        c.Offset(0, 2).Value = np
    Next c

End Sub

'Parse two addresses from "t" into "op" and "np"
Sub ParseAddresses(ByVal t, ByRef op As String, ByRef np As String)
    Dim arr

    op = "": np = ""
    t = Trim(t)
    If t Like "Address Change Circulation -*to*" Then
        t = Replace(t, "Address Change Circulation -", "")
        t = Replace(t, "from", "")
        arr = Split(t, "to")
        op = Trim(arr(0))
        np = Trim(arr(1))
        ' "from" part is just a number: replace number in "to" part
        If IsNumeric(op) Then
            arr = Split(np, " ")
            arr(0) = op
            op = Join(arr, " ")
        End If
    End If
End Sub