Как мне создать и перебрать хэш хэшей в TCL?

Question

Как мне создать и выполнить итерацию в хэше хэшей в TCL?

Если у меня есть такие данные, как:

foo = {
    a => {
        aa => { aa1 aa2 aa3 }
        ab => { ab1 ab2 ab3 }
        ac => { ac1 ac2 ac3 }
    }
    b => {
        ba => { ba1 ba2 ba3 }
        bb => { bb1 bb2 bb3 }
        bc => { bc1 bc2 bc3 }
    }
    c => {
        ca => { ca1 ca2 ca3 }
        cb => { cb1 cb2 cb3 }
        cc => { cc1 cc2 cc3 }
    }
}

Как создать такой хэш, вставляя по одному элементу данных конечного узла за раз. Что-то вроде:

lappend foo (a) (ab) "ab1"

Тогда как мне перебрать все элементы данных? как:

foreach key in foo {
    foreach sub_key in foo($key) {
        foreach elem in foo($key)($sub_key) {
            puts "foo\($key\)\($sub_key\) is $elem"
        }
    }
}

Редактировать: К сожалению, у меня нет доступа к более новой конструкции 'dict'.

Answer 1

Предполагается, что вы используете Tcl 8.5+, и словари - путь:

Определить словарь просто:

set foo {
    a {
        aa { aa1 aa2 aa3 }
        ab { ab1 ab2 ab3 }
        ac { ac1 ac2 ac3 }
    }
    b {
        ba { ba1 ba2 ba3 }
        bb { bb1 bb2 bb3 }
        bc { bc1 bc2 bc3 }
    }
    c {
        ca { ca1 ca2 ca3 }
        cb { cb1 cb2 cb3 }
        cc { cc1 cc2 cc3 }
    }
}

Или определить это программно:

set foo [dict create]
foreach first {a b c} {
    dict update foo $first subdict {
        foreach second {a b c} {
            foreach third {1 2 3} {
                dict lappend subdict "$first$second" "$first$second$third"
            }
        }
    }
}

И выведите его:

dict for {key1 subdict} $foo {
    dict for {key2 list} $subdict {
        foreach elem $list {
            puts "$key1\t$key2\t$elem"
        }
    }
}

edit : перенес решение массива (не dict) в отдельный ответ.

Answer 2

Если вы не используете Tcl 8.5, тогда вы можете использовать массивы. Обратите внимание, что массивы являются одномерными, но ключ - это произвольная строка, которая может использоваться для имитации многомерности:

array set foo {}
foreach first {a b c} {
    foreach second {a b c} {
        foreach third {1 2 3} {
            lappend foo($first,$first$second) "$first$second$third"
        }
    }
}
parray data

и выведите его - обратите внимание: ключи массива, в отличие от ключей словаря, неупорядочены:

foreach key [array names foo] {
    foreach elem $foo($key) {
        puts "$key\t$elem"
    }
}

Если вы получили ключи (например, 'b' и 'bc'), вы можете получить значение таким образом:

set key1 b
set key2 bc
foreach elem $foo($key1,$key2) {puts $elem}

Answer 3

Если вам не хватает роскоши словаря Tcl 8.5, используйте команды списка ключей для выполнения работы. Вы можете использовать Google для одного из следующих терминов: keylget, keylset.

package require Tclx

# Create the nested structure
catch {unset foo}
foreach key1 {a b c} {
    foreach key2 {a b c} {
        catch {unset element}
        foreach key3 {1 2 3} {
            lappend element "$key1$key2$key3"
        }
        keylset foo $key1.$key1$key2 $element
    }
}

# Access the nested structure
foreach key1 {a b c} {
    foreach key2 {a b c} {
        set elementList [keylget foo $key1.$key1$key2]
        foreach element $elementList {
            puts "foo\\$key1\\$key1$key2\\$key3 = $element"
        }
    }
}

#
# Access examples
#

# Access a block of data
puts "foo\\a = [keylget foo a]"
# Access a nested block of data
puts "foo\\b\\ba = [keylget foo b.ba]"
# Access an individual element, remember that Tcl's list index is 0 based
puts "foo\\c\\cb\\1 = [lindex [keylget foo c.cb] 0]"

Answer 4

Если вы просто хотите перебрать dict (который является просто списком пар ключ-значение) без команды dict, тогда вы можете просто использовать класс foreach:

set foo {
  a {
    aa { aa1 aa2 aa3 }
    ab { ab1 ab2 ab3 }
    ac { ac1 ac2 ac3 }
  }
  b {
    ba { ba1 ba2 ba3 }
    bb { bb1 bb2 bb3 }
    bc { bc1 bc2 bc3 }
  }
  c {
    ca { ca1 ca2 ca3 }
    cb { cb1 cb2 cb3 }
    cc { cc1 cc2 cc3 }
  }
}

foreach {key value} $foo {
  foreach {sub_key sub_value} $value {
    foreach elem $sub_value {
      puts "foo\($key\)\($sub_key\) is $elem"
    }
  }
}

с другой стороны, вставка элементов по одному без болезненной команды dict:

set foo {}
lappend foo a {}
set a_index [lsearch $foo a]
set a_value_index [expr {$a_index+1}]
set a_value [lindex $foo $a_value_index]
lappend a_value aa {}
lset foo $a_value_index $a_value
# it is now too painful for me to continue :-(

К счастью, вы можете использовать реализацию команды dict pure-tcl: forward-совместимый dict