ABAP: отчет через GUI имеет 18 столбцов, через RFC 6 (иерархический ALV) - PullRequest
Новая
       14

ABAP: отчет через GUI имеет 18 столбцов, через RFC 6 (иерархический ALV)

0 голосов
/ 05 ноября 2018

Я хочу экспортировать отчет "RM07MLBS" (tcode mb52).

Если я вызываю этот отчет через SAP-GUI, он имеет 18 столбцов.

Если я вызову отчет со следующим кодом abap, то в нем будут только эти столбцы:

  • maktx, werks, matkl, matnr, name1, mtart

Здесь приблизительно код: 

FUNCTION /FOO/GET_REPORT_DATA .

cl_salv_bs_runtime_info=>set(
 EXPORTING
   display  = abap_false
   metadata = abap_false
   data     = abap_true
).

SUBMIT (IV_REPORT_NAME)
   WITH SELECTION-TABLE selection_table
  AND RETURN.


DATA: lo_data        TYPE REF TO data.

cl_salv_bs_runtime_info=>get_data_ref(
      IMPORTING
        r_data = lo_data
).

IF lo_data IS NOT BOUND.
  ev_result_json = '[]'.
  EXIT.
ENDIF.


field-SYMBOLS <lv_data> type any table.
ASSIGN lo_data->* TO <lv_data>.
ev_result_json = /ui2/cl_json=>serialize( data = <lv_data> pretty_name = /ui2/cl_json=>pretty_mode-low_case ).

cl_salv_bs_runtime_info=>clear_all( ).

ENDFUNCTION.

Как получить все столбцы?

1 Ответ

0 голосов
/ 06 ноября 2018

Пользователь JozsefSzikszai дал мне подсказку, необходимую для решения этой проблемы.

Таким образом, я могу прочитать все столбцы из иерархической ALV 

SUBMIT (IV_REPORT_NAME)
   WITH SELECTION-TABLE selection_table
  AND RETURN.

FIELD-SYMBOLS <lt_data>             TYPE ANY TABLE.
FIELD-SYMBOLS <lt_data_line>        TYPE ANY TABLE.

DATA          lr_data               TYPE REF TO data.
DATA          lr_data_line          TYPE REF TO data.
DATA          lr_data_descr          TYPE REF TO cl_abap_datadescr.
DATA          lr_data_line_descr    TYPE REF TO cl_abap_datadescr.

cl_salv_bs_runtime_info=>get_data_ref(
     IMPORTING r_data_descr      = lr_data_descr
                          r_data_line_descr = lr_data_line_descr ).

CREATE DATA lr_data         TYPE HANDLE lr_data_descr.
CREATE DATA lr_data_line    TYPE HANDLE lr_data_line_descr.

ASSIGN lr_data->*           TO <lt_data>.
ASSIGN lr_data_line->*      TO <lt_data_line>.

cl_salv_bs_runtime_info=>get_data(
  IMPORTING
    t_data      = <lt_data>
    t_data_line = <lt_data_line>
       ).


IF <lt_data> IS INITIAL.
  ev_result_json = '[]'.
  EXIT.
ENDIF.


ev_result_json = /ui2/cl_json=>serialize( data = <lt_data_line> pretty_name = /ui2/cl_json=>pretty_mode-low_case ).

cl_salv_bs_runtime_info=>clear_all( ).

ENDFUNCTION.

Обратная связь и советы по ее улучшению приветствуются.

...