Как сравнить идентификатор в файле XML

Question

Моя цель - ввести в выходной файл XML фамилию и количество клиентов. Я хочу сопоставить идентификатор от <ClientList> и идентификатор от <AmountList> и, если они совпадают, показать сумму. Мой XSL-файл работает неправильно.

У меня есть такой XML-файл:

<?xml version="1.0" encoding="utf-8"?>
<myData>
<ClientList>
    <Client>
        <surname>Kowalski</surname>
        <id>12</id>
    </Client>
    <Client>
        <surname>Nowak</surname>
        <id>13</id>
    </Client>
</ClientList>
<AmountList>
     <Client>
        <id>12<id>
        <amount>500</amount>
    </Client>
    <Client>
       <id>13<id>
       <amount>300</amount>
</Client>
</AmountList>
<myData>

Этот XML я бы хотел получить:

<ClientList>
<Client>
   <surname>Kowalski</surname>
   <amount>500</amount>
</Client>
<Client>
  <surname>Nowak</surname>
  <amount>300</amount>
</Client>
</ClientList>

Мой XSL-файл не работает должным образом:

<xsl:template match="/">
<ClientList>
<xsl:for-each select="ClientList/Client">
<Client>
   <surname>
       <xsl:value-of select="surname" />
   </surname>
   <amount>
       <xsl:variable name="Var1" select="substring(id, 1, 2)" />
       <xsl:variable name="Var2" select="substring(id, 1, 2)" />
       <xsl:if test="Var1 = Var2">AmountList/Client/amount</xsl:if> 
   </amount>
</Client>
</xsl:for-each>
</ClientList>

Answer 1

 <xsl:template match="myData">
        <xsl:for-each select="ClientList/Client">
            <xsl:if test="id=../following-sibling::AmountList/Client/id">
                <xsl:element name="ClientList">
                    <xsl:element name="Client">
                <xsl:element name="surname">
                    <xsl:value-of select="surname"/>
                </xsl:element>
                        <amount>
                            <xsl:value-of select="../following-sibling::AmountList/Client[id=current()/id]/amount"/>
                        </amount>
                    </xsl:element>
                </xsl:element>
            </xsl:if>
        </xsl:for-each>
    </xsl:template>

Answer 2

Во-первых, есть несколько небольших проблем с вашим входным XML: узлы <id> в <AmountList> не закрыты должным образом, и у вас отсутствует закрывающий тег для корневого узла <myData>.

Исправив это, вот мое предложение:

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" >
    <xsl:output method="xml" indent="yes"/>
    <xsl:template match="/myData">
    <ClientList>
        <xsl:for-each select="ClientList/Client">
        <Client>
            <surname>
                <xsl:value-of select="surname" />
            </surname>
            <amount>
                <xsl:value-of select="/myData/AmountList/Client[id=current()/id]/amount" />
            </amount>
        </Client>
        </xsl:for-each>
    </ClientList>
    </xsl:template>
</xsl:stylesheet>

Выражение xPath /myData/AmountList/Client[id=current()/id]/amount означает следующее:

Начиная с корня, найдите узел /myData/AmoutList/Client , чей id дочерний узел равен id дочерний узел текущего контекстного узла , а затем выберите amount дочерний узел этого узла.

Функция current() является ключом, чтобы иметь возможность выполнять поиск подобным образом, когда вы ищете в другом месте дерева ввода какой-то узел на основе значения относительно узла, на котором вы находитесь в данный момент.

В этом случае текущий контекстный узел , возвращаемый current(), является Client узлом, потому что это то, что выбрано for-each. Я считаю хорошей практикой всегда знать, какой ваш текущий контекстный узел находится в любой точке преобразования XSL.