Сокращение Фамилия, Имя в XSLT

Question

Я пытаюсь отформатировать имя игрока в LAST, F., а не в полное имя.
Поэтому я хочу вырезать строку через 2 пробела после каждой запятой и добавить. (Точка)

Вот пример XML:

<fbgame>
 <team>
   <player name="LASTNAME, FIRSTNAME"></player>
</team>
 </fbgame>

это кодовый блок xslt

<name>
  <xsl:value-of select="@name"/>
</name>

Answer 1

XSLT 1.0

<xsl:template match="player">
    <name>
        <xsl:value-of select="substring-before(@name, ', ')" />
        <xsl:text>, </xsl:text>
        <xsl:value-of select="substring(substring-after(@name, ', '), 1, 1)" />
        <xsl:text>.</xsl:text>
    </name>
</xsl:template>

Или, если вы предпочитаете:

<xsl:template match="player">
    <name>
        <xsl:variable name="last" select="substring-before(@name, ', ')" />
        <xsl:value-of select="substring(@name, 1, string-length($last) + 3)" />
        <xsl:text>.</xsl:text>
    </name>
</xsl:template>

Answer 2

Другая опция XSLT 2.0:

<xsl:template match="player">
  <name>
    <xsl:value-of select="replace(@name,'([^,]+, .).*','$1.')"/>
  </name>
</xsl:template>

Answer 3

Использование xslt 2.0,

<name>
  <xsl:variable name="fullname" select="tokenize(@name, ',')" />
  <xsl:value-of select="concat($fullname[1], ',',substring($fullname[2],1,2),'.')"/>
</name>