Excel VLOOKUP несколько значений для каждого элемента

Question

У меня есть два листа Excel, где мне нужно vlookup, используя первый столбец: (имя) в моем случае.

Но проблема здесь в том, что у каждого Имени есть несколько школ на листе 1, и у каждого Имени есть несколько видов спорта на Листе 2, и у моего финального листа должно быть Имя: Школа: Спорт.

Мне нужно vlookup с именем столбца.

Пожалуйста, просмотрите приведенный ниже пример для получения ясной информации. Пожалуйста, помогите мне с этим делом.

Лист1
Название школы
Сэм Оксфорд
Сэм Гарвард
Лили Оливет
Гэри Кэмбридж
Лили Кембридж
Джон Окридж
Гари Санта Мария
Том Мэй Джонс

Лист2
Название Спорт
Гари Футбол
Сэм Хоккей
Сэм Стрельба из лука
Лили Футбол
Том теннис
Лили плавание
Гэри Поло
Джон Скуба

Я хочу итоговый лист таким образом:
Название Школа Спорта
Сэм Оксфорд хоккей
Сэм Гарвард Хоккей
Сэм Оксфорд Стрельба из лука
Сэм Гарвард Стрельба из лука
Лили Оливет Плавание
Лили Оливет Футбол
Гэри Кэмбридж Футбол
Гэри Кэмбридж Поло
Лили Кембридж Плавание
Лили Кембридж Футбол
Джон Окридж Скуба
Гари Санта Мария Футбол
Гари Санта Мария Поло
Том Мэй Джонс, теннис

Answer 1

Вспомогательный столбец облегчает его использование. Обратитесь к изображению ниже.

Я поместил эту формулу массива в A1, чтобы получить количество строк в выводе (фиксация с ctrl + shift + enter ):

=SUM(--(Sheet1!A2:A9=TRANSPOSE(Sheet2!A2:A9)))

Я поместил это как формулу массива в A2:A15 (столбец с 14 строками - количество строк в A1):

=SMALL(IF(Sheet1!A2:A9=TRANSPOSE(Sheet2!A2:A9),(ROW(Sheet1!A2:A9)-ROW(Sheet1!A1))*(ROWS(Sheet2!A2:A9)+1)+TRANSPOSE(ROW(Sheet2!A2:A9)-ROW(Sheet2!A1))),ROW(INDIRECT("1:"&Sheet3!A1)))

Я положил это в B2 (не нужно вводить его как формулу массива) и заполнил:

=INDEX(Sheet1!$A$2:$A$9,INT(A2/(ROWS(Sheet2!$A$2:$A$9)+1)))

Я положил это в C2 и заполнил:

=INDEX(Sheet1!$B$2:$B$9,INT(A2/(ROWS(Sheet2!$A$2:$A$9)+1)))

Я положил это в D2 и заполнил:

=INDEX(Sheet2!$B$2:$B$9,MOD(A2,ROWS(Sheet2!$B$2:$B$9)+1))