SAS proc report Ширина столбца таблицы RTF, не совпадающая с указанной шириной - PullRequest
Новая
       25

SAS proc report Ширина столбца таблицы RTF, не совпадающая с указанной шириной

0 голосов
/ 03 сентября 2018

При создании таблицы SAS в формате .rtf с использованием proc report ширина столбцов не совпадает с указанной шириной. Это приводит к тому, что заголовки столбцов занимают несколько строк, а некоторые значения усекаются, чего я хочу избежать.

Использование данных: 

/* Insert data */
data aaa;
   input cohort $ color $ sum $ pctn $;
   datalines;
group_1 dark_yellow 2   12.500%
group_2 orange  6   37.500%
group_2 dark_green  8   50.000%
overall orange  6   30.000%
overall dark_green  8   42.250%
;
run;

И этот код для генерации файла .rtf с шириной столбцов 7, 11, 16 и 30 соответственно: 

/* Output settings */
options nocenter nodate nonumber missing=' ' orientation=landscape linesize=116 pagesize=42;    * page settings;
ods output close;       * close ods output;
ods rtf close;          * close ods rtf;
ods listing close;      * close ods listing;
footnote "Table generated on %sysfunc(date(), worddatx.w.)";            * insert date below report;
ods rtf file = "C:\Astudies\Colors.rtf" bodytitle;

/* Generate table */
proc report data=aaa nowd split='~';
column cohort color sum pctn;
define cohort   /order order=data       width=7     left    'Cohort';
define color        /display            width=11    left    'Color';
define sum          /display            width=16    left    'Number of colors';
define pctn         /display            width=30    left    'Percentage of total colors (%)';
title 'Painting';
title2'Common colours per cohort';
run;

title;              * remove any titles;
footnote;           * remove any footnotes;
ods rtf close;      * close ods rtf;
ods listing;

Это приводит к этой таблице. Столбцы 3-4 имеют заголовки, охватывающие несколько строк (их длина составляет 16 и 30 символов соответственно). Столбец 2 имеет усеченные значения, где максимальная длина символа (dark_yellow) должна быть 11.

enter image description here

1 Ответ

0 голосов
/ 03 сентября 2018

Вы можете установить PROC REPORT стиль столбца width= в опции DEFINE столбец / STYLE=[].

Пример кода

В этом примере предполагается 10-дюймовая ландшафтная недвижимость с относительной (безразмерной) шириной столбцов 7, 11, 16 и 30. Вычисление% SYSEVALF отображает относительную ширину в явные дюймы, которые будут использоваться при рендеринге RTF ODS. 

proc report data=aaa nowd split='~'
;
column cohort color sum pctn;
define cohort   /order order=data       left    'Cohort'                          style=[width=%sysevalf(10 *  7 / (7+11+16+30))in];
define color        /display            left    'Color'                           style=[width=%sysevalf(10 * 11 / (7+11+16+30))in];
define sum          /display            left    'Number of colors'                style=[width=%sysevalf(10 * 16 / (7+11+16+30))in];;
define pctn         /display            left    'Percentage of total colors (%)'  style=[width=%sysevalf(10 * 30 / (7+11+16+30))in];;
title 'Painting';
title2'Common colours per cohort';
run;
...