Как создать собственные настройки тестового набора, такие как теги в Robot Framework

Question

*** Test Cases ***
TestCase_ID
    [Documentation]    Clef test
    [Tags]    default_tag
    [link]    this is hyperlink
    Log    This is testing

Используйте приведенный выше код, я хочу, чтобы часть "link:" отображалась в log.html.

Answer 1

На странице Robot Framework Github есть запрос функции 2080 для того, что вы просите. Однако этот запрос был закрыт, и ни один из предоставленных вариантов использования также не может быть реализован с использованием тегов.

Альтернативой, которая делает почти то же самое, является использование функциональности сообщения Test Case Message и форматирования HTML для создания раздела для добавления ссылок. Ниже приведен пример кода, показывающий различные варианты и общий результат.

*** Settings ***
Documentation    This is the Suite Level Documentation

Metadata    Version    1.0.0.1           #This the first patch on the initial version.
Metadata    Author     Stack Overflow    #The core developer


*** Test Cases ***
Test Case 1
    [Documentation]     This is the test case documentation
    [Tags]              Test Tag 1

    Set Suite Documentation    Test Level addition to Suite Documenation    append=${true}

    Set Suite Metadata         Test Case 1    A Suite Level Metadata item from the Test Case     append=${true}
    Set Suite Metadata         Link           http://www.microsoft.com    append=${true} 

    Set Test Documentation     My Test Level documentation       append=${true}   
    Set Test Message           *HTML* My Test level Message<br/>             append=${true}

    Comment                    My Test Case Comment
    Log                        My Test Case Log
    Fail
    [Teardown]  Set Jira Link    1234  

*** Keywords ***
Set Jira Link
    [Arguments]    ${jira_Id}
    ${prev_level}    Set Log Level    WARN
    Set Test Message     *HTML* <br/><b>Link:</b> <a href='http://www.jira.com/issue/${jira_Id}'>Jira Issue ${jira_Id}</a><br/>    append=${true}
    Set Log Level    ${prev_level}

С соответствующим результатом. В этом случае обратите внимание на последнюю строку в примере кода и соответствующий раздел сообщения под тестовым регистром в этой последней строке.