Excel VBA Выбрать листы из списка, где значение TRUE

Question

Я пытаюсь написать макрос, который напечатает несколько листов в pdf. У меня есть лист («PDF»), в котором перечислены все листы в рабочей тетради в столбце D, а рядом со столбцом F у меня есть список значений TRUE / FALSE. Мой макрос должен напечатать все листы в столбце D, которые имеют ИСТИНА в столбце F, в одном файле PDF.

Количество листов в этой книге действительно различается.

Ниже мой первый удар по коду для этого

Sub PDFCreater()

Dim pdfName As String
Dim FullName As String
Dim myArray() As Variant
Dim ArrSize As Integer
Dim ArrWkst As String
Dim RowCnt As Long, ArrCnt As Long

pdfName = Sheets("PDF").Range("D1").Text
FullName = ThisWorkbook.Path & "\" & pdfName & ".pdf"

ReDim myArray(Sheets("PDF").Range("D2").Value)    'Size of array/ number of sheets in PDF
ArrCnt = 0
For RowCnt = 8 To 302
    If Sheets("PDF").Cells(RowCnt, 6).Value = True Then
        myArray(ArrCnt) = Cells(RowCnt, 4).Value
        ArrCnt = ArrCnt + 1
    End If
    RowCnt = RowCnt + 1
Next
'Select all worksheets in MyArray()
Sheets(myArray).Select
ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=FullName _
, Quality:=xlQualityMedium, IncludeDocProperties:=False,
IgnorePrintAreas:=False, OpenAfterPublish:=True
End Sub

Answer 1

По вашему описанию в вашем коде несколько ошибок

Sub Test()
Dim pdfName As String
Dim FullName As String
Dim myArray() As Variant
Dim ArrSize As Integer
Dim ArrWkst As String
Dim RowCnt As Long, ArrCnt As Long

    pdfName = Sheets("PDF").Range("D1").Text
    FullName = ThisWorkbook.Path & "\" & pdfName & ".pdf"

    ' You need to re-dim the array in the loop in order to have an array with
    ' the correct dimension. Otherwisae the array is too big and will contain
    ' empty entries
    'ReDim myArray(Sheets("PDF").Range("D2").Value)    'Size of array/ number of sheets in PDF
    ArrCnt = 0
    For RowCnt = 8 To 302
        If Sheets("PDF").Cells(RowCnt, 6).Value Then
            ReDim Preserve myArray(ArrCnt)
            myArray(ArrCnt) = Cells(RowCnt, 4).Value
            ArrCnt = ArrCnt + 1
        End If
        ' the for loop will increase rowcnt itself
        ' no need to do that
        'RowCnt = RowCnt + 1
    Next
    'Select all worksheets in MyArray()
    Sheets(myArray).Select
    ActiveSheet.ExportAsFixedFormat Type:=xlTypePDF, Filename:=FullName, _
                                    IncludeDocProperties:=False, _
                                    IgnorePrintAreas:=False, OpenAfterPublish:=True

End Sub

Answer 2

Используйте цикл, чтобы скрыть листы со значением FALSE, затем:

ThisWorkbook.ExportAsFixedFormat Type:=xlTypePDF, Filename:=FullName _
        , Quality:=xlQualityStandard, IncludeDocProperties:=True, IgnorePrintAreas _
        :=False, OpenAfterPublish:=True

Это сохранит всю книгу в формате PDF, за исключением скрытых листов.