Добавить код в существующий модуль: удалить повторяющиеся значения в строке 2

Question

Я создал существующий модуль, который будет импортировать текстовый файл в мою таблицу, и он отлично работает. Для ускорения процесса я хотел бы автоматически удалять строки. Размер импортируемых данных может варьироваться, поэтому я не могу использовать фиксированный диапазон.

Sub Import_Data()
    Dim Ret

    Ret = Application.GetOpenFilename("Text Files (*.txt), *.txt")

    If Ret <> False Then
        With ActiveSheet.QueryTables.Add(Connection:= _
        "TEXT;" & Ret, Destination:=Application.InputBox(prompt:="Select Input Cell", Type:=8))

        .Name = "Sample"
        .FieldNames = True
        .RowNumbers = False
        .FillAdjacentFormulas = False
        .PreserveFormatting = True
        .RefreshOnFileOpen = False
        .RefreshStyle = xlInsertDeleteCells
        .SavePassword = False
        .SaveData = True
        .AdjustColumnWidth = True
        .RefreshPeriod = 0
        .TextFilePromptOnRefresh = False
        .TextFilePlatform = 437
        .TextFileStartRow = 1
        .TextFileParseType = xlDelimited
        .TextFileTextQualifier = xlTextQualifierDoubleQuote
        .TextFileConsecutiveDelimiter = False
        .TextFileTabDelimiter = False
        .TextFileSemicolonDelimiter = False
        .TextFileCommaDelimiter = True
        .TextFileSpaceDelimiter = False
        .TextFileColumnDataTypes = Array(2, 2, 1, 2, 2, 1)
        .TextFileTrailingMinusNumbers = True
        .Refresh BackgroundQuery:=False

        End With
End If
End Sub

Я хотел бы просканировать новый импортированный файл. Если в столбце 2 есть повторяющиеся значения, удалите повторяющиеся строки.

Answer 1

Определите диапазон, в котором находятся данные, затем примените метод RemoveDuplicates.

 ActiveSheet.Range("$A$1:$C$20").RemoveDuplicates Columns:=2, Header:=xlYes

Ваш диапазон может быть получен путем поиска номера строки после импорта данных с вашим предыдущим кодом

Dim myrow As Long
    ' get the row number of the last row of data in column A
    myrow = ActiveSheet.Cells(Rows.Count, "A").End(xlUp).Row
    ' remove rows with duplicates in the second column, column B, in
    ' the table that sits in A1 to Cx
    ActiveSheet.Range("$A$1:$C" & myrow).RemoveDuplicates Columns:=2, Header:=xlYes