Хаскель и Квадратика

Question

Мне нужно написать программу для решения квадратиков, возвращающую результат комплексного числа.

До сих пор я получил определение сложного числа, объявив его частью числа num, так что +, - и * - могут иметь место.

Я также определил тип данных для квадратного уравнения, но теперь я застрял с фактическим решением квадратичного уравнения. Моя математика довольно плохая, поэтому любая помощь будет принята с благодарностью ...

data Complex = C {
re :: Float,
im :: Float
} deriving Eq

-- Display complex numbers in the normal way

instance Show Complex where
    show (C r i)
        | i == 0            = show r
        | r == 0            = show i++"i"
        | r < 0 && i < 0    = show r ++ " - "++ show (C 0 (i*(-1)))
        | r < 0 && i > 0    = show r ++ " + "++ show (C 0 i)
        | r > 0 && i < 0    = show r ++ " - "++ show (C 0 (i*(-1)))
        | r > 0 && i > 0    = show r ++ " + "++ show (C 0 i)


-- Define algebraic operations on complex numbers
instance Num Complex where
    fromInteger n       = C (fromInteger n) 0 -- tech reasons
    (C a b) + (C x y)   = C (a+x) (b+y)
    (C a b) * (C x y)   = C (a*x - b*y) (b*x + b*y)
    negate (C a b)      = C (-a) (-b)

instance Fractional Complex where
    fromRational r      = C (fromRational r) 0 -- tech reasons
    recip (C a b)       = C (a/((a^2)+(b^2))) (b/((a^2)+(b^2)))


root :: Complex -> Complex
root (C x y)
    | y == 0 && x == 0  = C 0 0
    | y == 0 && x > 0   = C (sqrt ( ( x + sqrt ( (x^2) + 0 ) ) / 2 ) )  0
    | otherwise         = C (sqrt ( ( x + sqrt ( (x^2) + (y^2) ) ) / 2 ) ) ((y/(2*(sqrt ( ( x + sqrt ( (x^2) + (y^2) ) ) / 2 ) ) ) ) )


-- quadratic polynomial : a.x^2 + b.x + c
data Quad = Q {
    aCoeff, bCoeff, cCoeff :: Complex
    } deriving Eq


instance Show Quad where
    show (Q a b c) = show a ++ "x^2 + " ++ show b ++ "x + " ++ show c

solve :: Quad -> (Complex, Complex)
solve (Q a b c) = STUCK!

РЕДАКТИРОВАТЬ: Кажется, я упустил весь смысл использования моего собственного типа данных комплексного числа, чтобы узнать о пользовательских типах данных. Я хорошо знаю, что я мог бы использовать complex.data. Будем весьма благодарны за любую помощь, которая может быть оказана с использованием решения my . \

РЕДАКТИРОВАТЬ 2: Кажется, мой первоначальный вопрос был сформулирован ужасно. Я знаю, что квадратная формула вернет мне оба (или только один) корень. У меня возникают проблемы с возвратом этих корней в виде (сложного, сложного) кортежа с кодом выше.

Мне хорошо известно, что я мог бы использовать встроенные квадратичные функции, как показано ниже, но это не упражнение. Идея этого упражнения и создания собственного типа данных комплексного числа заключается в изучении пользовательских типов данных.

Answer 1

Как сказал newacct, это просто квадратное уравнение:

(-b +- sqrt(b^2 - 4ac)) / 2a

module QuadraticSolver where

import Data.Complex
data Quadratic a = Quadratic a a a deriving (Show, Eq)

roots :: (RealFloat a) => Quadratic a -> [ Complex a ]
roots (Quadratic a b c) = 
  if discriminant == 0 
  then [ numer / denom ]
  else [ (numer + root_discriminant) / denom,
         (numer - root_discriminant) / denom ]
  where discriminant = (b*b - 4*a*c)
        root_discriminant = if (discriminant < 0) 
                            then 0 :+ (sqrt $ -discriminant)
                            else (sqrt discriminant) :+ 0
        denom = 2*a :+ 0
        numer = (negate b) :+ 0

на практике:

ghci> :l QuadraticSolver
Ok, modules loaded: QuadraticSolver.
ghci> roots (Quadratic 1 2 1)
[(-1.0) :+ 0.0]
ghci> roots (Quadratic 1 0 1)
[0.0 :+ 1.0,(-0.0) :+ (-1.0)]

И адаптируясь к вашим терминам:

solve :: Quad -> (Complex, Complex)
solve (Q a b c) = ( sol (+), sol (-) )
  where sol op = (op (negate b) $ root $ b*b - 4*a*c) / (2 * a)

Хотя я не проверял этот код

Answer 2

Поскольку sqrt в Haskell также может обрабатывать комплексные числа, решение rampion может быть еще более упрощено:

import Data.Complex

-- roots for quadratic equations with complex coefficients
croots :: (RealFloat a) =>
          (Complex a) -> (Complex a) -> (Complex a) -> [Complex a]
croots a b c
      | disc == 0 = [solution (+)]
      | otherwise = [solution (+), solution (-)]
   where disc = b*b - 4*a*c
         solution plmi = plmi (-b) (sqrt disc) / (2*a)

-- roots for quadratic equations with real coefficients
roots :: (RealFloat a) => a -> a -> a -> [Complex a]
roots a b c = croots (a :+ 0) (b :+ 0) (c :+ 0)

Вы также можете использовать эту функцию croots с вашим собственным типом данных, если вы измените типы в соответствии с вашей реализацией (и вызовете функцию root вместо sqrt).